meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 project('DPDK', 'C',
   5         version: '18.11.0-rc0',
   6         license: 'BSD',
   7         default_options: ['buildtype=release', 'default_library=static'],
   8         meson_version: '>= 0.41'
   9 )
  10
  11 # set up some global vars for compiler, platform, configuration, etc.
  12 cc = meson.get_compiler('c')
  13 dpdk_conf = configuration_data()
  14 dpdk_libraries = []
  15 dpdk_drivers = []
  16 dpdk_extra_ldflags = []
  17
  18 driver_install_path = join_paths(get_option('libdir'), 'dpdk/drivers')
  19 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  20
  21 # configure the build, and make sure configs here and in config folder are
  22 # able to be included in any file. We also store a global array of include dirs
  23 # for passing to pmdinfogen scripts
  24 global_inc = include_directories('.', 'config')
  25 subdir('config')
  26
  27 # build libs and drivers
  28 subdir('lib')
  29 subdir('buildtools')
  30 subdir('drivers')
  31
  32 # build binaries and installable tools
  33 subdir('usertools')
  34 subdir('app')
  35 subdir('test')
  36
  37 # build docs
  38 subdir('doc')
  39
  40 # build any examples explicitly requested - useful for developers
  41 if get_option('examples') != ''
  42         subdir('examples')
  43 endif
  44
  45 # build kernel modules if enabled
  46 if get_option('enable_kmods')
  47         subdir('kernel')
  48 endif
  49
  50 # write the build config
  51 build_cfg = 'rte_build_config.h'
  52 configure_file(output: build_cfg,
  53                 configuration: dpdk_conf,
  54                 install_dir: join_paths(get_option('includedir'),
  55                                 get_option('include_subdir_arch')))
  56
  57 # for static builds, include the drivers as libs and we need to "whole-archive"
  58 # them.
  59 dpdk_drivers = ['-Wl,--whole-archive'] + dpdk_drivers + ['-Wl,--no-whole-archive']
  60
  61 # driver .so files often depend upon the bus drivers for their connect bus,
  62 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  63 # to be in the library path, so symlink the drivers from the main lib directory.
  64 meson.add_install_script('buildtools/symlink-drivers-solibs.sh',
  65                 driver_install_path,
  66                 get_option('libdir'))
  67
  68 pkg = import('pkgconfig')
  69 pkg.generate(name: meson.project_name(),
  70         filebase: 'lib' + meson.project_name().to_lower(),
  71         version: meson.project_version(),
  72         libraries: dpdk_libraries,
  73         libraries_private: dpdk_drivers + dpdk_libraries +
  74                         ['-Wl,-Bdynamic'] + dpdk_extra_ldflags,
  75         description: 'The Data Plane Development Kit (DPDK)',
  76         subdirs: [get_option('include_subdir_arch'), '.'],
  77         extra_cflags: ['-include', 'rte_config.h'] + machine_args
  78 )
  79
  80 # final output, list all the libs and drivers to be built
  81 # this does not affect any part of the build, for information only.
  82 output_message = '\n=================\nLibraries Enabled\n=================\n'
  83 output_message += '\nlibs:\n\t'
  84 output_count = 0
  85 foreach lib:enabled_libs
  86         output_message += lib + ', '
  87         output_count += 1
  88         if output_count == 8
  89                 output_message += '\n\t'
  90                 output_count = 0
  91         endif
  92 endforeach
  93 message(output_message + '\n')
  94
  95
  96 # prior to 0.47 set_variable didn't work with arrays, so we can't
  97 # track driver lists easily
  98 if meson.version().version_compare('>=0.47')
  99         output_message = '\n===============\nDrivers Enabled\n===============\n'
 100         foreach class:driver_classes
 101                 class_drivers = get_variable(class + '_drivers')
 102                 output_message += '\n' + class + ':\n\t'
 103                 output_count = 0
 104                 foreach drv:class_drivers
 105                         output_message += drv + ', '
 106                         output_count += 1
 107                         if output_count == 8
 108                                 output_message += '\n\t'
 109                                 output_count = 0
 110                         endif
 111                 endforeach
 112         endforeach
 113         message(output_message + '\n')
 114 endif