test/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 if not get_option('tests')
   5     subdir_done()
   6 endif
   7
   8 test_sources = files(
   9         'commands.c',
  10         'packet_burst_generator.c',
  11         'test.c',
  12         'test_acl.c',
  13         'test_alarm.c',
  14         'test_atomic.c',
  15         'test_barrier.c',
  16         'test_bitops.c',
  17         'test_bitmap.c',
  18         'test_bpf.c',
  19         'test_byteorder.c',
  20         'test_cksum.c',
  21         'test_cmdline.c',
  22         'test_cmdline_cirbuf.c',
  23         'test_cmdline_etheraddr.c',
  24         'test_cmdline_ipaddr.c',
  25         'test_cmdline_lib.c',
  26         'test_cmdline_num.c',
  27         'test_cmdline_portlist.c',
  28         'test_cmdline_string.c',
  29         'test_common.c',
  30         'test_cpuflags.c',
  31         'test_crc.c',
  32         'test_cryptodev.c',
  33         'test_cryptodev_asym.c',
  34         'test_cryptodev_blockcipher.c',
  35         'test_cryptodev_security_ipsec.c',
  36         'test_cryptodev_security_pdcp.c',
  37         'test_cycles.c',
  38         'test_debug.c',
  39         'test_devargs.c',
  40         'test_distributor.c',
  41         'test_distributor_perf.c',
  42         'test_dmadev.c',
  43         'test_dmadev_api.c',
  44         'test_eal_flags.c',
  45         'test_eal_fs.c',
  46         'test_efd.c',
  47         'test_efd_perf.c',
  48         'test_errno.c',
  49         'test_ethdev_link.c',
  50         'test_event_crypto_adapter.c',
  51         'test_event_eth_rx_adapter.c',
  52         'test_event_ring.c',
  53         'test_event_timer_adapter.c',
  54         'test_eventdev.c',
  55         'test_external_mem.c',
  56         'test_fbarray.c',
  57         'test_fib.c',
  58         'test_fib_perf.c',
  59         'test_fib6.c',
  60         'test_fib6_perf.c',
  61         'test_func_reentrancy.c',
  62         'test_graph.c',
  63         'test_graph_perf.c',
  64         'test_hash.c',
  65         'test_hash_functions.c',
  66         'test_hash_multiwriter.c',
  67         'test_hash_readwrite.c',
  68         'test_hash_perf.c',
  69         'test_hash_readwrite_lf_perf.c',
  70         'test_interrupts.c',
  71         'test_ipfrag.c',
  72         'test_ipsec.c',
  73         'test_ipsec_sad.c',
  74         'test_ipsec_perf.c',
  75         'test_kni.c',
  76         'test_kvargs.c',
  77         'test_lcores.c',
  78         'test_logs.c',
  79         'test_lpm.c',
  80         'test_lpm6.c',
  81         'test_lpm6_perf.c',
  82         'test_lpm_perf.c',
  83         'test_malloc.c',
  84         'test_malloc_perf.c',
  85         'test_mbuf.c',
  86         'test_member.c',
  87         'test_member_perf.c',
  88         'test_memcpy.c',
  89         'test_memcpy_perf.c',
  90         'test_memory.c',
  91         'test_mempool.c',
  92         'test_mempool_perf.c',
  93         'test_memzone.c',
  94         'test_meter.c',
  95         'test_mcslock.c',
  96         'test_mp_secondary.c',
  97         'test_per_lcore.c',
  98         'test_pflock.c',
  99         'test_pmd_perf.c',
 100         'test_power.c',
 101         'test_power_cpufreq.c',
 102         'test_power_kvm_vm.c',
 103         'test_prefetch.c',
 104         'test_rand_perf.c',
 105         'test_rawdev.c',
 106         'test_rcu_qsbr.c',
 107         'test_rcu_qsbr_perf.c',
 108         'test_reciprocal_division.c',
 109         'test_reciprocal_division_perf.c',
 110         'test_red.c',
 111         'test_pie.c',
 112         'test_reorder.c',
 113         'test_rib.c',
 114         'test_rib6.c',
 115         'test_ring.c',
 116         'test_ring_mpmc_stress.c',
 117         'test_ring_hts_stress.c',
 118         'test_ring_mt_peek_stress.c',
 119         'test_ring_mt_peek_stress_zc.c',
 120         'test_ring_perf.c',
 121         'test_ring_rts_stress.c',
 122         'test_ring_st_peek_stress.c',
 123         'test_ring_st_peek_stress_zc.c',
 124         'test_ring_stress.c',
 125         'test_rwlock.c',
 126         'test_sched.c',
 127         'test_security.c',
 128         'test_security_inline_proto.c',
 129         'test_seqlock.c',
 130         'test_service_cores.c',
 131         'test_spinlock.c',
 132         'test_stack.c',
 133         'test_stack_perf.c',
 134         'test_string_fns.c',
 135         'test_tailq.c',
 136         'test_thash.c',
 137         'test_thash_perf.c',
 138         'test_threads.c',
 139         'test_timer.c',
 140         'test_timer_perf.c',
 141         'test_timer_racecond.c',
 142         'test_timer_secondary.c',
 143         'test_ticketlock.c',
 144         'test_trace.c',
 145         'test_trace_register.c',
 146         'test_trace_perf.c',
 147         'test_version.c',
 148         'virtual_pmd.c',
 149 )
 150
 151 test_deps = enabled_libs
 152 # as well as libs, the pci and vdev bus drivers are needed for a lot of tests
 153 test_deps += ['bus_pci', 'bus_vdev']
 154
 155 # Each test is marked with flags:
 156 # - the first flag indicates whether the test can run in no-huge mode,
 157 # - the second flag indicates whether the test can run with ASan enabled,
 158 fast_tests = [
 159         ['acl_autotest', true, true],
 160         ['atomic_autotest', false, true],
 161         ['bitmap_autotest', true, true],
 162         ['bpf_autotest', true, true],
 163         ['bpf_convert_autotest', true, true],
 164         ['bitops_autotest', true, true],
 165         ['byteorder_autotest', true, true],
 166         ['cksum_autotest', true, true],
 167         ['cmdline_autotest', true, true],
 168         ['common_autotest', true, true],
 169         ['cpuflags_autotest', true, true],
 170         ['debug_autotest', true, true],
 171         ['devargs_autotest', true, true],
 172         ['eal_flags_c_opt_autotest', false, false],
 173         ['eal_flags_main_opt_autotest', false, false],
 174         ['eal_flags_n_opt_autotest', false, false],
 175         ['eal_flags_hpet_autotest', false, false],
 176         ['eal_flags_no_huge_autotest', false, false],
 177         ['eal_flags_a_opt_autotest', false, false],
 178         ['eal_flags_b_opt_autotest', false, false],
 179         ['eal_flags_vdev_opt_autotest', false, false],
 180         ['eal_flags_r_opt_autotest', false, false],
 181         ['eal_flags_mem_autotest', false, false],
 182         ['eal_flags_file_prefix_autotest', false, false],
 183         ['eal_flags_misc_autotest', false, false],
 184         ['eal_fs_autotest', true, true],
 185         ['errno_autotest', true, true],
 186         ['ethdev_link_status', true, true],
 187         ['event_ring_autotest', true, true],
 188         ['fib_autotest', true, true],
 189         ['fib6_autotest', true, true],
 190         ['func_reentrancy_autotest', false, true],
 191         ['hash_autotest', true, true],
 192         ['interrupt_autotest', true, true],
 193         ['ipfrag_autotest', false, true],
 194         ['lcores_autotest', true, true],
 195         ['logs_autotest', true, true],
 196         ['lpm_autotest', true, true],
 197         ['lpm6_autotest', true, true],
 198         ['malloc_autotest', false, true],
 199         ['mbuf_autotest', false, true],
 200         ['mcslock_autotest', false, true],
 201         ['memcpy_autotest', true, true],
 202         ['memory_autotest', false, true],
 203         ['mempool_autotest', false, true],
 204         ['memzone_autotest', false, true],
 205         ['meter_autotest', true, true],
 206         ['multiprocess_autotest', false, false],
 207         ['per_lcore_autotest', true, true],
 208         ['pflock_autotest', true, true],
 209         ['prefetch_autotest', true, true],
 210         ['rcu_qsbr_autotest', true, true],
 211         ['pie_autotest', true, true],
 212         ['rib_autotest', true, true],
 213         ['rib6_autotest', true, true],
 214         ['ring_autotest', true, true],
 215         ['rwlock_test1_autotest', true, true],
 216         ['rwlock_rda_autotest', true, true],
 217         ['rwlock_rds_wrm_autotest', true, true],
 218         ['rwlock_rde_wro_autotest', true, true],
 219         ['sched_autotest', true, true],
 220         ['security_autotest', false, true],
 221         ['seqlock_autotest', true, true],
 222         ['spinlock_autotest', true, true],
 223         ['stack_autotest', false, true],
 224         ['stack_lf_autotest', false, true],
 225         ['string_autotest', true, true],
 226         ['tailq_autotest', true, true],
 227         ['ticketlock_autotest', true, true],
 228         ['timer_autotest', false, true],
 229         ['user_delay_us', true, true],
 230         ['version_autotest', true, true],
 231         ['crc_autotest', true, true],
 232         ['distributor_autotest', false, true],
 233         ['eventdev_common_autotest', true, true],
 234         ['fbarray_autotest', true, true],
 235         ['hash_readwrite_func_autotest', false, true],
 236         ['ipsec_autotest', true, true],
 237         ['kni_autotest', false, true],
 238         ['kvargs_autotest', true, true],
 239         ['member_autotest', true, true],
 240         ['power_cpufreq_autotest', false, true],
 241         ['power_autotest', true, true],
 242         ['power_kvm_vm_autotest', false, true],
 243         ['reorder_autotest', true, true],
 244         ['service_autotest', true, true],
 245         ['thash_autotest', true, true],
 246         ['threads_autotest', true, true],
 247         ['trace_autotest', true, true],
 248 ]
 249
 250 # Tests known to have issues or which don't belong in other tests lists.
 251 extra_test_names = [
 252         'alarm_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 253         'red_autotest', # https://bugs.dpdk.org/show_bug.cgi?id=826
 254 ]
 255
 256 perf_test_names = [
 257         'ring_perf_autotest',
 258         'malloc_perf_autotest',
 259         'mempool_perf_autotest',
 260         'memcpy_perf_autotest',
 261         'hash_perf_autotest',
 262         'timer_perf_autotest',
 263         'reciprocal_division',
 264         'reciprocal_division_perf',
 265         'lpm_perf_autotest',
 266         'rib_slow_autotest',
 267         'fib_slow_autotest',
 268         'fib_perf_autotest',
 269         'red_all',
 270         'pie_all',
 271         'barrier_autotest',
 272         'hash_multiwriter_autotest',
 273         'timer_racecond_autotest',
 274         'efd_autotest',
 275         'hash_functions_autotest',
 276         'member_perf_autotest',
 277         'efd_perf_autotest',
 278         'lpm6_perf_autotest',
 279         'rib6_slow_autotest',
 280         'fib6_slow_autotest',
 281         'fib6_perf_autotest',
 282         'rcu_qsbr_perf_autotest',
 283         'red_perf',
 284         'pie_perf',
 285         'distributor_perf_autotest',
 286         'pmd_perf_autotest',
 287         'stack_perf_autotest',
 288         'stack_lf_perf_autotest',
 289         'rand_perf_autotest',
 290         'hash_readwrite_perf_autotest',
 291         'hash_readwrite_lf_perf_autotest',
 292         'trace_perf_autotest',
 293         'ipsec_perf_autotest',
 294         'thash_perf_autotest',
 295 ]
 296
 297 driver_test_names = [
 298         'cryptodev_aesni_gcm_autotest',
 299         'cryptodev_aesni_mb_autotest',
 300         'cryptodev_cn10k_autotest',
 301         'cryptodev_cn9k_autotest',
 302         'cryptodev_dpaa2_sec_autotest',
 303         'cryptodev_dpaa_sec_autotest',
 304         'cryptodev_null_autotest',
 305         'cryptodev_openssl_autotest',
 306         'cryptodev_qat_autotest',
 307         'cryptodev_sw_armv8_autotest',
 308         'cryptodev_sw_kasumi_autotest',
 309         'cryptodev_sw_mvsam_autotest',
 310         'cryptodev_sw_snow3g_autotest',
 311         'cryptodev_sw_zuc_autotest',
 312         'dmadev_autotest',
 313         'rawdev_autotest',
 314 ]
 315
 316 dump_test_names = []
 317
 318 if not is_windows
 319     driver_test_names += [
 320             'cryptodev_openssl_asym_autotest',
 321             'eventdev_selftest_octeontx',
 322             'eventdev_selftest_sw',
 323     ]
 324
 325     dump_test_names += [
 326             'dump_struct_sizes',
 327             'dump_mempool',
 328             'dump_malloc_stats',
 329             'dump_devargs',
 330             'dump_log_types',
 331             'dump_ring',
 332             'dump_physmem',
 333             'dump_memzone',
 334     ]
 335 endif
 336
 337 # The following linkages are an exception to allow running the
 338 # unit tests without requiring that the developer install the
 339 # DPDK libraries.  Explicit linkage of drivers (plugin libraries)
 340 # in applications should not be used.
 341 if dpdk_conf.has('RTE_MEMPOOL_RING')
 342     test_deps += 'mempool_ring'
 343 endif
 344 if dpdk_conf.has('RTE_MEMPOOL_STACK')
 345     test_deps += 'mempool_stack'
 346 endif
 347 if dpdk_conf.has('RTE_EVENT_SKELETON')
 348     test_deps += 'event_skeleton'
 349 endif
 350
 351 if dpdk_conf.has('RTE_LIB_FLOW_CLASSIFY')
 352     test_sources += 'test_flow_classify.c'
 353     fast_tests += [['flow_classify_autotest', false, true]]
 354 endif
 355 if dpdk_conf.has('RTE_LIB_METRICS')
 356     test_sources += ['test_metrics.c']
 357     fast_tests += [['metrics_autotest', true, true]]
 358 endif
 359 if not is_windows and dpdk_conf.has('RTE_LIB_TELEMETRY')
 360     test_sources += ['test_telemetry_json.c', 'test_telemetry_data.c']
 361     fast_tests += [['telemetry_json_autotest', true, true]]
 362     fast_tests += [['telemetry_data_autotest', true, true]]
 363 endif
 364 if dpdk_conf.has('RTE_LIB_PIPELINE')
 365 # pipeline lib depends on port and table libs, so those must be present
 366 # if pipeline library is.
 367     test_sources += [
 368             'test_table.c',
 369             'test_table_acl.c',
 370             'test_table_combined.c',
 371             'test_table_pipeline.c',
 372             'test_table_ports.c',
 373             'test_table_tables.c',
 374     ]
 375     fast_tests += [['table_autotest', true, true]]
 376 endif
 377
 378 # The following linkages of drivers are required because
 379 # they are used via a driver-specific API.
 380 if dpdk_conf.has('RTE_NET_BOND')
 381     test_deps += 'net_bond'
 382     test_sources += ['test_link_bonding.c', 'test_link_bonding_rssconf.c']
 383     driver_test_names += ['link_bonding_autotest', 'link_bonding_rssconf_autotest']
 384     if dpdk_conf.has('RTE_NET_RING')
 385         test_sources += 'test_link_bonding_mode4.c'
 386         driver_test_names += 'link_bonding_mode4_autotest'
 387     endif
 388 endif
 389 if dpdk_conf.has('RTE_NET_RING')
 390     test_deps += 'net_ring'
 391     test_sources += 'test_pmd_ring_perf.c'
 392     test_sources += 'test_pmd_ring.c'
 393     test_sources += 'test_event_eth_tx_adapter.c'
 394     test_sources += 'sample_packet_forward.c'
 395     fast_tests += [['ring_pmd_autotest', true, true]]
 396     perf_test_names += 'ring_pmd_perf_autotest'
 397     fast_tests += [['event_eth_tx_adapter_autotest', false, true]]
 398     if dpdk_conf.has('RTE_LIB_BITRATESTATS')
 399         test_sources += 'test_bitratestats.c'
 400         fast_tests += [['bitratestats_autotest', true, true]]
 401     endif
 402     if dpdk_conf.has('RTE_LIB_LATENCYSTATS')
 403         test_sources += 'test_latencystats.c'
 404         fast_tests += [['latencystats_autotest', true, true]]
 405     endif
 406     if dpdk_conf.has('RTE_LIB_PDUMP')
 407         test_sources += 'test_pdump.c'
 408         fast_tests += [['pdump_autotest', true, false]]
 409     endif
 410 endif
 411 if dpdk_conf.has('RTE_NET_NULL')
 412     test_deps += 'net_null'
 413     test_sources += 'test_vdev.c'
 414     fast_tests += [['vdev_autotest', true, true]]
 415 endif
 416
 417 if dpdk_conf.has('RTE_HAS_LIBPCAP')
 418     ext_deps += pcap_dep
 419     if dpdk_conf.has('RTE_LIB_PCAPNG')
 420         test_sources += 'test_pcapng.c'
 421     endif
 422 endif
 423
 424 if cc.has_argument('-Wno-format-truncation')
 425     cflags += '-Wno-format-truncation'
 426 endif
 427
 428 # Strict-aliasing rules are violated by uint8_t[] to context size casts.
 429 cflags += '-fno-strict-aliasing'
 430
 431 # Enable using internal APIs in unit tests
 432 cflags += ['-DALLOW_INTERNAL_API']
 433
 434 test_dep_objs = []
 435 if dpdk_conf.has('RTE_LIB_COMPRESSDEV')
 436     compress_test_dep = dependency('zlib', required: false, method: 'pkg-config')
 437     if compress_test_dep.found()
 438         test_dep_objs += compress_test_dep
 439         test_sources += 'test_compressdev.c'
 440         fast_tests += [['compressdev_autotest', false, true]]
 441     endif
 442 endif
 443
 444 if dpdk_conf.has('RTE_CRYPTO_SCHEDULER')
 445     driver_test_names += 'cryptodev_scheduler_autotest'
 446     test_deps += 'crypto_scheduler'
 447 endif
 448
 449 foreach d:test_deps
 450     def_lib = get_option('default_library')
 451     test_dep_objs += get_variable(def_lib + '_rte_' + d)
 452 endforeach
 453
 454 link_libs = []
 455 if get_option('default_library') == 'static'
 456     link_libs = dpdk_static_libraries + dpdk_drivers
 457 endif
 458
 459 dpdk_test = executable('dpdk-test',
 460         test_sources,
 461         link_whole: link_libs,
 462         dependencies: test_dep_objs + ext_deps,
 463         c_args: cflags,
 464         install_rpath: join_paths(get_option('prefix'),
 465              driver_install_path),
 466         install: true)
 467
 468 has_hugepage = run_command(py3, 'has_hugepage.py', check: true).stdout().strip() != '0'
 469 message('hugepage availability: @0@'.format(has_hugepage))
 470
 471 # some perf tests (eg: memcpy perf autotest)take very long
 472 # to complete, so timeout to 10 minutes
 473 timeout_seconds = 600
 474 timeout_seconds_fast = 10
 475
 476 foreach arg : fast_tests
 477     test_args = []
 478     run_test = true
 479     if not has_hugepage
 480         if arg[1]
 481             test_args += ['--no-huge', '-m', '2048']
 482         else
 483             run_test = false
 484         endif
 485     endif
 486
 487     if get_option('b_sanitize') == 'address' or get_option('b_sanitize') == 'address,undefined'
 488         if not arg[2]
 489             run_test = false
 490         endif
 491     endif
 492
 493     if (get_option('default_library') == 'shared' and
 494         arg[0] == 'event_eth_tx_adapter_autotest')
 495         foreach drv:dpdk_drivers
 496             test_args += ['-d', drv.full_path().split('.a')[0] + '.so']
 497         endforeach
 498     endif
 499     if is_linux
 500         test_args += ['--file-prefix=@0@'.format(arg[0])]
 501     endif
 502
 503     if run_test
 504         test(arg[0], dpdk_test,
 505                 env : ['DPDK_TEST=' + arg[0]],
 506                 args : test_args,
 507                 timeout : timeout_seconds_fast,
 508                 is_parallel : false,
 509                 suite : 'fast-tests')
 510         if not is_windows and arg[0] == 'trace_autotest'
 511             test_args += ['--trace=.*']
 512             test_args += ['--trace-dir=@0@'.format(meson.current_build_dir())]
 513             test(arg[0] + '_with_traces', dpdk_test,
 514                     env : ['DPDK_TEST=' + arg[0]],
 515                     args : test_args,
 516                     timeout : timeout_seconds_fast,
 517                     is_parallel : false,
 518                     suite : 'fast-tests')
 519         endif
 520     endif
 521 endforeach
 522
 523 foreach arg : perf_test_names
 524     test(arg, dpdk_test,
 525             env : ['DPDK_TEST=' + arg],
 526             timeout : timeout_seconds,
 527             is_parallel : false,
 528             suite : 'perf-tests')
 529 endforeach
 530
 531 foreach arg : driver_test_names
 532     test(arg, dpdk_test,
 533             env : ['DPDK_TEST=' + arg],
 534             timeout : timeout_seconds,
 535             is_parallel : false,
 536             suite : 'driver-tests')
 537 endforeach
 538
 539 foreach arg : dump_test_names
 540     test(arg, dpdk_test,
 541             env : ['DPDK_TEST=' + arg],
 542             timeout : timeout_seconds,
 543             is_parallel : false,
 544             suite : 'debug-tests')
 545 endforeach
 546
 547 foreach arg : extra_test_names
 548     test(arg, dpdk_test,
 549             env : ['DPDK_TEST=' + arg],
 550             timeout : timeout_seconds,
 551             is_parallel : false,
 552             suite : 'extra-tests')
 553 endforeach