config/arm/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation.
   3 # Copyright(c) 2017 Cavium, Inc
   4
   5 # for checking defines we need to use the correct compiler flags
   6 march_opt = '-march=@0@'.format(machine)
   7
   8 arm_force_native_march = false
   9 arm_force_default_march = (machine == 'default')
  10
  11 flags_common_default = [
  12         # Accelarate rte_memcpy. Be sure to run unit test (memcpy_perf_autotest)
  13         # to determine the best threshold in code. Refer to notes in source file
  14         # (lib/librte_eal/common/include/arch/arm/rte_memcpy_64.h) for more info.
  15         ['RTE_ARCH_ARM64_MEMCPY', false],
  16         #       ['RTE_ARM64_MEMCPY_ALIGNED_THRESHOLD', 2048],
  17         #       ['RTE_ARM64_MEMCPY_UNALIGNED_THRESHOLD', 512],
  18         # Leave below RTE_ARM64_MEMCPY_xxx options commented out, unless there're
  19         # strong reasons.
  20         #       ['RTE_ARM64_MEMCPY_SKIP_GCC_VER_CHECK', false],
  21         #       ['RTE_ARM64_MEMCPY_ALIGN_MASK', 0xF],
  22         #       ['RTE_ARM64_MEMCPY_STRICT_ALIGN', false],
  23
  24         ['RTE_LIBRTE_FM10K_PMD', false],
  25         ['RTE_LIBRTE_SFC_EFX_PMD', false],
  26         ['RTE_LIBRTE_AVP_PMD', false],
  27
  28         ['RTE_SCHED_VECTOR', false],
  29 ]
  30
  31 flags_generic = [
  32         ['RTE_MACHINE', '"armv8a"'],
  33         ['RTE_MAX_LCORE', 256],
  34         ['RTE_USE_C11_MEM_MODEL', true],
  35         ['RTE_CACHE_LINE_SIZE', 128]]
  36 flags_arm = [
  37         ['RTE_MACHINE', '"armv8a"'],
  38         ['RTE_MAX_LCORE', 16],
  39         ['RTE_USE_C11_MEM_MODEL', true],
  40         ['RTE_CACHE_LINE_SIZE', 64]]
  41 flags_cavium = [
  42         ['RTE_CACHE_LINE_SIZE', 128],
  43         ['RTE_MAX_NUMA_NODES', 2],
  44         ['RTE_MAX_LCORE', 96],
  45         ['RTE_MAX_VFIO_GROUPS', 128]]
  46 flags_dpaa = [
  47         ['RTE_MACHINE', '"dpaa"'],
  48         ['RTE_USE_C11_MEM_MODEL', true],
  49         ['RTE_CACHE_LINE_SIZE', 64],
  50         ['RTE_MAX_NUMA_NODES', 1],
  51         ['RTE_MAX_LCORE', 16]]
  52 flags_dpaa2 = [
  53         ['RTE_MACHINE', '"dpaa2"'],
  54         ['RTE_USE_C11_MEM_MODEL', true],
  55         ['RTE_CACHE_LINE_SIZE', 64],
  56         ['RTE_MAX_NUMA_NODES', 1],
  57         ['RTE_MAX_LCORE', 16],
  58         ['RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', false]]
  59 flags_armada = [
  60         ['RTE_MACHINE', '"armv8a"'],
  61         ['RTE_CACHE_LINE_SIZE', 64],
  62         ['RTE_MAX_NUMA_NODES', 1],
  63         ['RTE_MAX_LCORE', 16]]
  64
  65 flags_default_extra = []
  66 flags_thunderx_extra = [
  67         ['RTE_MACHINE', '"thunderx"'],
  68         ['RTE_USE_C11_MEM_MODEL', false]]
  69 flags_thunderx2_extra = [
  70         ['RTE_MACHINE', '"thunderx2"'],
  71         ['RTE_CACHE_LINE_SIZE', 64],
  72         ['RTE_MAX_NUMA_NODES', 2],
  73         ['RTE_MAX_LCORE', 256],
  74         ['RTE_USE_C11_MEM_MODEL', true]]
  75 flags_octeontx2_extra = [
  76         ['RTE_MACHINE', '"octeontx2"'],
  77         ['RTE_MAX_NUMA_NODES', 1],
  78         ['RTE_MAX_LCORE', 24],
  79         ['RTE_EAL_IGB_UIO', false],
  80         ['RTE_USE_C11_MEM_MODEL', true]]
  81
  82 machine_args_generic = [
  83         ['default', ['-march=armv8-a+crc']],
  84         ['native', ['-march=native']],
  85         ['0xd03', ['-mcpu=cortex-a53']],
  86         ['0xd04', ['-mcpu=cortex-a35']],
  87         ['0xd07', ['-mcpu=cortex-a57']],
  88         ['0xd08', ['-mcpu=cortex-a72']],
  89         ['0xd09', ['-mcpu=cortex-a73']],
  90         ['0xd0a', ['-mcpu=cortex-a75']]]
  91
  92 machine_args_cavium = [
  93         ['default', ['-march=armv8-a+crc+crypto','-mcpu=thunderx']],
  94         ['native', ['-march=native']],
  95         ['0xa1', ['-mcpu=thunderxt88'], flags_thunderx_extra],
  96         ['0xa2', ['-mcpu=thunderxt81'], flags_thunderx_extra],
  97         ['0xa3', ['-mcpu=thunderxt83'], flags_thunderx_extra],
  98         ['0xaf', ['-march=armv8.1-a+crc+crypto','-mcpu=thunderx2t99'], flags_thunderx2_extra],
  99         ['0xb2', ['-mcpu=octeontx2'], flags_octeontx2_extra]]
 100
 101 ## Arm implementer ID (ARM DDI 0487C.a, Section G7.2.106, Page G7-5321)
 102 impl_generic = ['Generic armv8', flags_generic, machine_args_generic]
 103 impl_0x41 = ['Arm', flags_arm, machine_args_generic]
 104 impl_0x42 = ['Broadcom', flags_generic, machine_args_generic]
 105 impl_0x43 = ['Cavium', flags_cavium, machine_args_cavium]
 106 impl_0x44 = ['DEC', flags_generic, machine_args_generic]
 107 impl_0x49 = ['Infineon', flags_generic, machine_args_generic]
 108 impl_0x4d = ['Motorola', flags_generic, machine_args_generic]
 109 impl_0x4e = ['NVIDIA', flags_generic, machine_args_generic]
 110 impl_0x50 = ['AppliedMicro', flags_generic, machine_args_generic]
 111 impl_0x51 = ['Qualcomm', flags_generic, machine_args_generic]
 112 impl_0x53 = ['Samsung', flags_generic, machine_args_generic]
 113 impl_0x56 = ['Marvell ARMADA', flags_armada, machine_args_generic]
 114 impl_0x69 = ['Intel', flags_generic, machine_args_generic]
 115 impl_dpaa = ['NXP DPAA', flags_dpaa, machine_args_generic]
 116 impl_dpaa2 = ['NXP DPAA2', flags_dpaa2, machine_args_generic]
 117
 118 dpdk_conf.set('RTE_FORCE_INTRINSICS', 1)
 119
 120 if not dpdk_conf.get('RTE_ARCH_64')
 121         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)
 122         dpdk_conf.set('RTE_ARCH_ARM', 1)
 123         dpdk_conf.set('RTE_ARCH_ARMv7', 1)
 124         # the minimum architecture supported, armv7-a, needs the following,
 125         # mk/machine/armv7a/rte.vars.mk sets it too
 126         machine_args += '-mfpu=neon'
 127 else
 128         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 128)
 129         dpdk_conf.set('RTE_ARCH_ARM64', 1)
 130
 131         machine = []
 132         cmd_generic = ['generic', '', '', 'default', '']
 133         cmd_output = cmd_generic # Set generic by default
 134         machine_args = [] # Clear previous machine args
 135         if arm_force_default_march and not meson.is_cross_build()
 136                 machine = impl_generic
 137                 impl_pn = 'default'
 138         elif not meson.is_cross_build()
 139                 # The script returns ['Implementer', 'Variant', 'Architecture',
 140                 # 'Primary Part number', 'Revision']
 141                 detect_vendor = find_program(join_paths(
 142                                 meson.current_source_dir(), 'armv8_machine.py'))
 143                 cmd = run_command(detect_vendor.path())
 144                 if cmd.returncode() == 0
 145                         cmd_output = cmd.stdout().to_lower().strip().split(' ')
 146                 endif
 147                 # Set to generic if variable is not found
 148                 machine = get_variable('impl_' + cmd_output[0], ['generic'])
 149                 if machine[0] == 'generic'
 150                         machine = impl_generic
 151                         cmd_output = cmd_generic
 152                 endif
 153                 impl_pn = cmd_output[3]
 154                 if arm_force_native_march == true
 155                         impl_pn = 'native'
 156                 endif
 157         else
 158                 impl_id = meson.get_cross_property('implementor_id', 'generic')
 159                 impl_pn = meson.get_cross_property('implementor_pn', 'default')
 160                 machine = get_variable('impl_' + impl_id)
 161         endif
 162
 163         # Apply Common Defaults. These settings may be overwritten by machine
 164         # settings later.
 165         foreach flag: flags_common_default
 166                 if flag.length() > 0
 167                         dpdk_conf.set(flag[0], flag[1])
 168                 endif
 169         endforeach
 170
 171         message('Implementer : ' + machine[0])
 172         foreach flag: machine[1]
 173                 if flag.length() > 0
 174                         dpdk_conf.set(flag[0], flag[1])
 175                 endif
 176         endforeach
 177
 178         foreach marg: machine[2]
 179                 if marg[0] == impl_pn
 180                         foreach flag: marg[1]
 181                                 if cc.has_argument(flag)
 182                                         machine_args += flag
 183                                 endif
 184                         endforeach
 185                         # Apply any extra machine specific flags.
 186                         foreach flag: marg.get(2, flags_default_extra)
 187                                 if flag.length() > 0
 188                                         dpdk_conf.set(flag[0], flag[1])
 189                                 endif
 190                         endforeach
 191                 endif
 192         endforeach
 193 endif
 194 message(machine_args)
 195
 196 if (cc.get_define('__ARM_NEON', args: machine_args) != '' or
 197     cc.get_define('__aarch64__', args: machine_args) != '')
 198         dpdk_conf.set('RTE_MACHINE_CPUFLAG_NEON', 1)
 199         compile_time_cpuflags += ['RTE_CPUFLAG_NEON']
 200 endif
 201
 202 if cc.get_define('__ARM_FEATURE_CRC32', args: machine_args) != ''
 203         dpdk_conf.set('RTE_MACHINE_CPUFLAG_CRC32', 1)
 204         compile_time_cpuflags += ['RTE_CPUFLAG_CRC32']
 205 endif
 206
 207 if cc.get_define('__ARM_FEATURE_CRYPTO', args: machine_args) != ''
 208         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AES', 1)
 209         dpdk_conf.set('RTE_MACHINE_CPUFLAG_PMULL', 1)
 210         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA1', 1)
 211         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA2', 1)
 212         compile_time_cpuflags += ['RTE_CPUFLAG_AES', 'RTE_CPUFLAG_PMULL',
 213         'RTE_CPUFLAG_SHA1', 'RTE_CPUFLAG_SHA2']
 214 endif