config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # set the major version, which might be used by drivers and libraries
  18 # depending on the configuration options
  19 pver = meson.project_version().split('.')
  20 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  21 abi_version = run_command(find_program('cat', 'more'),
  22         abi_version_file).stdout().strip()
  23
  24 # Regular libraries have the abi_version as the filename extension
  25 # and have the soname be all but the final part of the abi_version.
  26 # Experimental libraries have soname with '0.major'
  27 # and the filename suffix as 0.majorminor versions,
  28 # e.g. v20.1 => librte_stable.so.20.1, librte_experimental.so.0.201
  29 #    sonames => librte_stable.so.20, librte_experimental.so.0.20
  30 # e.g. v20.0.1 => librte_stable.so.20.0.1, librte_experimental.so.0.2001
  31 #      sonames => librte_stable.so.20.0, librte_experimental.so.0.200
  32 abi_va = abi_version.split('.')
  33 stable_so_version = abi_va.length() == 2 ? abi_va[0] : abi_va[0] + '.' + abi_va[1]
  34 experimental_abi_version = '0.' + ''.join(abi_va)
  35 experimental_so_version = '0.' + ''.join(stable_so_version.split('.'))
  36
  37 # extract all version information into the build configuration
  38 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  39 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  40 if pver.get(2).contains('-rc')
  41         rc_ver = pver.get(2).split('-rc')
  42         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  43         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  44         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  45 else
  46         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  47         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  48 # for actual, non-rc releases, set the release value to 99 to ensure releases
  49 # have higher version numbers than their respective release candidates
  50         dpdk_conf.set('RTE_VER_RELEASE', 99)
  51 endif
  52
  53 pmd_subdir_opt = get_option('drivers_install_subdir')
  54 if pmd_subdir_opt.contains('<VERSION>')
  55         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  56 endif
  57 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  58 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  59
  60 # driver .so files often depend upon the bus drivers for their connect bus,
  61 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  62 # to be in the library path, so symlink the drivers from the main lib directory.
  63 meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  64                 get_option('libdir'),
  65                 pmd_subdir_opt)
  66
  67 # set the machine type and cflags for it
  68 if meson.is_cross_build()
  69         machine = host_machine.cpu()
  70 else
  71         machine = get_option('machine')
  72 endif
  73
  74 # machine type 'default' is special, it defaults to the per arch agreed common
  75 # minimal baseline needed for DPDK.
  76 # That might not be the most optimized, but the most portable version while
  77 # still being able to support the CPU features required for DPDK.
  78 # This can be bumped up by the DPDK project, but it can never be an
  79 # invariant like 'native'
  80 if machine == 'default'
  81         if host_machine.cpu_family().startswith('x86')
  82                 # matches the old pre-meson build systems default
  83                 machine = 'corei7'
  84         elif host_machine.cpu_family().startswith('arm')
  85                 machine = 'armv7-a'
  86         elif host_machine.cpu_family().startswith('aarch')
  87                 # arm64 manages defaults in config/arm/meson.build
  88                 machine = 'default'
  89         elif host_machine.cpu_family().startswith('ppc')
  90                 machine = 'power8'
  91         endif
  92 endif
  93
  94 dpdk_conf.set('RTE_MACHINE', machine)
  95 machine_args = []
  96
  97 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  98 if host_machine.cpu_family().startswith('ppc')
  99         machine_args += '-mcpu=' + machine
 100         machine_args += '-mtune=' + machine
 101 else
 102         machine_args += '-march=' + machine
 103 endif
 104
 105 toolchain = cc.get_id()
 106 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 107 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 108
 109 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 110
 111 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 112
 113 # use pthreads
 114 add_project_link_arguments('-pthread', language: 'c')
 115 dpdk_extra_ldflags += '-pthread'
 116
 117 # on some OS, maths functions are in a separate library
 118 if cc.find_library('m', required : false).found()
 119         # some libs depend on maths lib
 120         add_project_link_arguments('-lm', language: 'c')
 121         dpdk_extra_ldflags += '-lm'
 122 endif
 123
 124 # for linux link against dl, for bsd execinfo
 125 if is_linux
 126         link_lib = 'dl'
 127 elif is_freebsd
 128         link_lib = 'execinfo'
 129 else
 130         link_lib = ''
 131 endif
 132
 133 # if link_lib is empty, do not add it to project properties
 134 if link_lib != ''
 135         add_project_link_arguments('-l' + link_lib, language: 'c')
 136         dpdk_extra_ldflags += '-l' + link_lib
 137 endif
 138
 139 # check for libraries used in multiple places in DPDK
 140 has_libnuma = 0
 141 numa_dep = cc.find_library('numa', required: false)
 142 if numa_dep.found() and cc.has_header('numaif.h')
 143         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 144         has_libnuma = 1
 145         add_project_link_arguments('-lnuma', language: 'c')
 146         dpdk_extra_ldflags += '-lnuma'
 147 endif
 148
 149 # check for libbsd
 150 libbsd = dependency('libbsd', required: false)
 151 if libbsd.found()
 152         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 153 endif
 154
 155 # check for pcap
 156 pcap_dep = dependency('pcap', required: false)
 157 if pcap_dep.found()
 158         # pcap got a pkg-config file only in 1.9.0 and before that meson uses
 159         # an internal pcap-config finder, which is not compatible with
 160         # cross-compilation, so try to fallback to find_library
 161         pcap_dep = cc.find_library('pcap', required: false)
 162 endif
 163 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 164         dpdk_conf.set('RTE_PORT_PCAP', 1)
 165         dpdk_extra_ldflags += '-lpcap'
 166 endif
 167
 168 # add -include rte_config to cflags
 169 add_project_arguments('-include', 'rte_config.h', language: 'c')
 170
 171 # enable extra warnings and disable any unwanted warnings
 172 warning_flags = [
 173         # -Wall is added by meson by default, so add -Wextra only
 174         '-Wextra',
 175
 176         # additional warnings in alphabetical order
 177         '-Wcast-qual',
 178         '-Wdeprecated',
 179         '-Wformat-nonliteral',
 180         '-Wformat-security',
 181         '-Wmissing-declarations',
 182         '-Wmissing-prototypes',
 183         '-Wnested-externs',
 184         '-Wold-style-definition',
 185         '-Wpointer-arith',
 186         '-Wsign-compare',
 187         '-Wstrict-prototypes',
 188         '-Wundef',
 189         '-Wwrite-strings',
 190
 191         # globally disabled warnings
 192         '-Wno-address-of-packed-member',
 193         '-Wno-packed-not-aligned',
 194         '-Wno-missing-field-initializers'
 195 ]
 196 if not dpdk_conf.get('RTE_ARCH_64')
 197 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 198         warning_flags += '-Wno-pointer-to-int-cast'
 199 endif
 200 foreach arg: warning_flags
 201         if cc.has_argument(arg)
 202                 add_project_arguments(arg, language: 'c')
 203         endif
 204 endforeach
 205
 206 # set other values pulled from the build options
 207 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 208 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 209 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 210 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 211 # values which have defaults which may be overridden
 212 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 213 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 214 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 215
 216
 217 compile_time_cpuflags = []
 218 if host_machine.cpu_family().startswith('x86')
 219         arch_subdir = 'x86'
 220 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 221         arch_subdir = 'arm'
 222 elif host_machine.cpu_family().startswith('ppc')
 223         arch_subdir = 'ppc_64'
 224 endif
 225 subdir(arch_subdir)
 226 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 227
 228 # set the install path for the drivers
 229 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 230
 231 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 232
 233 # enable VFIO only if it is linux OS
 234 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 235
 236 # specify -D_GNU_SOURCE unconditionally
 237 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 238
 239 # specify -D__BSD_VISIBLE for FreeBSD
 240 if is_freebsd
 241         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 242 endif
 243
 244 if get_option('b_lto')
 245         if cc.has_argument('-ffat-lto-objects')
 246                 add_project_arguments('-ffat-lto-objects', language: 'c')
 247         else
 248                 error('compiler does not support fat LTO objects - please turn LTO off')
 249         endif
 250         # workaround for gcc bug 81440
 251         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 252                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 253                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 254         endif
 255 endif