config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8     error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14     set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'), abi_version_file).stdout().strip()
  26
  27 # Libraries have the abi_version as the filename extension
  28 # and have the soname be all but the final part of the abi_version.
  29 # e.g. v20.1 => librte_foo.so.20.1
  30 #    sonames => librte_foo.so.20
  31 so_version = abi_version.split('.')[0]
  32
  33 # extract all version information into the build configuration
  34 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  35 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  36 if pver.get(2).contains('-rc')
  37     rc_ver = pver.get(2).split('-rc')
  38     dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  39     dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  40     dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  41 else
  42     dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  43     dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  44 # for actual, non-rc releases, set the release value to 99 to ensure releases
  45 # have higher version numbers than their respective release candidates
  46     dpdk_conf.set('RTE_VER_RELEASE', 99)
  47 endif
  48
  49 pmd_subdir_opt = get_option('drivers_install_subdir')
  50 if pmd_subdir_opt.contains('<VERSION>')
  51     pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  52 endif
  53 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  54 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  55
  56 # driver .so files often depend upon the bus drivers for their connect bus,
  57 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  58 # to be in the library path, so symlink the drivers from the main lib directory.
  59 if not is_windows
  60     meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  61             get_option('libdir'), pmd_subdir_opt)
  62 elif meson.version().version_compare('>=0.55.0')
  63     # 0.55.0 is required to use external program with add_install_script
  64     meson.add_install_script(py3,
  65             files('../buildtools/symlink-drivers-solibs.py'),
  66             get_option('libdir'), pmd_subdir_opt, get_option('bindir'))
  67 endif
  68
  69 # init disable/enable driver lists that will be populated in different places
  70 disable_drivers = ''
  71 enable_drivers = ''
  72
  73 platform = get_option('platform')
  74
  75 # set the cpu_instruction_set and cflags for it
  76 if meson.is_cross_build()
  77     cpu_instruction_set = host_machine.cpu()
  78 else
  79     cpu_instruction_set = get_option('cpu_instruction_set')
  80     machine = get_option('machine')
  81     if machine != 'auto'
  82         warning('The "machine" option is deprecated. ' +
  83                 'Please use "cpu_instruction_set" instead.')
  84         if cpu_instruction_set != 'auto'
  85             error('Setting both "machine" and ' +
  86                 '"cpu_instruction_set" is unsupported.')
  87         endif
  88         cpu_instruction_set = machine
  89         if cpu_instruction_set == 'default'
  90             cpu_instruction_set = 'generic'
  91         endif
  92     endif
  93 endif
  94
  95 if platform == 'native'
  96     if cpu_instruction_set == 'auto'
  97         cpu_instruction_set = 'native'
  98     endif
  99 elif platform == 'generic'
 100     if cpu_instruction_set == 'auto'
 101         cpu_instruction_set = 'generic'
 102     endif
 103 endif
 104
 105 # cpu_instruction_set 'generic' is special, it selects the per arch agreed
 106 # common minimal baseline needed for DPDK. cpu_instruction_set 'default' is
 107 # also supported with the same meaning for backwards compatibility.
 108 # That might not be the most optimized, but the most portable version while
 109 # still being able to support the CPU features required for DPDK.
 110 # This can be bumped up by the DPDK project, but it can never be an
 111 # invariant like 'native'
 112 if cpu_instruction_set == 'generic'
 113     if host_machine.cpu_family().startswith('x86')
 114         # matches the old pre-meson build systems generic cpu_instruction_set
 115         cpu_instruction_set = 'corei7'
 116     elif host_machine.cpu_family().startswith('arm')
 117         cpu_instruction_set = 'armv7-a'
 118     elif host_machine.cpu_family().startswith('aarch')
 119         # arm64 manages generic config in config/arm/meson.build
 120         cpu_instruction_set = 'generic'
 121     elif host_machine.cpu_family().startswith('ppc')
 122         cpu_instruction_set = 'power8'
 123     endif
 124 endif
 125
 126 dpdk_conf.set('RTE_MACHINE', cpu_instruction_set)
 127 machine_args = []
 128
 129 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
 130 if host_machine.cpu_family().startswith('ppc')
 131     machine_args += '-mcpu=' + cpu_instruction_set
 132     machine_args += '-mtune=' + cpu_instruction_set
 133 else
 134     machine_args += '-march=' + cpu_instruction_set
 135 endif
 136
 137 toolchain = cc.get_id()
 138 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 139 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 140
 141 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 142 dpdk_conf.set('RTE_ARCH_32', cc.sizeof('void *') == 4)
 143
 144 if not is_windows
 145     add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 146 endif
 147
 148 # use pthreads if available for the platform
 149 if not is_windows
 150     add_project_link_arguments('-pthread', language: 'c')
 151     dpdk_extra_ldflags += '-pthread'
 152 endif
 153
 154 # on some OS, maths functions are in a separate library
 155 if cc.find_library('m', required : false).found()
 156     # some libs depend on maths lib
 157     add_project_link_arguments('-lm', language: 'c')
 158     dpdk_extra_ldflags += '-lm'
 159 endif
 160
 161 if is_linux
 162     link_lib = 'dl'
 163 else
 164     link_lib = ''
 165 endif
 166
 167 # if link_lib is empty, do not add it to project properties
 168 if link_lib != ''
 169     add_project_link_arguments('-l' + link_lib, language: 'c')
 170     dpdk_extra_ldflags += '-l' + link_lib
 171 endif
 172
 173 # check for libraries used in multiple places in DPDK
 174 has_libnuma = 0
 175 find_libnuma = true
 176 if meson.is_cross_build() and not meson.get_cross_property('numa', true)
 177     # don't look for libnuma if explicitly disabled in cross build
 178     find_libnuma = false
 179 endif
 180 if find_libnuma
 181     numa_dep = cc.find_library('numa', required: false)
 182     if numa_dep.found() and cc.has_header('numaif.h')
 183         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 184         has_libnuma = 1
 185         add_project_link_arguments('-lnuma', language: 'c')
 186         dpdk_extra_ldflags += '-lnuma'
 187     endif
 188 endif
 189
 190 has_libfdt = 0
 191 fdt_dep = cc.find_library('libfdt', required: false)
 192 if fdt_dep.found() and cc.has_header('fdt.h')
 193     dpdk_conf.set10('RTE_HAS_LIBFDT', true)
 194     has_libfdt = 1
 195     add_project_link_arguments('-lfdt', language: 'c')
 196     dpdk_extra_ldflags += '-lfdt'
 197 endif
 198
 199 libexecinfo = cc.find_library('libexecinfo', required: false)
 200 if libexecinfo.found() and cc.has_header('execinfo.h')
 201     add_project_link_arguments('-lexecinfo', language: 'c')
 202     dpdk_extra_ldflags += '-lexecinfo'
 203 endif
 204
 205 libarchive = dependency('libarchive', required: false, method: 'pkg-config')
 206 if libarchive.found()
 207     dpdk_conf.set('RTE_HAS_LIBARCHIVE', 1)
 208     # Push libarchive link dependency at the project level to support
 209     # statically linking dpdk apps. Details at:
 210     # https://inbox.dpdk.org/dev/20210605004024.660267a1@sovereign/
 211     add_project_link_arguments('-larchive', language: 'c')
 212     dpdk_extra_ldflags += '-larchive'
 213 endif
 214
 215 # check for libbsd
 216 libbsd = dependency('libbsd', required: false, method: 'pkg-config')
 217 if libbsd.found()
 218     dpdk_conf.set('RTE_USE_LIBBSD', 1)
 219 endif
 220
 221 # check for pcap
 222 pcap_dep = dependency('libpcap', required: false, method: 'pkg-config')
 223 pcap_lib = is_windows ? 'wpcap' : 'pcap'
 224 if not pcap_dep.found()
 225     # pcap got a pkg-config file only in 1.9.0
 226     pcap_dep = cc.find_library(pcap_lib, required: false)
 227 endif
 228 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 229     dpdk_conf.set('RTE_PORT_PCAP', 1)
 230     dpdk_extra_ldflags += '-l@0@'.format(pcap_lib)
 231 endif
 232
 233 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 234 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 235     atomic_dep = cc.find_library('atomic', required: true)
 236     add_project_link_arguments('-latomic', language: 'c')
 237     dpdk_extra_ldflags += '-latomic'
 238 endif
 239
 240 # add -include rte_config to cflags
 241 add_project_arguments('-include', 'rte_config.h', language: 'c')
 242
 243 # enable extra warnings and disable any unwanted warnings
 244 warning_flags = [
 245         # -Wall is added by meson by default, so add -Wextra only
 246         '-Wextra',
 247
 248         # additional warnings in alphabetical order
 249         '-Wcast-qual',
 250         '-Wdeprecated',
 251         '-Wformat',
 252         '-Wformat-nonliteral',
 253         '-Wformat-security',
 254         '-Wmissing-declarations',
 255         '-Wmissing-prototypes',
 256         '-Wnested-externs',
 257         '-Wold-style-definition',
 258         '-Wpointer-arith',
 259         '-Wsign-compare',
 260         '-Wstrict-prototypes',
 261         '-Wundef',
 262         '-Wwrite-strings',
 263
 264         # globally disabled warnings
 265         '-Wno-address-of-packed-member',
 266         '-Wno-packed-not-aligned',
 267         '-Wno-missing-field-initializers',
 268 ]
 269 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
 270 # FIXME: Bugzilla 396
 271     warning_flags += '-Wno-zero-length-bounds'
 272 endif
 273 if not dpdk_conf.get('RTE_ARCH_64')
 274 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 275     warning_flags += '-Wno-pointer-to-int-cast'
 276 endif
 277 if cc.get_id() == 'intel'
 278     warning_ids = [181, 188, 2203, 2279, 2557, 3179, 3656]
 279     foreach i:warning_ids
 280         warning_flags += '-diag-disable=@0@'.format(i)
 281     endforeach
 282 endif
 283 foreach arg: warning_flags
 284     if cc.has_argument(arg)
 285         add_project_arguments(arg, language: 'c')
 286     endif
 287 endforeach
 288
 289 # set other values pulled from the build options
 290 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 291 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 292 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 293 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 294 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 295 # values which have defaults which may be overridden
 296 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 297 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 298 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 299 if dpdk_conf.get('RTE_ARCH_64')
 300     dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
 301 else # for 32-bit we need smaller reserved memory areas
 302     dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
 303 endif
 304
 305
 306 compile_time_cpuflags = []
 307 subdir(arch_subdir)
 308 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 309
 310 # apply cross-specific options
 311 if meson.is_cross_build()
 312     # configure RTE_MAX_LCORE and RTE_MAX_NUMA_NODES from cross file
 313     cross_max_lcores = meson.get_cross_property('max_lcores', 0)
 314     if cross_max_lcores != 0
 315         message('Setting RTE_MAX_LCORE from cross file')
 316         dpdk_conf.set('RTE_MAX_LCORE', cross_max_lcores)
 317     endif
 318     cross_max_numa_nodes = meson.get_cross_property('max_numa_nodes', 0)
 319     if cross_max_numa_nodes != 0
 320         message('Setting RTE_MAX_NUMA_NODES from cross file')
 321         dpdk_conf.set('RTE_MAX_NUMA_NODES', cross_max_numa_nodes)
 322     endif
 323 endif
 324
 325 # set the install path for the drivers
 326 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 327
 328 install_headers(['rte_config.h'],
 329         subdir: get_option('include_subdir_arch'))
 330
 331 # enable VFIO only if it is linux OS
 332 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 333
 334 # specify -D_GNU_SOURCE unconditionally
 335 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 336
 337 # specify -D__BSD_VISIBLE for FreeBSD
 338 if is_freebsd
 339     add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 340 endif
 341
 342 if is_windows
 343     # VirtualAlloc2() is available since Windows 10 / Server 2016.
 344     add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
 345
 346     # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 347     if cc.get_id() == 'gcc'
 348         add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 349     endif
 350
 351     # Disable secure CRT deprecated warnings for clang
 352     if cc.get_id() == 'clang'
 353         add_project_arguments('-D_CRT_SECURE_NO_WARNINGS', language: 'c')
 354     endif
 355
 356     add_project_link_arguments('-lws2_32', language: 'c')
 357
 358     # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
 359     # in Windows SDK, while MinGW exports it by advapi32.a.
 360     if is_ms_linker
 361         add_project_link_arguments('-lmincore', language: 'c')
 362     endif
 363
 364     add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
 365     add_project_link_arguments('-ldbghelp', language: 'c')
 366 endif
 367
 368 if get_option('b_lto')
 369     if cc.has_argument('-ffat-lto-objects')
 370         add_project_arguments('-ffat-lto-objects', language: 'c')
 371     else
 372         error('compiler does not support fat LTO objects - please turn LTO off')
 373     endif
 374     # workaround for gcc bug 81440
 375     if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 376         add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 377         add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 378     endif
 379 endif
 380
 381 if get_option('default_library') == 'both'
 382     error( '''
 383  Unsupported value "both" for "default_library" option.
 384
 385  NOTE: DPDK always builds both shared and static libraries.  Please set
 386  "default_library" to either "static" or "shared" to select default linkage
 387  for apps and any examples.''')
 388 endif