config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # set the major version, which might be used by drivers and libraries
  18 # depending on the configuration options
  19 pver = meson.project_version().split('.')
  20 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  21 abi_version = run_command(find_program('cat', 'more'),
  22         files('../ABI_VERSION')).stdout().strip()
  23 # experimental libraries are versioned as 0.majorminor versions, e.g. 0.201
  24 ever = abi_version.split('.')
  25 experimental_abi_version = '0.@0@@1@'.format(ever.get(0), ever.get(1))
  26
  27 # extract all version information into the build configuration
  28 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  29 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  30 if pver.get(2).contains('-rc')
  31         rc_ver = pver.get(2).split('-rc')
  32         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  33         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  34         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  35 else
  36         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  37         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  38 # for actual, non-rc releases, set the release value to 99 to ensure releases
  39 # have higher version numbers than their respective release candidates
  40         dpdk_conf.set('RTE_VER_RELEASE', 99)
  41 endif
  42
  43 pmd_subdir_opt = get_option('drivers_install_subdir')
  44 if pmd_subdir_opt.contains('<VERSION>')
  45         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  46 endif
  47 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  48 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  49
  50 # driver .so files often depend upon the bus drivers for their connect bus,
  51 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  52 # to be in the library path, so symlink the drivers from the main lib directory.
  53 meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  54                 get_option('libdir'),
  55                 pmd_subdir_opt)
  56
  57 # set the machine type and cflags for it
  58 if meson.is_cross_build()
  59         machine = host_machine.cpu()
  60 else
  61         machine = get_option('machine')
  62 endif
  63
  64 # machine type 'default' is special, it defaults to the per arch agreed common
  65 # minimal baseline needed for DPDK.
  66 # That might not be the most optimized, but the most portable version while
  67 # still being able to support the CPU features required for DPDK.
  68 # This can be bumped up by the DPDK project, but it can never be an
  69 # invariant like 'native'
  70 if machine == 'default'
  71         if host_machine.cpu_family().startswith('x86')
  72                 # matches the old pre-meson build systems default
  73                 machine = 'corei7'
  74         elif host_machine.cpu_family().startswith('arm')
  75                 machine = 'armv7-a'
  76         elif host_machine.cpu_family().startswith('aarch')
  77                 # arm64 manages defaults in config/arm/meson.build
  78                 machine = 'default'
  79         elif host_machine.cpu_family().startswith('ppc')
  80                 machine = 'power8'
  81         endif
  82 endif
  83
  84 dpdk_conf.set('RTE_MACHINE', machine)
  85 machine_args = []
  86
  87 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  88 if host_machine.cpu_family().startswith('ppc')
  89         machine_args += '-mcpu=' + machine
  90         machine_args += '-mtune=' + machine
  91 else
  92         machine_args += '-march=' + machine
  93 endif
  94
  95 toolchain = cc.get_id()
  96 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  97 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  98
  99 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 100
 101 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 102
 103 # use pthreads
 104 add_project_link_arguments('-pthread', language: 'c')
 105 dpdk_extra_ldflags += '-pthread'
 106
 107 # on some OS, maths functions are in a separate library
 108 if cc.find_library('libm', required : false).found()
 109         # some libs depend on maths lib
 110         add_project_link_arguments('-lm', language: 'c')
 111         dpdk_extra_ldflags += '-lm'
 112 endif
 113
 114 # for linux link against dl, for bsd execinfo
 115 if is_linux
 116         link_lib = 'dl'
 117 elif is_freebsd
 118         link_lib = 'execinfo'
 119 else
 120         link_lib = ''
 121 endif
 122
 123 # if link_lib is empty, do not add it to project properties
 124 if link_lib != ''
 125         add_project_link_arguments('-l' + link_lib, language: 'c')
 126         dpdk_extra_ldflags += '-l' + link_lib
 127 endif
 128
 129 # check for libraries used in multiple places in DPDK
 130 has_libnuma = 0
 131 numa_dep = cc.find_library('numa', required: false)
 132 if numa_dep.found() and cc.has_header('numaif.h')
 133         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 134         has_libnuma = 1
 135         add_project_link_arguments('-lnuma', language: 'c')
 136         dpdk_extra_ldflags += '-lnuma'
 137 endif
 138
 139 # check for libbsd
 140 libbsd = dependency('libbsd', required: false)
 141 if libbsd.found()
 142         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 143 endif
 144
 145 # check for pcap
 146 pcap_dep = dependency('pcap', required: false)
 147 if pcap_dep.found()
 148         # pcap got a pkg-config file only in 1.9.0 and before that meson uses
 149         # an internal pcap-config finder, which is not compatible with
 150         # cross-compilation, so try to fallback to find_library
 151         pcap_dep = cc.find_library('pcap', required: false)
 152 endif
 153 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 154         dpdk_conf.set('RTE_PORT_PCAP', 1)
 155         dpdk_extra_ldflags += '-lpcap'
 156 endif
 157
 158 # add -include rte_config to cflags
 159 add_project_arguments('-include', 'rte_config.h', language: 'c')
 160
 161 # enable extra warnings and disable any unwanted warnings
 162 warning_flags = [
 163         # -Wall is added by meson by default, so add -Wextra only
 164         '-Wextra',
 165
 166         # additional warnings in alphabetical order
 167         '-Wcast-qual',
 168         '-Wdeprecated',
 169         '-Wformat-nonliteral',
 170         '-Wformat-security',
 171         '-Wmissing-declarations',
 172         '-Wmissing-prototypes',
 173         '-Wnested-externs',
 174         '-Wold-style-definition',
 175         '-Wpointer-arith',
 176         '-Wsign-compare',
 177         '-Wstrict-prototypes',
 178         '-Wundef',
 179         '-Wwrite-strings',
 180
 181         # globally disabled warnings
 182         '-Wno-address-of-packed-member',
 183         '-Wno-packed-not-aligned',
 184         '-Wno-missing-field-initializers'
 185 ]
 186 if not dpdk_conf.get('RTE_ARCH_64')
 187 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 188         warning_flags += '-Wno-pointer-to-int-cast'
 189 endif
 190 foreach arg: warning_flags
 191         if cc.has_argument(arg)
 192                 add_project_arguments(arg, language: 'c')
 193         endif
 194 endforeach
 195
 196 # set other values pulled from the build options
 197 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 198 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 199 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 200 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 201 # values which have defaults which may be overridden
 202 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 203 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 204 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 205
 206
 207 compile_time_cpuflags = []
 208 if host_machine.cpu_family().startswith('x86')
 209         arch_subdir = 'x86'
 210 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 211         arch_subdir = 'arm'
 212 elif host_machine.cpu_family().startswith('ppc')
 213         arch_subdir = 'ppc_64'
 214 endif
 215 subdir(arch_subdir)
 216 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 217
 218 # set the install path for the drivers
 219 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 220
 221 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 222
 223 # enable VFIO only if it is linux OS
 224 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 225
 226 # specify -D_GNU_SOURCE unconditionally
 227 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 228
 229 # specify -D__BSD_VISIBLE for FreeBSD
 230 if is_freebsd
 231         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 232 endif
 233
 234 if get_option('b_lto')
 235         if cc.has_argument('-ffat-lto-objects')
 236                 add_project_arguments('-ffat-lto-objects', language: 'c')
 237         else
 238                 error('compiler does not support fat LTO objects - please turn LTO off')
 239         endif
 240         # workaround for gcc bug 81440
 241         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 242                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 243                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 244         endif
 245 endif