config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'),
  26         abi_version_file).stdout().strip()
  27
  28 # Regular libraries have the abi_version as the filename extension
  29 # and have the soname be all but the final part of the abi_version.
  30 # Experimental libraries have soname with '0.major'
  31 # and the filename suffix as 0.majorminor versions,
  32 # e.g. v20.1 => librte_stable.so.20.1, librte_experimental.so.0.201
  33 #    sonames => librte_stable.so.20, librte_experimental.so.0.20
  34 # e.g. v20.0.1 => librte_stable.so.20.0.1, librte_experimental.so.0.2001
  35 #      sonames => librte_stable.so.20.0, librte_experimental.so.0.200
  36 abi_va = abi_version.split('.')
  37 stable_so_version = abi_va.length() == 2 ? abi_va[0] : abi_va[0] + '.' + abi_va[1]
  38 experimental_abi_version = '0.' + abi_va[0] + abi_va[1] + '.' + abi_va[2]
  39 experimental_so_version = experimental_abi_version
  40
  41 # extract all version information into the build configuration
  42 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  43 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  44 if pver.get(2).contains('-rc')
  45         rc_ver = pver.get(2).split('-rc')
  46         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  47         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  48         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  49 else
  50         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  51         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  52 # for actual, non-rc releases, set the release value to 99 to ensure releases
  53 # have higher version numbers than their respective release candidates
  54         dpdk_conf.set('RTE_VER_RELEASE', 99)
  55 endif
  56
  57 pmd_subdir_opt = get_option('drivers_install_subdir')
  58 if pmd_subdir_opt.contains('<VERSION>')
  59         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  60 endif
  61 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  62 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  63
  64 # driver .so files often depend upon the bus drivers for their connect bus,
  65 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  66 # to be in the library path, so symlink the drivers from the main lib directory.
  67 meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  68                 get_option('libdir'),
  69                 pmd_subdir_opt)
  70
  71 # set the machine type and cflags for it
  72 if meson.is_cross_build()
  73         machine = host_machine.cpu()
  74 else
  75         machine = get_option('machine')
  76 endif
  77
  78 # machine type 'default' is special, it defaults to the per arch agreed common
  79 # minimal baseline needed for DPDK.
  80 # That might not be the most optimized, but the most portable version while
  81 # still being able to support the CPU features required for DPDK.
  82 # This can be bumped up by the DPDK project, but it can never be an
  83 # invariant like 'native'
  84 if machine == 'default'
  85         if host_machine.cpu_family().startswith('x86')
  86                 # matches the old pre-meson build systems default
  87                 machine = 'corei7'
  88         elif host_machine.cpu_family().startswith('arm')
  89                 machine = 'armv7-a'
  90         elif host_machine.cpu_family().startswith('aarch')
  91                 # arm64 manages defaults in config/arm/meson.build
  92                 machine = 'default'
  93         elif host_machine.cpu_family().startswith('ppc')
  94                 machine = 'power8'
  95         endif
  96 endif
  97
  98 dpdk_conf.set('RTE_MACHINE', machine)
  99 machine_args = []
 100
 101 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
 102 if host_machine.cpu_family().startswith('ppc')
 103         machine_args += '-mcpu=' + machine
 104         machine_args += '-mtune=' + machine
 105 else
 106         machine_args += '-march=' + machine
 107 endif
 108
 109 toolchain = cc.get_id()
 110 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 111 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 112
 113 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 114
 115 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 116
 117 # use pthreads
 118 add_project_link_arguments('-pthread', language: 'c')
 119 dpdk_extra_ldflags += '-pthread'
 120
 121 # on some OS, maths functions are in a separate library
 122 if cc.find_library('m', required : false).found()
 123         # some libs depend on maths lib
 124         add_project_link_arguments('-lm', language: 'c')
 125         dpdk_extra_ldflags += '-lm'
 126 endif
 127
 128 # for linux link against dl, for bsd execinfo
 129 if is_linux
 130         link_lib = 'dl'
 131 elif is_freebsd
 132         link_lib = 'execinfo'
 133 else
 134         link_lib = ''
 135 endif
 136
 137 # if link_lib is empty, do not add it to project properties
 138 if link_lib != ''
 139         add_project_link_arguments('-l' + link_lib, language: 'c')
 140         dpdk_extra_ldflags += '-l' + link_lib
 141 endif
 142
 143 # check for libraries used in multiple places in DPDK
 144 has_libnuma = 0
 145 numa_dep = cc.find_library('numa', required: false)
 146 if numa_dep.found() and cc.has_header('numaif.h')
 147         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 148         has_libnuma = 1
 149         add_project_link_arguments('-lnuma', language: 'c')
 150         dpdk_extra_ldflags += '-lnuma'
 151 endif
 152
 153 # check for libbsd
 154 libbsd = dependency('libbsd', required: false)
 155 if libbsd.found()
 156         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 157 endif
 158
 159 # check for pcap
 160 pcap_dep = dependency('pcap', required: false)
 161 if pcap_dep.found()
 162         # pcap got a pkg-config file only in 1.9.0 and before that meson uses
 163         # an internal pcap-config finder, which is not compatible with
 164         # cross-compilation, so try to fallback to find_library
 165         pcap_dep = cc.find_library('pcap', required: false)
 166 endif
 167 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 168         dpdk_conf.set('RTE_PORT_PCAP', 1)
 169         dpdk_extra_ldflags += '-lpcap'
 170 endif
 171
 172 # add -include rte_config to cflags
 173 add_project_arguments('-include', 'rte_config.h', language: 'c')
 174
 175 # enable extra warnings and disable any unwanted warnings
 176 warning_flags = [
 177         # -Wall is added by meson by default, so add -Wextra only
 178         '-Wextra',
 179
 180         # additional warnings in alphabetical order
 181         '-Wcast-qual',
 182         '-Wdeprecated',
 183         '-Wformat-nonliteral',
 184         '-Wformat-security',
 185         '-Wmissing-declarations',
 186         '-Wmissing-prototypes',
 187         '-Wnested-externs',
 188         '-Wold-style-definition',
 189         '-Wpointer-arith',
 190         '-Wsign-compare',
 191         '-Wstrict-prototypes',
 192         '-Wundef',
 193         '-Wwrite-strings',
 194
 195         # globally disabled warnings
 196         '-Wno-address-of-packed-member',
 197         '-Wno-packed-not-aligned',
 198         '-Wno-missing-field-initializers'
 199 ]
 200 if not dpdk_conf.get('RTE_ARCH_64')
 201 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 202         warning_flags += '-Wno-pointer-to-int-cast'
 203 endif
 204 if cc.get_id() == 'intel'
 205         warning_ids = [188, 2203, 2279, 2557, 3179, 3656]
 206         foreach i:warning_ids
 207                 warning_flags += '-diag-disable=@0@'.format(i)
 208         endforeach
 209 endif
 210 foreach arg: warning_flags
 211         if cc.has_argument(arg)
 212                 add_project_arguments(arg, language: 'c')
 213         endif
 214 endforeach
 215
 216 # set other values pulled from the build options
 217 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 218 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 219 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 220 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 221 # values which have defaults which may be overridden
 222 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 223 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 224 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 225
 226
 227 compile_time_cpuflags = []
 228 if host_machine.cpu_family().startswith('x86')
 229         arch_subdir = 'x86'
 230 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 231         arch_subdir = 'arm'
 232 elif host_machine.cpu_family().startswith('ppc')
 233         arch_subdir = 'ppc_64'
 234 endif
 235 subdir(arch_subdir)
 236 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 237
 238 # set the install path for the drivers
 239 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 240
 241 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 242
 243 # enable VFIO only if it is linux OS
 244 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 245
 246 # specify -D_GNU_SOURCE unconditionally
 247 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 248
 249 # specify -D__BSD_VISIBLE for FreeBSD
 250 if is_freebsd
 251         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 252 endif
 253
 254 if is_windows
 255         # Minimum supported API is Windows 7.
 256         add_project_arguments('-D_WIN32_WINNT=0x0601', language: 'c')
 257
 258         # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 259         if cc.get_id() == 'gcc'
 260                 add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 261         endif
 262 endif
 263
 264 if get_option('b_lto')
 265         if cc.has_argument('-ffat-lto-objects')
 266                 add_project_arguments('-ffat-lto-objects', language: 'c')
 267         else
 268                 error('compiler does not support fat LTO objects - please turn LTO off')
 269         endif
 270         # workaround for gcc bug 81440
 271         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 272                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 273                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 274         endif
 275 endif