config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'),
  26         abi_version_file).stdout().strip()
  27
  28 # Libraries have the abi_version as the filename extension
  29 # and have the soname be all but the final part of the abi_version.
  30 # e.g. v20.1 => librte_foo.so.20.1
  31 #    sonames => librte_foo.so.20
  32 so_version = abi_version.split('.')[0]
  33
  34 # extract all version information into the build configuration
  35 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  36 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  37 if pver.get(2).contains('-rc')
  38         rc_ver = pver.get(2).split('-rc')
  39         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  40         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  41         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  42 else
  43         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  44         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  45 # for actual, non-rc releases, set the release value to 99 to ensure releases
  46 # have higher version numbers than their respective release candidates
  47         dpdk_conf.set('RTE_VER_RELEASE', 99)
  48 endif
  49
  50 pmd_subdir_opt = get_option('drivers_install_subdir')
  51 if pmd_subdir_opt.contains('<VERSION>')
  52         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  53 endif
  54 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  55 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  56
  57 # driver .so files often depend upon the bus drivers for their connect bus,
  58 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  59 # to be in the library path, so symlink the drivers from the main lib directory.
  60 if not is_windows
  61         meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  62                         get_option('libdir'),
  63                         pmd_subdir_opt)
  64 endif
  65
  66 # init disable/enable driver lists that will be populated in different places
  67 disable_drivers = ''
  68 enable_drivers = ''
  69
  70 # set the machine type and cflags for it
  71 if meson.is_cross_build()
  72         machine = host_machine.cpu()
  73 else
  74         machine = get_option('machine')
  75 endif
  76
  77 # machine type 'generic' is special, it selects the per arch agreed common
  78 # minimal baseline needed for DPDK. Machine type 'default' is also supported
  79 # with the same meaning for backwards compatibility.
  80 # That might not be the most optimized, but the most portable version while
  81 # still being able to support the CPU features required for DPDK.
  82 # This can be bumped up by the DPDK project, but it can never be an
  83 # invariant like 'native'
  84 if machine == 'default' or machine == 'generic'
  85         if host_machine.cpu_family().startswith('x86')
  86                 # matches the old pre-meson build systems generic machine
  87                 machine = 'corei7'
  88         elif host_machine.cpu_family().startswith('arm')
  89                 machine = 'armv7-a'
  90         elif host_machine.cpu_family().startswith('aarch')
  91                 # arm64 manages generic config in config/arm/meson.build
  92                 machine = 'generic'
  93         elif host_machine.cpu_family().startswith('ppc')
  94                 machine = 'power8'
  95         endif
  96 endif
  97
  98 dpdk_conf.set('RTE_MACHINE', machine)
  99 machine_args = []
 100
 101 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
 102 if host_machine.cpu_family().startswith('ppc')
 103         machine_args += '-mcpu=' + machine
 104         machine_args += '-mtune=' + machine
 105 else
 106         machine_args += '-march=' + machine
 107 endif
 108
 109 toolchain = cc.get_id()
 110 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 111 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 112
 113 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 114 dpdk_conf.set('RTE_ARCH_32', cc.sizeof('void *') == 4)
 115
 116 if not is_windows
 117         add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 118 endif
 119
 120 # use pthreads if available for the platform
 121 if not is_windows
 122         add_project_link_arguments('-pthread', language: 'c')
 123         dpdk_extra_ldflags += '-pthread'
 124 endif
 125
 126 # on some OS, maths functions are in a separate library
 127 if cc.find_library('m', required : false).found()
 128         # some libs depend on maths lib
 129         add_project_link_arguments('-lm', language: 'c')
 130         dpdk_extra_ldflags += '-lm'
 131 endif
 132
 133 if is_linux
 134         link_lib = 'dl'
 135 else
 136         link_lib = ''
 137 endif
 138
 139 # if link_lib is empty, do not add it to project properties
 140 if link_lib != ''
 141         add_project_link_arguments('-l' + link_lib, language: 'c')
 142         dpdk_extra_ldflags += '-l' + link_lib
 143 endif
 144
 145 # check for libraries used in multiple places in DPDK
 146 has_libnuma = 0
 147 find_libnuma = true
 148 if meson.is_cross_build() and not meson.get_cross_property('numa', true)
 149         # don't look for libnuma if explicitly disabled in cross build
 150         find_libnuma = false
 151 endif
 152 if find_libnuma
 153         numa_dep = cc.find_library('numa', required: false)
 154         if numa_dep.found() and cc.has_header('numaif.h')
 155                 dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 156                 has_libnuma = 1
 157                 add_project_link_arguments('-lnuma', language: 'c')
 158                 dpdk_extra_ldflags += '-lnuma'
 159         endif
 160 endif
 161
 162 has_libfdt = 0
 163 fdt_dep = cc.find_library('libfdt', required: false)
 164 if fdt_dep.found() and cc.has_header('fdt.h')
 165         dpdk_conf.set10('RTE_HAS_LIBFDT', true)
 166         has_libfdt = 1
 167         add_project_link_arguments('-lfdt', language: 'c')
 168         dpdk_extra_ldflags += '-lfdt'
 169 endif
 170
 171 libexecinfo = cc.find_library('libexecinfo', required: false)
 172 if libexecinfo.found() and cc.has_header('execinfo.h')
 173         add_project_link_arguments('-lexecinfo', language: 'c')
 174         dpdk_extra_ldflags += '-lexecinfo'
 175 endif
 176
 177 # check for libbsd
 178 libbsd = dependency('libbsd', required: false, method: 'pkg-config')
 179 if libbsd.found()
 180         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 181 endif
 182
 183 # check for pcap
 184 pcap_dep = dependency('libpcap', required: false, method: 'pkg-config')
 185 if not pcap_dep.found()
 186         # pcap got a pkg-config file only in 1.9.0
 187         pcap_dep = cc.find_library('pcap', required: false)
 188 endif
 189 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 190         dpdk_conf.set('RTE_PORT_PCAP', 1)
 191         dpdk_extra_ldflags += '-lpcap'
 192 endif
 193
 194 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 195 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 196         atomic_dep = cc.find_library('atomic', required: true)
 197         add_project_link_arguments('-latomic', language: 'c')
 198         dpdk_extra_ldflags += '-latomic'
 199 endif
 200
 201 # add -include rte_config to cflags
 202 add_project_arguments('-include', 'rte_config.h', language: 'c')
 203
 204 # enable extra warnings and disable any unwanted warnings
 205 warning_flags = [
 206         # -Wall is added by meson by default, so add -Wextra only
 207         '-Wextra',
 208
 209         # additional warnings in alphabetical order
 210         '-Wcast-qual',
 211         '-Wdeprecated',
 212         '-Wformat',
 213         '-Wformat-nonliteral',
 214         '-Wformat-security',
 215         '-Wmissing-declarations',
 216         '-Wmissing-prototypes',
 217         '-Wnested-externs',
 218         '-Wold-style-definition',
 219         '-Wpointer-arith',
 220         '-Wsign-compare',
 221         '-Wstrict-prototypes',
 222         '-Wundef',
 223         '-Wwrite-strings',
 224
 225         # globally disabled warnings
 226         '-Wno-address-of-packed-member',
 227         '-Wno-packed-not-aligned',
 228         '-Wno-missing-field-initializers'
 229 ]
 230 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
 231 # FIXME: Bugzilla 396
 232         warning_flags += '-Wno-zero-length-bounds'
 233 endif
 234 if not dpdk_conf.get('RTE_ARCH_64')
 235 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 236         warning_flags += '-Wno-pointer-to-int-cast'
 237 endif
 238 if cc.get_id() == 'intel'
 239         warning_ids = [181, 188, 2203, 2279, 2557, 3179, 3656]
 240         foreach i:warning_ids
 241                 warning_flags += '-diag-disable=@0@'.format(i)
 242         endforeach
 243 endif
 244 foreach arg: warning_flags
 245         if cc.has_argument(arg)
 246                 add_project_arguments(arg, language: 'c')
 247         endif
 248 endforeach
 249
 250 # set other values pulled from the build options
 251 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 252 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 253 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 254 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 255 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 256 # values which have defaults which may be overridden
 257 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 258 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 259 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 260 if dpdk_conf.get('RTE_ARCH_64')
 261         dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
 262 else # for 32-bit we need smaller reserved memory areas
 263         dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
 264 endif
 265
 266
 267 compile_time_cpuflags = []
 268 subdir(arch_subdir)
 269 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 270
 271 # apply cross-specific options
 272 if meson.is_cross_build()
 273         # configure RTE_MAX_LCORE and RTE_MAX_NUMA_NODES from cross file
 274         cross_max_lcores = meson.get_cross_property('max_lcores', 0)
 275         if cross_max_lcores != 0
 276                 message('Setting RTE_MAX_LCORE from cross file')
 277                 dpdk_conf.set('RTE_MAX_LCORE', cross_max_lcores)
 278         endif
 279         cross_max_numa_nodes = meson.get_cross_property('max_numa_nodes', 0)
 280         if cross_max_numa_nodes != 0
 281                 message('Setting RTE_MAX_NUMA_NODES from cross file')
 282                 dpdk_conf.set('RTE_MAX_NUMA_NODES', cross_max_numa_nodes)
 283         endif
 284 endif
 285
 286 # set the install path for the drivers
 287 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 288
 289 install_headers(['rte_config.h'],
 290                 subdir: get_option('include_subdir_arch'))
 291
 292 # enable VFIO only if it is linux OS
 293 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 294
 295 # specify -D_GNU_SOURCE unconditionally
 296 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 297
 298 # specify -D__BSD_VISIBLE for FreeBSD
 299 if is_freebsd
 300         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 301 endif
 302
 303 if is_windows
 304         # VirtualAlloc2() is available since Windows 10 / Server 2016.
 305         add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
 306
 307         # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 308         if cc.get_id() == 'gcc'
 309                 add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 310         endif
 311
 312         # Disable secure CRT deprecated warnings for clang
 313         if cc.get_id() == 'clang'
 314                 add_project_arguments('-D_CRT_SECURE_NO_WARNINGS', language: 'c')
 315         endif
 316
 317         add_project_link_arguments('-lws2_32', language: 'c')
 318
 319         # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
 320         # in Windows SDK, while MinGW exports it by advapi32.a.
 321         if is_ms_linker
 322                 add_project_link_arguments('-lmincore', language: 'c')
 323         endif
 324
 325         add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
 326         add_project_link_arguments('-ldbghelp', language: 'c')
 327 endif
 328
 329 if get_option('b_lto')
 330         if cc.has_argument('-ffat-lto-objects')
 331                 add_project_arguments('-ffat-lto-objects', language: 'c')
 332         else
 333                 error('compiler does not support fat LTO objects - please turn LTO off')
 334         endif
 335         # workaround for gcc bug 81440
 336         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 337                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 338                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 339         endif
 340 endif
 341
 342 if get_option('default_library') == 'both'
 343         error( '''
 344     Unsupported value "both" for "default_library" option.
 345
 346     NOTE: DPDK always builds both shared and static libraries.  Please set
 347     "default_library" to either "static" or "shared" to select default linkage
 348     for apps and any examples.''')
 349 endif