config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'),
  26         abi_version_file).stdout().strip()
  27
  28 # Libraries have the abi_version as the filename extension
  29 # and have the soname be all but the final part of the abi_version.
  30 # e.g. v20.1 => librte_foo.so.20.1
  31 #    sonames => librte_foo.so.20
  32 so_version = abi_version.split('.')[0]
  33
  34 # extract all version information into the build configuration
  35 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  36 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  37 if pver.get(2).contains('-rc')
  38         rc_ver = pver.get(2).split('-rc')
  39         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  40         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  41         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  42 else
  43         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  44         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  45 # for actual, non-rc releases, set the release value to 99 to ensure releases
  46 # have higher version numbers than their respective release candidates
  47         dpdk_conf.set('RTE_VER_RELEASE', 99)
  48 endif
  49
  50 pmd_subdir_opt = get_option('drivers_install_subdir')
  51 if pmd_subdir_opt.contains('<VERSION>')
  52         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  53 endif
  54 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  55 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  56
  57 # driver .so files often depend upon the bus drivers for their connect bus,
  58 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  59 # to be in the library path, so symlink the drivers from the main lib directory.
  60 if not is_windows
  61         meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  62                         get_option('libdir'),
  63                         pmd_subdir_opt)
  64 endif
  65
  66 # set the machine type and cflags for it
  67 if meson.is_cross_build()
  68         machine = host_machine.cpu()
  69 else
  70         machine = get_option('machine')
  71 endif
  72
  73 # machine type 'default' is special, it defaults to the per arch agreed common
  74 # minimal baseline needed for DPDK.
  75 # That might not be the most optimized, but the most portable version while
  76 # still being able to support the CPU features required for DPDK.
  77 # This can be bumped up by the DPDK project, but it can never be an
  78 # invariant like 'native'
  79 if machine == 'default'
  80         if host_machine.cpu_family().startswith('x86')
  81                 # matches the old pre-meson build systems default
  82                 machine = 'corei7'
  83         elif host_machine.cpu_family().startswith('arm')
  84                 machine = 'armv7-a'
  85         elif host_machine.cpu_family().startswith('aarch')
  86                 # arm64 manages defaults in config/arm/meson.build
  87                 machine = 'default'
  88         elif host_machine.cpu_family().startswith('ppc')
  89                 machine = 'power8'
  90         endif
  91 endif
  92
  93 dpdk_conf.set('RTE_MACHINE', machine)
  94 machine_args = []
  95
  96 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  97 if host_machine.cpu_family().startswith('ppc')
  98         machine_args += '-mcpu=' + machine
  99         machine_args += '-mtune=' + machine
 100 else
 101         machine_args += '-march=' + machine
 102 endif
 103
 104 toolchain = cc.get_id()
 105 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 106 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 107
 108 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 109 dpdk_conf.set('RTE_ARCH_32', cc.sizeof('void *') == 4)
 110
 111 if not is_windows
 112         add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 113 endif
 114
 115 # use pthreads if available for the platform
 116 if not is_windows
 117         add_project_link_arguments('-pthread', language: 'c')
 118         dpdk_extra_ldflags += '-pthread'
 119 endif
 120
 121 # on some OS, maths functions are in a separate library
 122 if cc.find_library('m', required : false).found()
 123         # some libs depend on maths lib
 124         add_project_link_arguments('-lm', language: 'c')
 125         dpdk_extra_ldflags += '-lm'
 126 endif
 127
 128 # for linux link against dl, for bsd execinfo
 129 if is_linux
 130         link_lib = 'dl'
 131 elif is_freebsd
 132         link_lib = 'execinfo'
 133 else
 134         link_lib = ''
 135 endif
 136
 137 # if link_lib is empty, do not add it to project properties
 138 if link_lib != ''
 139         add_project_link_arguments('-l' + link_lib, language: 'c')
 140         dpdk_extra_ldflags += '-l' + link_lib
 141 endif
 142
 143 # check for libraries used in multiple places in DPDK
 144 has_libnuma = 0
 145 numa_dep = cc.find_library('numa', required: false)
 146 if numa_dep.found() and cc.has_header('numaif.h')
 147         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 148         has_libnuma = 1
 149         add_project_link_arguments('-lnuma', language: 'c')
 150         dpdk_extra_ldflags += '-lnuma'
 151 endif
 152
 153 has_libfdt = 0
 154 fdt_dep = cc.find_library('libfdt', required: false)
 155 if fdt_dep.found() and cc.has_header('fdt.h')
 156         dpdk_conf.set10('RTE_HAS_LIBFDT', true)
 157         has_libfdt = 1
 158         add_project_link_arguments('-lfdt', language: 'c')
 159         dpdk_extra_ldflags += '-lfdt'
 160 endif
 161
 162 # check for libbsd
 163 libbsd = dependency('libbsd', required: false)
 164 if libbsd.found()
 165         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 166 endif
 167
 168 # check for pcap
 169 pcap_dep = dependency('libpcap', required: false, method: 'pkg-config')
 170 if not pcap_dep.found()
 171         # pcap got a pkg-config file only in 1.9.0
 172         pcap_dep = cc.find_library('pcap', required: false)
 173 endif
 174 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 175         dpdk_conf.set('RTE_PORT_PCAP', 1)
 176         dpdk_extra_ldflags += '-lpcap'
 177 endif
 178
 179 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 180 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 181         atomic_dep = cc.find_library('atomic', required: true)
 182         add_project_link_arguments('-latomic', language: 'c')
 183         dpdk_extra_ldflags += '-latomic'
 184 endif
 185
 186 # add -include rte_config to cflags
 187 add_project_arguments('-include', 'rte_config.h', language: 'c')
 188
 189 # enable extra warnings and disable any unwanted warnings
 190 warning_flags = [
 191         # -Wall is added by meson by default, so add -Wextra only
 192         '-Wextra',
 193
 194         # additional warnings in alphabetical order
 195         '-Wcast-qual',
 196         '-Wdeprecated',
 197         '-Wformat-nonliteral',
 198         '-Wformat-security',
 199         '-Wmissing-declarations',
 200         '-Wmissing-prototypes',
 201         '-Wnested-externs',
 202         '-Wold-style-definition',
 203         '-Wpointer-arith',
 204         '-Wsign-compare',
 205         '-Wstrict-prototypes',
 206         '-Wundef',
 207         '-Wwrite-strings',
 208
 209         # globally disabled warnings
 210         '-Wno-address-of-packed-member',
 211         '-Wno-packed-not-aligned',
 212         '-Wno-missing-field-initializers'
 213 ]
 214 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
 215 # FIXME: Bugzilla 396
 216         warning_flags += '-Wno-zero-length-bounds'
 217 endif
 218 if not dpdk_conf.get('RTE_ARCH_64')
 219 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 220         warning_flags += '-Wno-pointer-to-int-cast'
 221 endif
 222 if cc.get_id() == 'intel'
 223         warning_ids = [188, 2203, 2279, 2557, 3179, 3656]
 224         foreach i:warning_ids
 225                 warning_flags += '-diag-disable=@0@'.format(i)
 226         endforeach
 227 endif
 228 foreach arg: warning_flags
 229         if cc.has_argument(arg)
 230                 add_project_arguments(arg, language: 'c')
 231         endif
 232 endforeach
 233
 234 # set other values pulled from the build options
 235 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 236 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 237 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 238 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 239 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 240 # values which have defaults which may be overridden
 241 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 242 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 243 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 244 if dpdk_conf.get('RTE_ARCH_64')
 245         dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
 246 else # for 32-bit we need smaller reserved memory areas
 247         dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
 248 endif
 249
 250
 251 compile_time_cpuflags = []
 252 subdir(arch_subdir)
 253 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 254
 255 # set the install path for the drivers
 256 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 257
 258 install_headers(['rte_config.h', 'rte_compatibility_defines.h'],
 259                 subdir: get_option('include_subdir_arch'))
 260
 261 # enable VFIO only if it is linux OS
 262 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 263
 264 # specify -D_GNU_SOURCE unconditionally
 265 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 266
 267 # specify -D__BSD_VISIBLE for FreeBSD
 268 if is_freebsd
 269         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 270 endif
 271
 272 if is_windows
 273         # VirtualAlloc2() is available since Windows 10 / Server 2016.
 274         add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
 275
 276         # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 277         if cc.get_id() == 'gcc'
 278                 add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 279         endif
 280
 281         add_project_link_arguments('-lws2_32', language: 'c')
 282
 283         # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
 284         # in Windows SDK, while MinGW exports it by advapi32.a.
 285         if is_ms_linker
 286                 add_project_link_arguments('-lmincore', language: 'c')
 287         endif
 288
 289         add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
 290         add_project_link_arguments('-ldbghelp', language: 'c')
 291 endif
 292
 293 if get_option('b_lto')
 294         if cc.has_argument('-ffat-lto-objects')
 295                 add_project_arguments('-ffat-lto-objects', language: 'c')
 296         else
 297                 error('compiler does not support fat LTO objects - please turn LTO off')
 298         endif
 299         # workaround for gcc bug 81440
 300         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 301                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 302                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 303         endif
 304 endif