config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'),
  26         abi_version_file).stdout().strip()
  27
  28 # Regular libraries have the abi_version as the filename extension
  29 # and have the soname be all but the final part of the abi_version.
  30 # Experimental libraries have soname with '0.major'
  31 # and the filename suffix as 0.majorminor versions,
  32 # e.g. v20.1 => librte_stable.so.20.1, librte_experimental.so.0.201
  33 #    sonames => librte_stable.so.20, librte_experimental.so.0.20
  34 # e.g. v20.0.1 => librte_stable.so.20.0.1, librte_experimental.so.0.2001
  35 #      sonames => librte_stable.so.20.0, librte_experimental.so.0.200
  36 abi_va = abi_version.split('.')
  37 stable_so_version = abi_va.length() == 2 ? abi_va[0] : abi_va[0] + '.' + abi_va[1]
  38 experimental_abi_version = '0.' + abi_va[0] + abi_va[1] + '.' + abi_va[2]
  39 experimental_so_version = experimental_abi_version
  40
  41 # extract all version information into the build configuration
  42 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  43 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  44 if pver.get(2).contains('-rc')
  45         rc_ver = pver.get(2).split('-rc')
  46         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  47         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  48         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  49 else
  50         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  51         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  52 # for actual, non-rc releases, set the release value to 99 to ensure releases
  53 # have higher version numbers than their respective release candidates
  54         dpdk_conf.set('RTE_VER_RELEASE', 99)
  55 endif
  56
  57 pmd_subdir_opt = get_option('drivers_install_subdir')
  58 if pmd_subdir_opt.contains('<VERSION>')
  59         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  60 endif
  61 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  62 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  63
  64 # driver .so files often depend upon the bus drivers for their connect bus,
  65 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  66 # to be in the library path, so symlink the drivers from the main lib directory.
  67 meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  68                 get_option('libdir'),
  69                 pmd_subdir_opt)
  70
  71 # set the machine type and cflags for it
  72 if meson.is_cross_build()
  73         machine = host_machine.cpu()
  74 else
  75         machine = get_option('machine')
  76 endif
  77
  78 # machine type 'default' is special, it defaults to the per arch agreed common
  79 # minimal baseline needed for DPDK.
  80 # That might not be the most optimized, but the most portable version while
  81 # still being able to support the CPU features required for DPDK.
  82 # This can be bumped up by the DPDK project, but it can never be an
  83 # invariant like 'native'
  84 if machine == 'default'
  85         if host_machine.cpu_family().startswith('x86')
  86                 # matches the old pre-meson build systems default
  87                 machine = 'corei7'
  88         elif host_machine.cpu_family().startswith('arm')
  89                 machine = 'armv7-a'
  90         elif host_machine.cpu_family().startswith('aarch')
  91                 # arm64 manages defaults in config/arm/meson.build
  92                 machine = 'default'
  93         elif host_machine.cpu_family().startswith('ppc')
  94                 machine = 'power8'
  95         endif
  96 endif
  97
  98 dpdk_conf.set('RTE_MACHINE', machine)
  99 machine_args = []
 100
 101 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
 102 if host_machine.cpu_family().startswith('ppc')
 103         machine_args += '-mcpu=' + machine
 104         machine_args += '-mtune=' + machine
 105 else
 106         machine_args += '-march=' + machine
 107 endif
 108
 109 toolchain = cc.get_id()
 110 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 111 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 112
 113 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 114
 115 if not is_windows
 116         add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 117 endif
 118
 119 # use pthreads if available for the platform
 120 if not is_ms_linker
 121         add_project_link_arguments('-pthread', language: 'c')
 122         dpdk_extra_ldflags += '-pthread'
 123 endif
 124
 125 # on some OS, maths functions are in a separate library
 126 if cc.find_library('m', required : false).found()
 127         # some libs depend on maths lib
 128         add_project_link_arguments('-lm', language: 'c')
 129         dpdk_extra_ldflags += '-lm'
 130 endif
 131
 132 # for linux link against dl, for bsd execinfo
 133 if is_linux
 134         link_lib = 'dl'
 135 elif is_freebsd
 136         link_lib = 'execinfo'
 137 else
 138         link_lib = ''
 139 endif
 140
 141 # if link_lib is empty, do not add it to project properties
 142 if link_lib != ''
 143         add_project_link_arguments('-l' + link_lib, language: 'c')
 144         dpdk_extra_ldflags += '-l' + link_lib
 145 endif
 146
 147 # check for libraries used in multiple places in DPDK
 148 has_libnuma = 0
 149 numa_dep = cc.find_library('numa', required: false)
 150 if numa_dep.found() and cc.has_header('numaif.h')
 151         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 152         has_libnuma = 1
 153         add_project_link_arguments('-lnuma', language: 'c')
 154         dpdk_extra_ldflags += '-lnuma'
 155 endif
 156
 157 # check for libbsd
 158 libbsd = dependency('libbsd', required: false)
 159 if libbsd.found()
 160         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 161 endif
 162
 163 # check for pcap
 164 pcap_dep = dependency('pcap', required: false)
 165 if pcap_dep.found()
 166         # pcap got a pkg-config file only in 1.9.0 and before that meson uses
 167         # an internal pcap-config finder, which is not compatible with
 168         # cross-compilation, so try to fallback to find_library
 169         pcap_dep = cc.find_library('pcap', required: false)
 170 endif
 171 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 172         dpdk_conf.set('RTE_PORT_PCAP', 1)
 173         dpdk_extra_ldflags += '-lpcap'
 174 endif
 175
 176 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 177 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 178         atomic_dep = cc.find_library('atomic', required: true)
 179         add_project_link_arguments('-latomic', language: 'c')
 180         dpdk_extra_ldflags += '-latomic'
 181 endif
 182
 183 # add -include rte_config to cflags
 184 add_project_arguments('-include', 'rte_config.h', language: 'c')
 185
 186 # enable extra warnings and disable any unwanted warnings
 187 warning_flags = [
 188         # -Wall is added by meson by default, so add -Wextra only
 189         '-Wextra',
 190
 191         # additional warnings in alphabetical order
 192         '-Wcast-qual',
 193         '-Wdeprecated',
 194         '-Wformat-nonliteral',
 195         '-Wformat-security',
 196         '-Wmissing-declarations',
 197         '-Wmissing-prototypes',
 198         '-Wnested-externs',
 199         '-Wold-style-definition',
 200         '-Wpointer-arith',
 201         '-Wsign-compare',
 202         '-Wstrict-prototypes',
 203         '-Wundef',
 204         '-Wwrite-strings',
 205
 206         # globally disabled warnings
 207         '-Wno-address-of-packed-member',
 208         '-Wno-packed-not-aligned',
 209         '-Wno-missing-field-initializers'
 210 ]
 211 if not dpdk_conf.get('RTE_ARCH_64')
 212 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 213         warning_flags += '-Wno-pointer-to-int-cast'
 214 endif
 215 if cc.get_id() == 'intel'
 216         warning_ids = [188, 2203, 2279, 2557, 3179, 3656]
 217         foreach i:warning_ids
 218                 warning_flags += '-diag-disable=@0@'.format(i)
 219         endforeach
 220 endif
 221 foreach arg: warning_flags
 222         if cc.has_argument(arg)
 223                 add_project_arguments(arg, language: 'c')
 224         endif
 225 endforeach
 226
 227 # set other values pulled from the build options
 228 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 229 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 230 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 231 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 232 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 233 # values which have defaults which may be overridden
 234 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 235 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 236 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 237
 238
 239 compile_time_cpuflags = []
 240 if host_machine.cpu_family().startswith('x86')
 241         arch_subdir = 'x86'
 242 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 243         arch_subdir = 'arm'
 244 elif host_machine.cpu_family().startswith('ppc')
 245         arch_subdir = 'ppc'
 246 endif
 247 subdir(arch_subdir)
 248 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 249
 250 # set the install path for the drivers
 251 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 252
 253 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 254
 255 # enable VFIO only if it is linux OS
 256 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 257
 258 # specify -D_GNU_SOURCE unconditionally
 259 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 260
 261 # specify -D__BSD_VISIBLE for FreeBSD
 262 if is_freebsd
 263         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 264 endif
 265
 266 if is_windows
 267         # Minimum supported API is Windows 7.
 268         add_project_arguments('-D_WIN32_WINNT=0x0601', language: 'c')
 269
 270         # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 271         if cc.get_id() == 'gcc'
 272                 add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 273         endif
 274 endif
 275
 276 if get_option('b_lto')
 277         if cc.has_argument('-ffat-lto-objects')
 278                 add_project_arguments('-ffat-lto-objects', language: 'c')
 279         else
 280                 error('compiler does not support fat LTO objects - please turn LTO off')
 281         endif
 282         # workaround for gcc bug 81440
 283         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 284                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 285                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 286         endif
 287 endif