config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 # set the major version, which might be used by drivers and libraries
   5 # depending on the configuration options
   6 pver = meson.project_version().split('.')
   7 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
   8
   9 pmd_subdir_opt = get_option('drivers_install_subdir')
  10 if pmd_subdir_opt.contains('<VERSION>')
  11         pmd_subdir_opt = major_version.join(pmd_subdir_opt.split('<VERSION>'))
  12 endif
  13 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  14 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  15
  16 # set the machine type and cflags for it
  17 if meson.is_cross_build()
  18         machine = host_machine.cpu()
  19 else
  20         machine = get_option('machine')
  21 endif
  22
  23 # machine type 'default' is special, it defaults to the per arch agreed common
  24 # minimal baseline needed for DPDK.
  25 # That might not be the most optimized, but the most portable version while
  26 # still being able to support the CPU features required for DPDK.
  27 # This can be bumped up by the DPDK project, but it can never be an
  28 # invariant like 'native'
  29 if machine == 'default'
  30         if host_machine.cpu_family().startswith('x86')
  31                 # matches the old pre-meson build systems default
  32                 machine = 'corei7'
  33         elif host_machine.cpu_family().startswith('arm')
  34                 machine = 'armv7-a'
  35         elif host_machine.cpu_family().startswith('aarch')
  36                 # arm64 manages defaults in config/arm/meson.build
  37                 machine = 'default'
  38         elif host_machine.cpu_family().startswith('ppc')
  39                 machine = 'power8'
  40         endif
  41 endif
  42
  43 dpdk_conf.set('RTE_MACHINE', machine)
  44 machine_args = []
  45
  46 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  47 if host_machine.cpu_family().startswith('ppc')
  48         machine_args += '-mcpu=' + machine
  49         machine_args += '-mtune=' + machine
  50 else
  51         machine_args += '-march=' + machine
  52 endif
  53
  54 toolchain = cc.get_id()
  55 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  56 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  57
  58 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
  59
  60 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
  61 dpdk_extra_ldflags += '-Wl,--no-as-needed'
  62
  63 # use pthreads
  64 add_project_link_arguments('-pthread', language: 'c')
  65 dpdk_extra_ldflags += '-pthread'
  66
  67 # some libs depend on maths lib
  68 add_project_link_arguments('-lm', language: 'c')
  69 dpdk_extra_ldflags += '-lm'
  70
  71 # for linux link against dl, for bsd execinfo
  72 if host_machine.system() == 'linux'
  73         link_lib = 'dl'
  74 else
  75         link_lib = 'execinfo'
  76 endif
  77 add_project_link_arguments('-l' + link_lib, language: 'c')
  78 dpdk_extra_ldflags += '-l' + link_lib
  79
  80 # check for libraries used in multiple places in DPDK
  81 has_libnuma = 0
  82 numa_dep = cc.find_library('numa', required: false)
  83 if numa_dep.found() and cc.has_header('numaif.h')
  84         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
  85         has_libnuma = 1
  86         add_project_link_arguments('-lnuma', language: 'c')
  87         dpdk_extra_ldflags += '-lnuma'
  88 endif
  89
  90 # check for strlcpy
  91 if host_machine.system() == 'linux'
  92         libbsd = dependency('libbsd', required: false)
  93         if libbsd.found()
  94                 dpdk_conf.set('RTE_USE_LIBBSD', 1)
  95         endif
  96 endif
  97
  98 # add -include rte_config to cflags
  99 add_project_arguments('-include', 'rte_config.h', language: 'c')
 100
 101 # enable extra warnings and disable any unwanted warnings
 102 warning_flags = [
 103         '-Wsign-compare',
 104         '-Wcast-qual',
 105         '-Wno-address-of-packed-member'
 106 ]
 107 if not dpdk_conf.get('RTE_ARCH_64')
 108 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 109         warning_flags += '-Wno-pointer-to-int-cast'
 110 endif
 111 foreach arg: warning_flags
 112         if cc.has_argument(arg)
 113                 add_project_arguments(arg, language: 'c')
 114         endif
 115 endforeach
 116
 117 # set other values pulled from the build options
 118 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 119 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 120 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 121 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 122 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
 123 # values which have defaults which may be overridden
 124 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 125 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 126 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 127
 128
 129 compile_time_cpuflags = []
 130 if host_machine.cpu_family().startswith('x86')
 131         arch_subdir = 'x86'
 132 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 133         arch_subdir = 'arm'
 134 elif host_machine.cpu_family().startswith('ppc')
 135         arch_subdir = 'ppc_64'
 136 endif
 137 subdir(arch_subdir)
 138 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 139
 140 # set the install path for the drivers
 141 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 142
 143 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 144
 145 # enable VFIO only if it is linux OS
 146 dpdk_conf.set('RTE_EAL_VFIO', host_machine.system() == 'linux')