config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 # set the machine type and cflags for it
   5 if meson.is_cross_build()
   6         machine = host_machine.cpu()
   7 else
   8         machine = get_option('machine')
   9 endif
  10
  11 # machine type 'default' is special, it defaults to the per arch agreed common
  12 # minimal baseline needed for DPDK.
  13 # That might not be the most optimized, but the most portable version while
  14 # still being able to support the CPU features required for DPDK.
  15 # This can be bumped up by the DPDK project, but it can never be an
  16 # invariant like 'native'
  17 if machine == 'default'
  18         if host_machine.cpu_family().startswith('x86')
  19                 # matches the old pre-meson build systems default
  20                 machine = 'corei7'
  21         elif host_machine.cpu_family().startswith('arm')
  22                 machine = 'armv7-a'
  23         elif host_machine.cpu_family().startswith('aarch')
  24                 # arm64 manages defaults in config/arm/meson.build
  25                 machine = 'default'
  26         elif host_machine.cpu_family().startswith('ppc')
  27                 machine = 'power8'
  28         endif
  29 endif
  30
  31 dpdk_conf.set('RTE_MACHINE', machine)
  32 machine_args = []
  33
  34 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  35 if host_machine.cpu_family().startswith('ppc')
  36         machine_args += '-mcpu=' + machine
  37         machine_args += '-mtune=' + machine
  38 else
  39         machine_args += '-march=' + machine
  40 endif
  41
  42 toolchain = cc.get_id()
  43 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  44 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  45
  46 # get binutils version for the workaround of Bug 97
  47 ldver = run_command('ld', '-v').stdout().strip()
  48 if ldver.contains('2.30')
  49         if cc.has_argument('-mno-avx512f')
  50                 machine_args += '-mno-avx512f'
  51         endif
  52 endif
  53
  54 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
  55 dpdk_extra_ldflags += '-Wl,--no-as-needed'
  56
  57 # use pthreads
  58 add_project_link_arguments('-pthread', language: 'c')
  59 dpdk_extra_ldflags += '-pthread'
  60
  61 # some libs depend on maths lib
  62 add_project_link_arguments('-lm', language: 'c')
  63 dpdk_extra_ldflags += '-lm'
  64
  65 # for linux link against dl, for bsd execinfo
  66 if host_machine.system() == 'linux'
  67         link_lib = 'dl'
  68 else
  69         link_lib = 'execinfo'
  70 endif
  71 add_project_link_arguments('-l' + link_lib, language: 'c')
  72 dpdk_extra_ldflags += '-l' + link_lib
  73
  74 # check for libraries used in multiple places in DPDK
  75 has_libnuma = 0
  76 numa_dep = cc.find_library('numa', required: false)
  77 if numa_dep.found() and cc.has_header('numaif.h')
  78         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
  79         has_libnuma = 1
  80         add_project_link_arguments('-lnuma', language: 'c')
  81         dpdk_extra_ldflags += '-lnuma'
  82 endif
  83
  84 # check for strlcpy
  85 if host_machine.system() == 'linux' and cc.find_library('bsd',
  86                 required: false).found() and cc.has_header('bsd/string.h')
  87         dpdk_conf.set('RTE_USE_LIBBSD', 1)
  88         add_project_link_arguments('-lbsd', language: 'c')
  89         dpdk_extra_ldflags += '-lbsd'
  90 endif
  91
  92 # add -include rte_config to cflags
  93 add_project_arguments('-include', 'rte_config.h', language: 'c')
  94
  95 # enable extra warnings and disable any unwanted warnings
  96 warning_flags = [
  97         '-Wsign-compare',
  98         '-Wcast-qual',
  99         '-Wno-address-of-packed-member'
 100 ]
 101 if cc.sizeof('void *') == 4
 102 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 103         warning_flags += '-Wno-pointer-to-int-cast'
 104 endif
 105 foreach arg: warning_flags
 106         if cc.has_argument(arg)
 107                 add_project_arguments(arg, language: 'c')
 108         endif
 109 endforeach
 110
 111 # set other values pulled from the build options
 112 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 113 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 114 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 115 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
 116 # values which have defaults which may be overridden
 117 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 118 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 119 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 120
 121 compile_time_cpuflags = []
 122 if host_machine.cpu_family().startswith('x86')
 123         arch_subdir = 'x86'
 124 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 125         arch_subdir = 'arm'
 126 elif host_machine.cpu_family().startswith('ppc')
 127         arch_subdir = 'ppc_64'
 128 endif
 129 subdir(arch_subdir)
 130 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 131
 132 # set the install path for the drivers
 133 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 134
 135 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 136
 137 # enable VFIO only if it is linux OS
 138 dpdk_conf.set('RTE_EAL_VFIO', host_machine.system() == 'linux')