config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 # set the machine type and cflags for it
   5 if meson.is_cross_build()
   6         machine = host_machine.cpu()
   7 else
   8         machine = get_option('machine')
   9 endif
  10 dpdk_conf.set('RTE_MACHINE', machine)
  11 machine_args = []
  12 machine_args += '-march=' + machine
  13
  14 toolchain = cc.get_id()
  15 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  16 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  17
  18 # use pthreads
  19 add_project_link_arguments('-pthread', language: 'c')
  20 dpdk_extra_ldflags += '-pthread'
  21
  22 # some libs depend on maths lib
  23 add_project_link_arguments('-lm', language: 'c')
  24 dpdk_extra_ldflags += '-lm'
  25
  26 # for linux link against dl, for bsd execinfo
  27 if host_machine.system() == 'linux'
  28         link_lib = 'dl'
  29 else
  30         link_lib = 'execinfo'
  31 endif
  32 add_project_link_arguments('-l' + link_lib, language: 'c')
  33 dpdk_extra_ldflags += '-l' + link_lib
  34
  35 # check for libraries used in multiple places in DPDK
  36 has_libnuma = 0
  37 numa_dep = cc.find_library('numa', required: false)
  38 if numa_dep.found() and cc.has_header('numaif.h')
  39         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
  40         has_libnuma = 1
  41         add_project_link_arguments('-lnuma', language: 'c')
  42         dpdk_extra_ldflags += '-lnuma'
  43 endif
  44
  45 # check for strlcpy
  46 if host_machine.system() == 'linux' and cc.find_library('bsd', required: false).found()
  47         dpdk_conf.set('RTE_USE_LIBBSD', 1)
  48         add_project_link_arguments('-lbsd', language: 'c')
  49         dpdk_extra_ldflags += '-lbsd'
  50 endif
  51
  52 # add -include rte_config to cflags
  53 add_project_arguments('-include', 'rte_config.h', language: 'c')
  54
  55 # enable extra warnings and disable any unwanted warnings
  56 warning_flags = [
  57         '-Wsign-compare',
  58         '-Wcast-qual',
  59         '-Wno-address-of-packed-member',
  60         '-Wno-format-truncation'
  61 ]
  62 foreach arg: warning_flags
  63         if cc.has_argument(arg)
  64                 add_project_arguments(arg, language: 'c')
  65         endif
  66 endforeach
  67
  68 # set other values pulled from the build options
  69 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
  70 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
  71 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
  72 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
  73 # values which have defaults which may be overridden
  74 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
  75
  76 compile_time_cpuflags = []
  77 if host_machine.cpu_family().startswith('x86')
  78         arch_subdir = 'x86'
  79 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
  80         arch_subdir = 'arm'
  81 endif
  82 subdir(arch_subdir)
  83 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
  84
  85 # set the install path for the drivers
  86 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
  87
  88 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))