config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # set the major version, which might be used by drivers and libraries
  12 # depending on the configuration options
  13 pver = meson.project_version().split('.')
  14 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  15
  16 # extract all version information into the build configuration
  17 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  18 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  19 if pver.get(2).contains('-rc')
  20         rc_ver = pver.get(2).split('-rc')
  21         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  22         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  23         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  24 else
  25         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  26         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  27 # for actual, non-rc releases, set the release value to 99 to ensure releases
  28 # have higher version numbers than their respective release candidates
  29         dpdk_conf.set('RTE_VER_RELEASE', 99)
  30 endif
  31
  32 pmd_subdir_opt = get_option('drivers_install_subdir')
  33 if pmd_subdir_opt.contains('<VERSION>')
  34         pmd_subdir_opt = major_version.join(pmd_subdir_opt.split('<VERSION>'))
  35 endif
  36 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  37 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  38
  39 # set the machine type and cflags for it
  40 if meson.is_cross_build()
  41         machine = host_machine.cpu()
  42 else
  43         machine = get_option('machine')
  44 endif
  45
  46 # machine type 'default' is special, it defaults to the per arch agreed common
  47 # minimal baseline needed for DPDK.
  48 # That might not be the most optimized, but the most portable version while
  49 # still being able to support the CPU features required for DPDK.
  50 # This can be bumped up by the DPDK project, but it can never be an
  51 # invariant like 'native'
  52 if machine == 'default'
  53         if host_machine.cpu_family().startswith('x86')
  54                 # matches the old pre-meson build systems default
  55                 machine = 'corei7'
  56         elif host_machine.cpu_family().startswith('arm')
  57                 machine = 'armv7-a'
  58         elif host_machine.cpu_family().startswith('aarch')
  59                 # arm64 manages defaults in config/arm/meson.build
  60                 machine = 'default'
  61         elif host_machine.cpu_family().startswith('ppc')
  62                 machine = 'power8'
  63         endif
  64 endif
  65
  66 dpdk_conf.set('RTE_MACHINE', machine)
  67 machine_args = []
  68
  69 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  70 if host_machine.cpu_family().startswith('ppc')
  71         machine_args += '-mcpu=' + machine
  72         machine_args += '-mtune=' + machine
  73 else
  74         machine_args += '-march=' + machine
  75 endif
  76
  77 toolchain = cc.get_id()
  78 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  79 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  80
  81 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
  82
  83 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
  84 dpdk_extra_ldflags += '-Wl,--no-as-needed'
  85
  86 # use pthreads
  87 add_project_link_arguments('-pthread', language: 'c')
  88 dpdk_extra_ldflags += '-pthread'
  89
  90 # on some OS, maths functions are in a separate library
  91 if cc.find_library('libm', required : false).found()
  92         # some libs depend on maths lib
  93         add_project_link_arguments('-lm', language: 'c')
  94         dpdk_extra_ldflags += '-lm'
  95 endif
  96
  97 # for linux link against dl, for bsd execinfo
  98 if host_machine.system() == 'linux'
  99         link_lib = 'dl'
 100 elif host_machine.system() == 'freebsd'
 101         link_lib = 'execinfo'
 102 else
 103         link_lib = ''
 104 endif
 105
 106 # if link_lib is empty, do not add it to project properties
 107 if link_lib != ''
 108         add_project_link_arguments('-l' + link_lib, language: 'c')
 109         dpdk_extra_ldflags += '-l' + link_lib
 110 endif
 111
 112 # check for libraries used in multiple places in DPDK
 113 has_libnuma = 0
 114 numa_dep = cc.find_library('numa', required: false)
 115 if numa_dep.found() and cc.has_header('numaif.h')
 116         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 117         has_libnuma = 1
 118         add_project_link_arguments('-lnuma', language: 'c')
 119         dpdk_extra_ldflags += '-lnuma'
 120 endif
 121
 122 # check for strlcpy
 123 if host_machine.system() == 'linux'
 124         libbsd = dependency('libbsd', required: false)
 125         if libbsd.found()
 126                 dpdk_conf.set('RTE_USE_LIBBSD', 1)
 127         endif
 128 endif
 129
 130 # add -include rte_config to cflags
 131 add_project_arguments('-include', 'rte_config.h', language: 'c')
 132
 133 # enable extra warnings and disable any unwanted warnings
 134 warning_flags = [
 135         '-Wsign-compare',
 136         '-Wcast-qual',
 137         '-Wno-address-of-packed-member'
 138 ]
 139 if not dpdk_conf.get('RTE_ARCH_64')
 140 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 141         warning_flags += '-Wno-pointer-to-int-cast'
 142 endif
 143 foreach arg: warning_flags
 144         if cc.has_argument(arg)
 145                 add_project_arguments(arg, language: 'c')
 146         endif
 147 endforeach
 148
 149 # set other values pulled from the build options
 150 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 151 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 152 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 153 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 154 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
 155 # values which have defaults which may be overridden
 156 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 157 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 158 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 159
 160
 161 compile_time_cpuflags = []
 162 if host_machine.cpu_family().startswith('x86')
 163         arch_subdir = 'x86'
 164 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 165         arch_subdir = 'arm'
 166 elif host_machine.cpu_family().startswith('ppc')
 167         arch_subdir = 'ppc_64'
 168 endif
 169 subdir(arch_subdir)
 170 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 171
 172 # set the install path for the drivers
 173 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 174
 175 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 176
 177 # enable VFIO only if it is linux OS
 178 dpdk_conf.set('RTE_EAL_VFIO', host_machine.system() == 'linux')