config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 # set the major version, which might be used by drivers and libraries
   5 # depending on the configuration options
   6 pver = meson.project_version().split('.')
   7 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
   8
   9 # extract all version information into the build configuration
  10 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  11 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  12 if pver.get(2).contains('-rc')
  13         rc_ver = pver.get(2).split('-rc')
  14         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  15         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  16         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  17 else
  18         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  19         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  20 # for actual, non-rc releases, set the release value to 99 to ensure releases
  21 # have higher version numbers than their respective release candidates
  22         dpdk_conf.set('RTE_VER_RELEASE', 99)
  23 endif
  24
  25 pmd_subdir_opt = get_option('drivers_install_subdir')
  26 if pmd_subdir_opt.contains('<VERSION>')
  27         pmd_subdir_opt = major_version.join(pmd_subdir_opt.split('<VERSION>'))
  28 endif
  29 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  30 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  31
  32 # set the machine type and cflags for it
  33 if meson.is_cross_build()
  34         machine = host_machine.cpu()
  35 else
  36         machine = get_option('machine')
  37 endif
  38
  39 # machine type 'default' is special, it defaults to the per arch agreed common
  40 # minimal baseline needed for DPDK.
  41 # That might not be the most optimized, but the most portable version while
  42 # still being able to support the CPU features required for DPDK.
  43 # This can be bumped up by the DPDK project, but it can never be an
  44 # invariant like 'native'
  45 if machine == 'default'
  46         if host_machine.cpu_family().startswith('x86')
  47                 # matches the old pre-meson build systems default
  48                 machine = 'corei7'
  49         elif host_machine.cpu_family().startswith('arm')
  50                 machine = 'armv7-a'
  51         elif host_machine.cpu_family().startswith('aarch')
  52                 # arm64 manages defaults in config/arm/meson.build
  53                 machine = 'default'
  54         elif host_machine.cpu_family().startswith('ppc')
  55                 machine = 'power8'
  56         endif
  57 endif
  58
  59 dpdk_conf.set('RTE_MACHINE', machine)
  60 machine_args = []
  61
  62 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  63 if host_machine.cpu_family().startswith('ppc')
  64         machine_args += '-mcpu=' + machine
  65         machine_args += '-mtune=' + machine
  66 else
  67         machine_args += '-march=' + machine
  68 endif
  69
  70 toolchain = cc.get_id()
  71 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  72 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  73
  74 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
  75
  76 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
  77 dpdk_extra_ldflags += '-Wl,--no-as-needed'
  78
  79 # use pthreads
  80 add_project_link_arguments('-pthread', language: 'c')
  81 dpdk_extra_ldflags += '-pthread'
  82
  83 # some libs depend on maths lib
  84 add_project_link_arguments('-lm', language: 'c')
  85 dpdk_extra_ldflags += '-lm'
  86
  87 # for linux link against dl, for bsd execinfo
  88 if host_machine.system() == 'linux'
  89         link_lib = 'dl'
  90 else
  91         link_lib = 'execinfo'
  92 endif
  93 add_project_link_arguments('-l' + link_lib, language: 'c')
  94 dpdk_extra_ldflags += '-l' + link_lib
  95
  96 # check for libraries used in multiple places in DPDK
  97 has_libnuma = 0
  98 numa_dep = cc.find_library('numa', required: false)
  99 if numa_dep.found() and cc.has_header('numaif.h')
 100         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 101         has_libnuma = 1
 102         add_project_link_arguments('-lnuma', language: 'c')
 103         dpdk_extra_ldflags += '-lnuma'
 104 endif
 105
 106 # check for strlcpy
 107 if host_machine.system() == 'linux'
 108         libbsd = dependency('libbsd', required: false)
 109         if libbsd.found()
 110                 dpdk_conf.set('RTE_USE_LIBBSD', 1)
 111         endif
 112 endif
 113
 114 # add -include rte_config to cflags
 115 add_project_arguments('-include', 'rte_config.h', language: 'c')
 116
 117 # enable extra warnings and disable any unwanted warnings
 118 warning_flags = [
 119         '-Wsign-compare',
 120         '-Wcast-qual',
 121         '-Wno-address-of-packed-member'
 122 ]
 123 if not dpdk_conf.get('RTE_ARCH_64')
 124 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 125         warning_flags += '-Wno-pointer-to-int-cast'
 126 endif
 127 foreach arg: warning_flags
 128         if cc.has_argument(arg)
 129                 add_project_arguments(arg, language: 'c')
 130         endif
 131 endforeach
 132
 133 # set other values pulled from the build options
 134 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 135 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 136 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 137 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 138 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
 139 # values which have defaults which may be overridden
 140 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 141 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 142 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 143
 144
 145 compile_time_cpuflags = []
 146 if host_machine.cpu_family().startswith('x86')
 147         arch_subdir = 'x86'
 148 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 149         arch_subdir = 'arm'
 150 elif host_machine.cpu_family().startswith('ppc')
 151         arch_subdir = 'ppc_64'
 152 endif
 153 subdir(arch_subdir)
 154 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 155
 156 # set the install path for the drivers
 157 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 158
 159 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 160
 161 # enable VFIO only if it is linux OS
 162 dpdk_conf.set('RTE_EAL_VFIO', host_machine.system() == 'linux')