config/meson.build

   1 #   BSD LICENSE
   2 #
   3 #   Copyright(c) 2017 Intel Corporation.
   4 #   All rights reserved.
   5 #
   6 #   Redistribution and use in source and binary forms, with or without
   7 #   modification, are permitted provided that the following conditions
   8 #   are met:
   9 #
  10 #     * Redistributions of source code must retain the above copyright
  11 #       notice, this list of conditions and the following disclaimer.
  12 #     * Redistributions in binary form must reproduce the above copyright
  13 #       notice, this list of conditions and the following disclaimer in
  14 #       the documentation and/or other materials provided with the
  15 #       distribution.
  16 #     * Neither the name of Intel Corporation nor the names of its
  17 #       contributors may be used to endorse or promote products derived
  18 #       from this software without specific prior written permission.
  19 #
  20 #   THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  21 #   "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  22 #   LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  23 #   A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  24 #   OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  25 #   SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  26 #   LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27 #   DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28 #   THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29 #   (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  30 #   OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31
  32 # set the machine type and cflags for it
  33 machine = get_option('machine')
  34 dpdk_conf.set('RTE_MACHINE', machine)
  35 add_project_arguments('-march=@0@'.format(machine), language: 'c')
  36 # some libs depend on maths lib
  37 add_project_link_arguments('-lm', language: 'c')
  38 dpdk_extra_ldflags += '-lm'
  39
  40 # check for libraries used in multiple places in DPDK
  41 has_libnuma = 0
  42 numa_dep = cc.find_library('numa', required: false)
  43 if numa_dep.found() and cc.has_header('numaif.h')
  44         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
  45         has_libnuma = 1
  46         add_project_link_arguments('-lnuma', language: 'c')
  47         dpdk_extra_ldflags += '-lnuma'
  48 endif
  49
  50 # add -include rte_config to cflags
  51 add_project_arguments('-include', 'rte_config.h', language: 'c')
  52
  53 # enable extra warnings and disable any unwanted warnings
  54 warning_flags = [
  55         '-Wsign-compare',
  56         '-Wcast-qual',
  57         '-Wno-address-of-packed-member',
  58         '-Wno-format-truncation'
  59 ]
  60 foreach arg: warning_flags
  61         if cc.has_argument(arg)
  62                 add_project_arguments(arg, language: 'c')
  63         endif
  64 endforeach
  65
  66 compile_time_cpuflags = []
  67 if host_machine.cpu_family().startswith('x86')
  68         arch_subdir = 'x86'
  69         subdir(arch_subdir)
  70 endif
  71 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
  72
  73 # set the install path for the drivers
  74 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
  75
  76 # set other values pulled from the build options
  77 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
  78 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
  79 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
  80 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
  81 # values which have defaults which may be overridden
  82 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
  83
  84 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))