config/x86/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2020 Intel Corporation
   3
   4 # get binutils version for the workaround of Bug 97
   5 if not is_windows
   6     binutils_ok = run_command(binutils_avx512_check)
   7     if binutils_ok.returncode() != 0 and cc.has_argument('-mno-avx512f')
   8         machine_args += '-mno-avx512f'
   9         warning('Binutils error with AVX512 assembly, disabling AVX512 support')
  10     endif
  11 endif
  12
  13 # check if compiler is working with _mm512_extracti64x4_epi64
  14 # Ref: https://gcc.gnu.org/bugzilla/show_bug.cgi?id=82887
  15 if cc.has_argument('-mavx512f')
  16     code = '''#include <immintrin.h>
  17     void test(__m512i zmm){
  18         __m256i ymm = _mm512_extracti64x4_epi64(zmm, 0);}'''
  19     result = cc.compiles(code, args : '-mavx512f', name : 'AVX512 checking')
  20     if result == false
  21         machine_args += '-mno-avx512f'
  22         warning('Broken _mm512_extracti64x4_epi64, disabling AVX512 support')
  23     endif
  24 endif
  25
  26 # we require SSE4.2 for DPDK
  27 if cc.get_define('__SSE4_2__', args: machine_args) == ''
  28     message('SSE 4.2 not enabled by default, explicitly enabling')
  29     machine_args += '-msse4'
  30 endif
  31
  32 base_flags = ['SSE', 'SSE2', 'SSE3','SSSE3', 'SSE4_1', 'SSE4_2']
  33 foreach f:base_flags
  34     compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  35 endforeach
  36
  37 optional_flags = [
  38         'AES',
  39         'AVX',
  40         'AVX2',
  41         'AVX512BW',
  42         'AVX512CD',
  43         'AVX512DQ',
  44         'AVX512F',
  45         'AVX512VL',
  46         'PCLMUL',
  47         'RDRND',
  48         'RDSEED',
  49         'VPCLMULQDQ',
  50 ]
  51 foreach f:optional_flags
  52     if cc.get_define('__@0@__'.format(f), args: machine_args) == '1'
  53         if f == 'PCLMUL' # special case flags with different defines
  54             f = 'PCLMULQDQ'
  55         elif f == 'RDRND'
  56             f = 'RDRAND'
  57         endif
  58         compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  59     endif
  60 endforeach
  61
  62
  63 dpdk_conf.set('RTE_ARCH_X86', 1)
  64 if dpdk_conf.get('RTE_ARCH_64')
  65     dpdk_conf.set('RTE_ARCH_X86_64', 1)
  66     dpdk_conf.set('RTE_ARCH', 'x86_64')
  67 else
  68     dpdk_conf.set('RTE_ARCH_I686', 1)
  69     dpdk_conf.set('RTE_ARCH', 'i686')
  70 endif
  71
  72 dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)