config/x86/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # get binutils version for the workaround of Bug 97
   5 if not is_windows
   6         ldver = run_command('ld', '-v').stdout().strip()
   7         if ldver.contains('2.30') and cc.has_argument('-mno-avx512f')
   8                 machine_args += '-mno-avx512f'
   9                 message('Binutils 2.30 detected, disabling AVX512 support as workaround for bug #97')
  10         endif
  11         if ldver.contains('2.31') and cc.has_argument('-mno-avx512f')
  12                 machine_args += '-mno-avx512f'
  13                 message('Binutils 2.31 detected, disabling AVX512 support as workaround for bug #249')
  14         endif
  15 endif
  16
  17 # we require SSE4.2 for DPDK
  18 sse_errormsg = '''SSE4.2 instruction set is required for DPDK.
  19 Please set the machine type to "nehalem" or "corei7" or higher value'''
  20
  21 if cc.get_define('__SSE4_2__', args: machine_args) == ''
  22         error(sse_errormsg)
  23 endif
  24
  25 base_flags = ['SSE', 'SSE2', 'SSE3','SSSE3', 'SSE4_1', 'SSE4_2']
  26 foreach f:base_flags
  27         dpdk_conf.set('RTE_MACHINE_CPUFLAG_' + f, 1)
  28         compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  29 endforeach
  30
  31 optional_flags = ['AES', 'PCLMUL',
  32                 'AVX', 'AVX2', 'AVX512F',
  33                 'RDRND', 'RDSEED']
  34 foreach f:optional_flags
  35         if cc.get_define('__@0@__'.format(f), args: machine_args) == '1'
  36                 if f == 'PCLMUL' # special case flags with different defines
  37                         f = 'PCLMULQDQ'
  38                 elif f == 'RDRND'
  39                         f = 'RDRAND'
  40                 endif
  41                 dpdk_conf.set('RTE_MACHINE_CPUFLAG_' + f, 1)
  42                 compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  43         endif
  44 endforeach
  45
  46
  47 dpdk_conf.set('RTE_ARCH_X86', 1)
  48 if dpdk_conf.get('RTE_ARCH_64')
  49         dpdk_conf.set('RTE_ARCH_X86_64', 1)
  50         dpdk_conf.set('RTE_ARCH', 'x86_64')
  51 else
  52         dpdk_conf.set('RTE_ARCH_I686', 1)
  53         dpdk_conf.set('RTE_ARCH', 'i686')
  54 endif
  55
  56 dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)