config/x86/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # get binutils version for the workaround of Bug 97
   5 if not is_windows
   6         ldver = run_command('ld', '-v').stdout().strip()
   7         if ldver.contains('2.30') and cc.has_argument('-mno-avx512f')
   8                 machine_args += '-mno-avx512f'
   9                 message('Binutils 2.30 detected, disabling AVX512 support as workaround for bug #97')
  10         endif
  11         if ldver.contains('2.31') and cc.has_argument('-mno-avx512f')
  12                 machine_args += '-mno-avx512f'
  13                 message('Binutils 2.31 detected, disabling AVX512 support as workaround for bug #249')
  14         endif
  15 endif
  16
  17 # we require SSE4.2 for DPDK
  18 if cc.get_define('__SSE4_2__', args: machine_args) == ''
  19         message('SSE 4.2 not enabled by default, explicitly enabling')
  20         machine_args += '-msse4'
  21 endif
  22
  23 base_flags = ['SSE', 'SSE2', 'SSE3','SSSE3', 'SSE4_1', 'SSE4_2']
  24 foreach f:base_flags
  25         dpdk_conf.set('RTE_MACHINE_CPUFLAG_' + f, 1)
  26         compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  27 endforeach
  28
  29 optional_flags = ['AES', 'PCLMUL',
  30                 'AVX', 'AVX2', 'AVX512F',
  31                 'RDRND', 'RDSEED']
  32 foreach f:optional_flags
  33         if cc.get_define('__@0@__'.format(f), args: machine_args) == '1'
  34                 if f == 'PCLMUL' # special case flags with different defines
  35                         f = 'PCLMULQDQ'
  36                 elif f == 'RDRND'
  37                         f = 'RDRAND'
  38                 endif
  39                 dpdk_conf.set('RTE_MACHINE_CPUFLAG_' + f, 1)
  40                 compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  41         endif
  42 endforeach
  43
  44
  45 dpdk_conf.set('RTE_ARCH_X86', 1)
  46 if dpdk_conf.get('RTE_ARCH_64')
  47         dpdk_conf.set('RTE_ARCH_X86_64', 1)
  48         dpdk_conf.set('RTE_ARCH', 'x86_64')
  49 else
  50         dpdk_conf.set('RTE_ARCH_I686', 1)
  51         dpdk_conf.set('RTE_ARCH', 'i686')
  52 endif
  53
  54 dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)