drivers/common/mlx5/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2019 Mellanox Technologies, Ltd
   3
   4 if not is_linux
   5         build = false
   6         reason = 'only supported on Linux'
   7         subdir_done()
   8 endif
   9 build = true
  10
  11 pmd_dlopen = (get_option('ibverbs_link') == 'dlopen')
  12 LIB_GLUE_BASE = 'librte_pmd_mlx5_glue.so'
  13 LIB_GLUE_VERSION = '20.02.0'
  14 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
  15 if pmd_dlopen
  16         dpdk_conf.set('RTE_IBVERBS_LINK_DLOPEN', 1)
  17         cflags += [
  18                 '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  19                 '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  20         ]
  21 endif
  22
  23 libnames = [ 'mlx5', 'ibverbs' ]
  24 libs = []
  25 foreach libname:libnames
  26         lib = dependency('lib' + libname, required:false)
  27         if not lib.found()
  28                 lib = cc.find_library(libname, required:false)
  29         endif
  30         if lib.found()
  31                 libs += lib
  32         else
  33                 build = false
  34                 reason = 'missing dependency, "' + libname + '"'
  35         endif
  36 endforeach
  37
  38 if build
  39         allow_experimental_apis = true
  40         deps += ['hash', 'pci', 'net', 'eal']
  41         ext_deps += libs
  42         sources = files(
  43                 'mlx5_devx_cmds.c',
  44                 'mlx5_common.c',
  45         )
  46         if not pmd_dlopen
  47                 sources += files('mlx5_glue.c')
  48         endif
  49         cflags_options = [
  50                 '-std=c11',
  51                 '-Wno-strict-prototypes',
  52                 '-D_BSD_SOURCE',
  53                 '-D_DEFAULT_SOURCE',
  54                 '-D_XOPEN_SOURCE=600'
  55         ]
  56         foreach option:cflags_options
  57                 if cc.has_argument(option)
  58                         cflags += option
  59                 endif
  60         endforeach
  61         if get_option('buildtype').contains('debug')
  62                 cflags += [ '-pedantic', '-UNDEBUG', '-DPEDANTIC' ]
  63         else
  64                 cflags += [ '-DNDEBUG', '-UPEDANTIC' ]
  65         endif
  66         # To maintain the compatibility with the make build system
  67         # mlx5_autoconf.h file is still generated.
  68         # input array for meson member search:
  69         # [ "MACRO to define if found", "header for the search",
  70         #   "symbol to search", "struct member to search" ]
  71         has_member_args = [
  72                 [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  73                 'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  74                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V42', 'infiniband/verbs.h',
  75                 'struct ibv_counter_set_init_attr', 'counter_set_id' ],
  76                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V45', 'infiniband/verbs.h',
  77                 'struct ibv_counters_init_attr', 'comp_mask' ],
  78         ]
  79         # input array for meson symbol search:
  80         # [ "MACRO to define if found", "header for the search",
  81         #   "symbol to search" ]
  82         has_sym_args = [
  83                 [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
  84                 'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
  85                 [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
  86                 'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
  87                 [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
  88                 'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
  89                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
  90                 'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
  91                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_PAD', 'infiniband/mlx5dv.h',
  92                 'MLX5DV_CQ_INIT_ATTR_FLAGS_CQE_PAD' ],
  93                 [ 'HAVE_IBV_FLOW_DV_SUPPORT', 'infiniband/mlx5dv.h',
  94                 'mlx5dv_create_flow_action_packet_reformat' ],
  95                 [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
  96                 'IBV_FLOW_SPEC_MPLS' ],
  97                 [ 'HAVE_IBV_WQ_FLAGS_PCI_WRITE_END_PADDING', 'infiniband/verbs.h',
  98                 'IBV_WQ_FLAGS_PCI_WRITE_END_PADDING' ],
  99                 [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
 100                 'IBV_WQ_FLAG_RX_END_PADDING' ],
 101                 [ 'HAVE_MLX5DV_DR_DEVX_PORT', 'infiniband/mlx5dv.h',
 102                 'mlx5dv_query_devx_port' ],
 103                 [ 'HAVE_IBV_DEVX_OBJ', 'infiniband/mlx5dv.h',
 104                 'mlx5dv_devx_obj_create' ],
 105                 [ 'HAVE_IBV_FLOW_DEVX_COUNTERS', 'infiniband/mlx5dv.h',
 106                 'MLX5DV_FLOW_ACTION_COUNTERS_DEVX' ],
 107                 [ 'HAVE_IBV_DEVX_ASYNC', 'infiniband/mlx5dv.h',
 108                 'mlx5dv_devx_obj_query_async' ],
 109                 [ 'HAVE_MLX5DV_DR_ACTION_DEST_DEVX_TIR', 'infiniband/mlx5dv.h',
 110                 'mlx5dv_dr_action_create_dest_devx_tir' ],
 111                 [ 'HAVE_MLX5_DR_CREATE_ACTION_FLOW_METER', 'infiniband/mlx5dv.h',
 112                 'mlx5dv_dr_action_create_flow_meter' ],
 113                 [ 'HAVE_MLX5DV_MMAP_GET_NC_PAGES_CMD', 'infiniband/mlx5dv.h',
 114                 'MLX5_MMAP_GET_NC_PAGES_CMD' ],
 115                 [ 'HAVE_MLX5DV_DR', 'infiniband/mlx5dv.h',
 116                 'MLX5DV_DR_DOMAIN_TYPE_NIC_RX' ],
 117                 [ 'HAVE_MLX5DV_DR_ESWITCH', 'infiniband/mlx5dv.h',
 118                 'MLX5DV_DR_DOMAIN_TYPE_FDB' ],
 119                 [ 'HAVE_MLX5DV_DR_VLAN', 'infiniband/mlx5dv.h',
 120                 'mlx5dv_dr_action_create_push_vlan' ],
 121                 [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 122                 'SUPPORTED_40000baseKR4_Full' ],
 123                 [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 124                 'SUPPORTED_40000baseCR4_Full' ],
 125                 [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 126                 'SUPPORTED_40000baseSR4_Full' ],
 127                 [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 128                 'SUPPORTED_40000baseLR4_Full' ],
 129                 [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 130                 'SUPPORTED_56000baseKR4_Full' ],
 131                 [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 132                 'SUPPORTED_56000baseCR4_Full' ],
 133                 [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 134                 'SUPPORTED_56000baseSR4_Full' ],
 135                 [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 136                 'SUPPORTED_56000baseLR4_Full' ],
 137                 [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 138                 'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 139                 [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 140                 'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 141                 [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 142                 'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 143                 [ 'HAVE_IFLA_NUM_VF', 'linux/if_link.h',
 144                 'IFLA_NUM_VF' ],
 145                 [ 'HAVE_IFLA_EXT_MASK', 'linux/if_link.h',
 146                 'IFLA_EXT_MASK' ],
 147                 [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 148                 'IFLA_PHYS_SWITCH_ID' ],
 149                 [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 150                 'IFLA_PHYS_PORT_NAME' ],
 151                 [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 152                 'RDMA_NL_NLDEV' ],
 153                 [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 154                 'RDMA_NLDEV_CMD_GET' ],
 155                 [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 156                 'RDMA_NLDEV_CMD_PORT_GET' ],
 157                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 158                 'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 159                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 160                 'RDMA_NLDEV_ATTR_DEV_NAME' ],
 161                 [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 162                 'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 163                 [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 164                 'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 165                 [ 'HAVE_MLX5_DR_FLOW_DUMP', 'infiniband/mlx5dv.h',
 166                 'mlx5dv_dump_dr_domain'],
 167         ]
 168         config = configuration_data()
 169         foreach arg:has_sym_args
 170                 config.set(arg[0], cc.has_header_symbol(arg[1], arg[2],
 171                         dependencies: libs))
 172         endforeach
 173         foreach arg:has_member_args
 174                 file_prefix = '#include <' + arg[1] + '>'
 175                 config.set(arg[0], cc.has_member(arg[2], arg[3],
 176                         prefix : file_prefix, dependencies: libs))
 177         endforeach
 178         configure_file(output : 'mlx5_autoconf.h', configuration : config)
 179 endif
 180 # Build Glue Library
 181 if pmd_dlopen and build
 182         dlopen_name = 'mlx5_glue'
 183         dlopen_lib_name = driver_name_fmt.format(dlopen_name)
 184         dlopen_so_version = LIB_GLUE_VERSION
 185         dlopen_sources = files('mlx5_glue.c')
 186         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 187         dlopen_includes = [global_inc]
 188         dlopen_includes += include_directories(
 189                 '../../../lib/librte_eal/common/include/generic',
 190         )
 191         shared_lib = shared_library(
 192                 dlopen_lib_name,
 193                 dlopen_sources,
 194                 include_directories: dlopen_includes,
 195                 c_args: cflags,
 196                 dependencies: libs,
 197                 link_args: [
 198                 '-Wl,-export-dynamic',
 199                 '-Wl,-h,@0@'.format(LIB_GLUE),
 200                 ],
 201                 soversion: dlopen_so_version,
 202                 install: true,
 203                 install_dir: dlopen_install_dir,
 204         )
 205 endif