drivers/common/mlx5/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2019 Mellanox Technologies, Ltd
   3
   4 if not is_linux
   5         build = false
   6         reason = 'only supported on Linux'
   7         subdir_done()
   8 endif
   9
  10 pmd_dlopen = (get_option('ibverbs_link') == 'dlopen')
  11 LIB_GLUE_BASE = 'librte_pmd_mlx5_glue.so'
  12 LIB_GLUE_VERSION = '20.02.0'
  13 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
  14 if pmd_dlopen
  15         dpdk_conf.set('RTE_IBVERBS_LINK_DLOPEN', 1)
  16         cflags += [
  17                 '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  18                 '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  19         ]
  20 endif
  21
  22 libnames = [ 'mlx5', 'ibverbs' ]
  23 libs = []
  24 foreach libname:libnames
  25         lib = dependency('lib' + libname, required:false)
  26         if not lib.found()
  27                 lib = cc.find_library(libname, required:false)
  28         endif
  29         if lib.found()
  30                 libs += lib
  31         else
  32                 build = false
  33                 reason = 'missing dependency, "' + libname + '"'
  34                 subdir_done()
  35         endif
  36 endforeach
  37
  38 allow_experimental_apis = true
  39 deps += ['hash', 'pci', 'net', 'eal', 'kvargs']
  40 ext_deps += libs
  41 sources = files(
  42         'mlx5_devx_cmds.c',
  43         'mlx5_common.c',
  44         'mlx5_nl.c',
  45 )
  46 if not pmd_dlopen
  47         sources += files('mlx5_glue.c')
  48 endif
  49 cflags_options = [
  50         '-std=c11',
  51         '-Wno-strict-prototypes',
  52         '-D_BSD_SOURCE',
  53         '-D_DEFAULT_SOURCE',
  54         '-D_XOPEN_SOURCE=600'
  55 ]
  56 foreach option:cflags_options
  57         if cc.has_argument(option)
  58                 cflags += option
  59         endif
  60 endforeach
  61 if get_option('buildtype').contains('debug')
  62         cflags += [ '-pedantic', '-DPEDANTIC' ]
  63 else
  64         cflags += [ '-UPEDANTIC' ]
  65 endif
  66 # To maintain the compatibility with the make build system
  67 # mlx5_autoconf.h file is still generated.
  68 # input array for meson member search:
  69 # [ "MACRO to define if found", "header for the search",
  70 #   "symbol to search", "struct member to search" ]
  71 has_member_args = [
  72         [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  73         'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  74         [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V42', 'infiniband/verbs.h',
  75         'struct ibv_counter_set_init_attr', 'counter_set_id' ],
  76         [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V45', 'infiniband/verbs.h',
  77         'struct ibv_counters_init_attr', 'comp_mask' ],
  78 ]
  79 # input array for meson symbol search:
  80 # [ "MACRO to define if found", "header for the search",
  81 #   "symbol to search" ]
  82 has_sym_args = [
  83         [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
  84         'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
  85         [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
  86         'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
  87         [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
  88         'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
  89         [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
  90         'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
  91         [ 'HAVE_IBV_MLX5_MOD_CQE_128B_PAD', 'infiniband/mlx5dv.h',
  92         'MLX5DV_CQ_INIT_ATTR_FLAGS_CQE_PAD' ],
  93         [ 'HAVE_IBV_FLOW_DV_SUPPORT', 'infiniband/mlx5dv.h',
  94         'mlx5dv_create_flow_action_packet_reformat' ],
  95         [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
  96         'IBV_FLOW_SPEC_MPLS' ],
  97         [ 'HAVE_IBV_WQ_FLAGS_PCI_WRITE_END_PADDING', 'infiniband/verbs.h',
  98         'IBV_WQ_FLAGS_PCI_WRITE_END_PADDING' ],
  99         [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
 100         'IBV_WQ_FLAG_RX_END_PADDING' ],
 101         [ 'HAVE_MLX5DV_DR_DEVX_PORT', 'infiniband/mlx5dv.h',
 102         'mlx5dv_query_devx_port' ],
 103         [ 'HAVE_IBV_DEVX_OBJ', 'infiniband/mlx5dv.h',
 104         'mlx5dv_devx_obj_create' ],
 105         [ 'HAVE_IBV_FLOW_DEVX_COUNTERS', 'infiniband/mlx5dv.h',
 106         'MLX5DV_FLOW_ACTION_COUNTERS_DEVX' ],
 107         [ 'HAVE_IBV_DEVX_ASYNC', 'infiniband/mlx5dv.h',
 108         'mlx5dv_devx_obj_query_async' ],
 109         [ 'HAVE_MLX5DV_DR_ACTION_DEST_DEVX_TIR', 'infiniband/mlx5dv.h',
 110         'mlx5dv_dr_action_create_dest_devx_tir' ],
 111         [ 'HAVE_IBV_DEVX_EVENT', 'infiniband/mlx5dv.h',
 112         'mlx5dv_devx_get_event' ],
 113         [ 'HAVE_MLX5_DR_CREATE_ACTION_FLOW_METER', 'infiniband/mlx5dv.h',
 114         'mlx5dv_dr_action_create_flow_meter' ],
 115         [ 'HAVE_MLX5DV_MMAP_GET_NC_PAGES_CMD', 'infiniband/mlx5dv.h',
 116         'MLX5_MMAP_GET_NC_PAGES_CMD' ],
 117         [ 'HAVE_MLX5DV_DR', 'infiniband/mlx5dv.h',
 118         'MLX5DV_DR_DOMAIN_TYPE_NIC_RX' ],
 119         [ 'HAVE_MLX5DV_DR_ESWITCH', 'infiniband/mlx5dv.h',
 120         'MLX5DV_DR_DOMAIN_TYPE_FDB' ],
 121         [ 'HAVE_MLX5DV_DR_VLAN', 'infiniband/mlx5dv.h',
 122         'mlx5dv_dr_action_create_push_vlan' ],
 123         [ 'HAVE_IBV_VAR', 'infiniband/mlx5dv.h', 'mlx5dv_alloc_var' ],
 124         [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 125         'SUPPORTED_40000baseKR4_Full' ],
 126         [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 127         'SUPPORTED_40000baseCR4_Full' ],
 128         [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 129         'SUPPORTED_40000baseSR4_Full' ],
 130         [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 131         'SUPPORTED_40000baseLR4_Full' ],
 132         [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 133         'SUPPORTED_56000baseKR4_Full' ],
 134         [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 135         'SUPPORTED_56000baseCR4_Full' ],
 136         [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 137         'SUPPORTED_56000baseSR4_Full' ],
 138         [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 139         'SUPPORTED_56000baseLR4_Full' ],
 140         [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 141         'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 142         [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 143         'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 144         [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 145         'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 146         [ 'HAVE_IFLA_NUM_VF', 'linux/if_link.h',
 147         'IFLA_NUM_VF' ],
 148         [ 'HAVE_IFLA_EXT_MASK', 'linux/if_link.h',
 149         'IFLA_EXT_MASK' ],
 150         [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 151         'IFLA_PHYS_SWITCH_ID' ],
 152         [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 153         'IFLA_PHYS_PORT_NAME' ],
 154         [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 155         'RDMA_NL_NLDEV' ],
 156         [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 157         'RDMA_NLDEV_CMD_GET' ],
 158         [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 159         'RDMA_NLDEV_CMD_PORT_GET' ],
 160         [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 161         'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 162         [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 163         'RDMA_NLDEV_ATTR_DEV_NAME' ],
 164         [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 165         'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 166         [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 167         'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 168         [ 'HAVE_MLX5_DR_FLOW_DUMP', 'infiniband/mlx5dv.h',
 169         'mlx5dv_dump_dr_domain'],
 170         [ 'HAVE_DEVLINK', 'linux/devlink.h', 'DEVLINK_GENL_NAME' ],
 171 ]
 172 config = configuration_data()
 173 foreach arg:has_sym_args
 174         config.set(arg[0], cc.has_header_symbol(arg[1], arg[2],
 175                 dependencies: libs))
 176 endforeach
 177 foreach arg:has_member_args
 178         file_prefix = '#include <' + arg[1] + '>'
 179         config.set(arg[0], cc.has_member(arg[2], arg[3],
 180                 prefix : file_prefix, dependencies: libs))
 181 endforeach
 182 configure_file(output : 'mlx5_autoconf.h', configuration : config)
 183
 184 # Build Glue Library
 185 if pmd_dlopen
 186         dlopen_name = 'mlx5_glue'
 187         dlopen_lib_name = 'rte_pmd_@0@'.format(dlopen_name)
 188         dlopen_so_version = LIB_GLUE_VERSION
 189         dlopen_sources = files('mlx5_glue.c')
 190         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 191         dlopen_includes = [global_inc]
 192         dlopen_includes += include_directories(
 193                 '../../../lib/librte_eal/common/include/generic',
 194         )
 195         shared_lib = shared_library(
 196                 dlopen_lib_name,
 197                 dlopen_sources,
 198                 include_directories: dlopen_includes,
 199                 c_args: cflags,
 200                 dependencies: libs,
 201                 link_args: [
 202                 '-Wl,-export-dynamic',
 203                 '-Wl,-h,@0@'.format(LIB_GLUE),
 204                 ],
 205                 soversion: dlopen_so_version,
 206                 install: true,
 207                 install_dir: dlopen_install_dir,
 208         )
 209 endif