drivers/common/mlx5/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2019 Mellanox Technologies, Ltd
   3
   4 if not is_linux
   5         build = false
   6         reason = 'only supported on Linux'
   7         subdir_done()
   8 endif
   9
  10 static_ibverbs = (get_option('ibverbs_link') == 'static')
  11 dlopen_ibverbs = (get_option('ibverbs_link') == 'dlopen')
  12 LIB_GLUE_BASE = 'librte_pmd_mlx5_glue.so'
  13 LIB_GLUE_VERSION = '20.02.0'
  14 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
  15 if dlopen_ibverbs
  16         dpdk_conf.set('RTE_IBVERBS_LINK_DLOPEN', 1)
  17         cflags += [
  18                 '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  19                 '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  20         ]
  21 endif
  22
  23 libnames = [ 'mlx5', 'ibverbs' ]
  24 libs = []
  25 foreach libname:libnames
  26         lib = dependency('lib' + libname, static:static_ibverbs, required:false)
  27         if not lib.found() and not static_ibverbs
  28                 lib = cc.find_library(libname, required:false)
  29         endif
  30         if lib.found()
  31                 libs += lib
  32                 if not static_ibverbs and not dlopen_ibverbs
  33                         ext_deps += lib
  34                 endif
  35         else
  36                 build = false
  37                 reason = 'missing dependency, "' + libname + '"'
  38                 subdir_done()
  39         endif
  40 endforeach
  41 if static_ibverbs or dlopen_ibverbs
  42         # Build without adding shared libs to Requires.private
  43         ibv_cflags = run_command(pkgconf, '--cflags', 'libibverbs').stdout()
  44         ext_deps += declare_dependency(compile_args: ibv_cflags.split())
  45 endif
  46 if static_ibverbs
  47         # Add static deps ldflags to internal apps and Libs.private
  48         ibv_ldflags = run_command(ldflags_ibverbs_static, check:true).stdout()
  49         ext_deps += declare_dependency(link_args:ibv_ldflags.split())
  50 endif
  51
  52 allow_experimental_apis = true
  53 deps += ['hash', 'pci', 'net', 'eal', 'kvargs']
  54 sources = files(
  55         'mlx5_devx_cmds.c',
  56         'mlx5_common.c',
  57         'mlx5_nl.c',
  58 )
  59 if not dlopen_ibverbs
  60         sources += files('mlx5_glue.c')
  61 endif
  62 cflags_options = [
  63         '-std=c11',
  64         '-Wno-strict-prototypes',
  65         '-D_BSD_SOURCE',
  66         '-D_DEFAULT_SOURCE',
  67         '-D_XOPEN_SOURCE=600'
  68 ]
  69 foreach option:cflags_options
  70         if cc.has_argument(option)
  71                 cflags += option
  72         endif
  73 endforeach
  74 if get_option('buildtype').contains('debug')
  75         cflags += [ '-pedantic', '-DPEDANTIC' ]
  76 else
  77         cflags += [ '-UPEDANTIC' ]
  78 endif
  79 # To maintain the compatibility with the make build system
  80 # mlx5_autoconf.h file is still generated.
  81 # input array for meson member search:
  82 # [ "MACRO to define if found", "header for the search",
  83 #   "symbol to search", "struct member to search" ]
  84 has_member_args = [
  85         [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  86         'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  87         [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V42', 'infiniband/verbs.h',
  88         'struct ibv_counter_set_init_attr', 'counter_set_id' ],
  89         [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V45', 'infiniband/verbs.h',
  90         'struct ibv_counters_init_attr', 'comp_mask' ],
  91 ]
  92 # input array for meson symbol search:
  93 # [ "MACRO to define if found", "header for the search",
  94 #   "symbol to search" ]
  95 has_sym_args = [
  96         [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
  97         'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
  98         [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
  99         'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
 100         [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
 101         'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
 102         [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
 103         'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
 104         [ 'HAVE_IBV_MLX5_MOD_CQE_128B_PAD', 'infiniband/mlx5dv.h',
 105         'MLX5DV_CQ_INIT_ATTR_FLAGS_CQE_PAD' ],
 106         [ 'HAVE_IBV_FLOW_DV_SUPPORT', 'infiniband/mlx5dv.h',
 107         'mlx5dv_create_flow_action_packet_reformat' ],
 108         [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
 109         'IBV_FLOW_SPEC_MPLS' ],
 110         [ 'HAVE_IBV_WQ_FLAGS_PCI_WRITE_END_PADDING', 'infiniband/verbs.h',
 111         'IBV_WQ_FLAGS_PCI_WRITE_END_PADDING' ],
 112         [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
 113         'IBV_WQ_FLAG_RX_END_PADDING' ],
 114         [ 'HAVE_MLX5DV_DR_DEVX_PORT', 'infiniband/mlx5dv.h',
 115         'mlx5dv_query_devx_port' ],
 116         [ 'HAVE_IBV_DEVX_OBJ', 'infiniband/mlx5dv.h',
 117         'mlx5dv_devx_obj_create' ],
 118         [ 'HAVE_IBV_FLOW_DEVX_COUNTERS', 'infiniband/mlx5dv.h',
 119         'MLX5DV_FLOW_ACTION_COUNTERS_DEVX' ],
 120         [ 'HAVE_IBV_DEVX_ASYNC', 'infiniband/mlx5dv.h',
 121         'mlx5dv_devx_obj_query_async' ],
 122         [ 'HAVE_MLX5DV_DR_ACTION_DEST_DEVX_TIR', 'infiniband/mlx5dv.h',
 123         'mlx5dv_dr_action_create_dest_devx_tir' ],
 124         [ 'HAVE_IBV_DEVX_EVENT', 'infiniband/mlx5dv.h',
 125         'mlx5dv_devx_get_event' ],
 126         [ 'HAVE_MLX5_DR_CREATE_ACTION_FLOW_METER', 'infiniband/mlx5dv.h',
 127         'mlx5dv_dr_action_create_flow_meter' ],
 128         [ 'HAVE_MLX5DV_MMAP_GET_NC_PAGES_CMD', 'infiniband/mlx5dv.h',
 129         'MLX5_MMAP_GET_NC_PAGES_CMD' ],
 130         [ 'HAVE_MLX5DV_DR', 'infiniband/mlx5dv.h',
 131         'MLX5DV_DR_DOMAIN_TYPE_NIC_RX' ],
 132         [ 'HAVE_MLX5DV_DR_ESWITCH', 'infiniband/mlx5dv.h',
 133         'MLX5DV_DR_DOMAIN_TYPE_FDB' ],
 134         [ 'HAVE_MLX5DV_DR_VLAN', 'infiniband/mlx5dv.h',
 135         'mlx5dv_dr_action_create_push_vlan' ],
 136         [ 'HAVE_IBV_VAR', 'infiniband/mlx5dv.h', 'mlx5dv_alloc_var' ],
 137         [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 138         'SUPPORTED_40000baseKR4_Full' ],
 139         [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 140         'SUPPORTED_40000baseCR4_Full' ],
 141         [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 142         'SUPPORTED_40000baseSR4_Full' ],
 143         [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 144         'SUPPORTED_40000baseLR4_Full' ],
 145         [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 146         'SUPPORTED_56000baseKR4_Full' ],
 147         [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 148         'SUPPORTED_56000baseCR4_Full' ],
 149         [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 150         'SUPPORTED_56000baseSR4_Full' ],
 151         [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 152         'SUPPORTED_56000baseLR4_Full' ],
 153         [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 154         'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 155         [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 156         'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 157         [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 158         'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 159         [ 'HAVE_IFLA_NUM_VF', 'linux/if_link.h',
 160         'IFLA_NUM_VF' ],
 161         [ 'HAVE_IFLA_EXT_MASK', 'linux/if_link.h',
 162         'IFLA_EXT_MASK' ],
 163         [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 164         'IFLA_PHYS_SWITCH_ID' ],
 165         [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 166         'IFLA_PHYS_PORT_NAME' ],
 167         [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 168         'RDMA_NL_NLDEV' ],
 169         [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 170         'RDMA_NLDEV_CMD_GET' ],
 171         [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 172         'RDMA_NLDEV_CMD_PORT_GET' ],
 173         [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 174         'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 175         [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 176         'RDMA_NLDEV_ATTR_DEV_NAME' ],
 177         [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 178         'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 179         [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 180         'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 181         [ 'HAVE_MLX5_DR_FLOW_DUMP', 'infiniband/mlx5dv.h',
 182         'mlx5dv_dump_dr_domain'],
 183         [ 'HAVE_DEVLINK', 'linux/devlink.h', 'DEVLINK_GENL_NAME' ],
 184 ]
 185 config = configuration_data()
 186 foreach arg:has_sym_args
 187         config.set(arg[0], cc.has_header_symbol(arg[1], arg[2],
 188                 dependencies: libs))
 189 endforeach
 190 foreach arg:has_member_args
 191         file_prefix = '#include <' + arg[1] + '>'
 192         config.set(arg[0], cc.has_member(arg[2], arg[3],
 193                 prefix : file_prefix, dependencies: libs))
 194 endforeach
 195 configure_file(output : 'mlx5_autoconf.h', configuration : config)
 196
 197 # Build Glue Library
 198 if dlopen_ibverbs
 199         dlopen_name = 'mlx5_glue'
 200         dlopen_lib_name = 'rte_pmd_@0@'.format(dlopen_name)
 201         dlopen_so_version = LIB_GLUE_VERSION
 202         dlopen_sources = files('mlx5_glue.c')
 203         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 204         dlopen_includes = [global_inc]
 205         dlopen_includes += include_directories(
 206                 '../../../lib/librte_eal/include/generic',
 207         )
 208         shared_lib = shared_library(
 209                 dlopen_lib_name,
 210                 dlopen_sources,
 211                 include_directories: dlopen_includes,
 212                 c_args: cflags,
 213                 dependencies: libs,
 214                 link_args: [
 215                 '-Wl,-export-dynamic',
 216                 '-Wl,-h,@0@'.format(LIB_GLUE),
 217                 ],
 218                 soversion: dlopen_so_version,
 219                 install: true,
 220                 install_dir: dlopen_install_dir,
 221         )
 222 endif