drivers/common/mlx5/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2019 Mellanox Technologies, Ltd
   3
   4 if not is_linux
   5         build = false
   6         reason = 'only supported on Linux'
   7         subdir_done()
   8 endif
   9 build = true
  10
  11 pmd_dlopen = (get_option('ibverbs_link') == 'dlopen')
  12 LIB_GLUE_BASE = 'librte_pmd_mlx5_glue.so'
  13 LIB_GLUE_VERSION = '20.02.0'
  14 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
  15 if pmd_dlopen
  16         dpdk_conf.set('RTE_IBVERBS_LINK_DLOPEN', 1)
  17         cflags += [
  18                 '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  19                 '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  20         ]
  21 endif
  22
  23 libnames = [ 'mlx5', 'ibverbs' ]
  24 libs = []
  25 foreach libname:libnames
  26         lib = dependency('lib' + libname, required:false)
  27         if not lib.found()
  28                 lib = cc.find_library(libname, required:false)
  29         endif
  30         if lib.found()
  31                 libs += lib
  32         else
  33                 build = false
  34                 reason = 'missing dependency, "' + libname + '"'
  35         endif
  36 endforeach
  37
  38 if build
  39         allow_experimental_apis = true
  40         deps += ['hash', 'pci', 'net', 'eal', 'kvargs']
  41         ext_deps += libs
  42         sources = files(
  43                 'mlx5_devx_cmds.c',
  44                 'mlx5_common.c',
  45                 'mlx5_nl.c',
  46         )
  47         if not pmd_dlopen
  48                 sources += files('mlx5_glue.c')
  49         endif
  50         cflags_options = [
  51                 '-std=c11',
  52                 '-Wno-strict-prototypes',
  53                 '-D_BSD_SOURCE',
  54                 '-D_DEFAULT_SOURCE',
  55                 '-D_XOPEN_SOURCE=600'
  56         ]
  57         foreach option:cflags_options
  58                 if cc.has_argument(option)
  59                         cflags += option
  60                 endif
  61         endforeach
  62         if get_option('buildtype').contains('debug')
  63                 cflags += [ '-pedantic', '-UNDEBUG', '-DPEDANTIC' ]
  64         else
  65                 cflags += [ '-DNDEBUG', '-UPEDANTIC' ]
  66         endif
  67         # To maintain the compatibility with the make build system
  68         # mlx5_autoconf.h file is still generated.
  69         # input array for meson member search:
  70         # [ "MACRO to define if found", "header for the search",
  71         #   "symbol to search", "struct member to search" ]
  72         has_member_args = [
  73                 [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  74                 'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  75                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V42', 'infiniband/verbs.h',
  76                 'struct ibv_counter_set_init_attr', 'counter_set_id' ],
  77                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V45', 'infiniband/verbs.h',
  78                 'struct ibv_counters_init_attr', 'comp_mask' ],
  79         ]
  80         # input array for meson symbol search:
  81         # [ "MACRO to define if found", "header for the search",
  82         #   "symbol to search" ]
  83         has_sym_args = [
  84                 [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
  85                 'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
  86                 [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
  87                 'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
  88                 [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
  89                 'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
  90                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
  91                 'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
  92                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_PAD', 'infiniband/mlx5dv.h',
  93                 'MLX5DV_CQ_INIT_ATTR_FLAGS_CQE_PAD' ],
  94                 [ 'HAVE_IBV_FLOW_DV_SUPPORT', 'infiniband/mlx5dv.h',
  95                 'mlx5dv_create_flow_action_packet_reformat' ],
  96                 [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
  97                 'IBV_FLOW_SPEC_MPLS' ],
  98                 [ 'HAVE_IBV_WQ_FLAGS_PCI_WRITE_END_PADDING', 'infiniband/verbs.h',
  99                 'IBV_WQ_FLAGS_PCI_WRITE_END_PADDING' ],
 100                 [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
 101                 'IBV_WQ_FLAG_RX_END_PADDING' ],
 102                 [ 'HAVE_MLX5DV_DR_DEVX_PORT', 'infiniband/mlx5dv.h',
 103                 'mlx5dv_query_devx_port' ],
 104                 [ 'HAVE_IBV_DEVX_OBJ', 'infiniband/mlx5dv.h',
 105                 'mlx5dv_devx_obj_create' ],
 106                 [ 'HAVE_IBV_FLOW_DEVX_COUNTERS', 'infiniband/mlx5dv.h',
 107                 'MLX5DV_FLOW_ACTION_COUNTERS_DEVX' ],
 108                 [ 'HAVE_IBV_DEVX_ASYNC', 'infiniband/mlx5dv.h',
 109                 'mlx5dv_devx_obj_query_async' ],
 110                 [ 'HAVE_MLX5DV_DR_ACTION_DEST_DEVX_TIR', 'infiniband/mlx5dv.h',
 111                 'mlx5dv_dr_action_create_dest_devx_tir' ],
 112                 [ 'HAVE_IBV_DEVX_EVENT', 'infiniband/mlx5dv.h',
 113                 'mlx5dv_devx_get_event' ],
 114                 [ 'HAVE_MLX5_DR_CREATE_ACTION_FLOW_METER', 'infiniband/mlx5dv.h',
 115                 'mlx5dv_dr_action_create_flow_meter' ],
 116                 [ 'HAVE_MLX5DV_MMAP_GET_NC_PAGES_CMD', 'infiniband/mlx5dv.h',
 117                 'MLX5_MMAP_GET_NC_PAGES_CMD' ],
 118                 [ 'HAVE_MLX5DV_DR', 'infiniband/mlx5dv.h',
 119                 'MLX5DV_DR_DOMAIN_TYPE_NIC_RX' ],
 120                 [ 'HAVE_MLX5DV_DR_ESWITCH', 'infiniband/mlx5dv.h',
 121                 'MLX5DV_DR_DOMAIN_TYPE_FDB' ],
 122                 [ 'HAVE_MLX5DV_DR_VLAN', 'infiniband/mlx5dv.h',
 123                 'mlx5dv_dr_action_create_push_vlan' ],
 124                 [ 'HAVE_IBV_VAR', 'infiniband/mlx5dv.h', 'mlx5dv_alloc_var' ],
 125                 [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 126                 'SUPPORTED_40000baseKR4_Full' ],
 127                 [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 128                 'SUPPORTED_40000baseCR4_Full' ],
 129                 [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 130                 'SUPPORTED_40000baseSR4_Full' ],
 131                 [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 132                 'SUPPORTED_40000baseLR4_Full' ],
 133                 [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 134                 'SUPPORTED_56000baseKR4_Full' ],
 135                 [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 136                 'SUPPORTED_56000baseCR4_Full' ],
 137                 [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 138                 'SUPPORTED_56000baseSR4_Full' ],
 139                 [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 140                 'SUPPORTED_56000baseLR4_Full' ],
 141                 [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 142                 'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 143                 [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 144                 'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 145                 [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 146                 'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 147                 [ 'HAVE_IFLA_NUM_VF', 'linux/if_link.h',
 148                 'IFLA_NUM_VF' ],
 149                 [ 'HAVE_IFLA_EXT_MASK', 'linux/if_link.h',
 150                 'IFLA_EXT_MASK' ],
 151                 [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 152                 'IFLA_PHYS_SWITCH_ID' ],
 153                 [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 154                 'IFLA_PHYS_PORT_NAME' ],
 155                 [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 156                 'RDMA_NL_NLDEV' ],
 157                 [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 158                 'RDMA_NLDEV_CMD_GET' ],
 159                 [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 160                 'RDMA_NLDEV_CMD_PORT_GET' ],
 161                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 162                 'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 163                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 164                 'RDMA_NLDEV_ATTR_DEV_NAME' ],
 165                 [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 166                 'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 167                 [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 168                 'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 169                 [ 'HAVE_MLX5_DR_FLOW_DUMP', 'infiniband/mlx5dv.h',
 170                 'mlx5dv_dump_dr_domain'],
 171                 [ 'HAVE_DEVLINK', 'linux/devlink.h', 'DEVLINK_GENL_NAME' ],
 172         ]
 173         config = configuration_data()
 174         foreach arg:has_sym_args
 175                 config.set(arg[0], cc.has_header_symbol(arg[1], arg[2],
 176                         dependencies: libs))
 177         endforeach
 178         foreach arg:has_member_args
 179                 file_prefix = '#include <' + arg[1] + '>'
 180                 config.set(arg[0], cc.has_member(arg[2], arg[3],
 181                         prefix : file_prefix, dependencies: libs))
 182         endforeach
 183         configure_file(output : 'mlx5_autoconf.h', configuration : config)
 184 endif
 185 # Build Glue Library
 186 if pmd_dlopen and build
 187         dlopen_name = 'mlx5_glue'
 188         dlopen_lib_name = driver_name_fmt.format(dlopen_name)
 189         dlopen_so_version = LIB_GLUE_VERSION
 190         dlopen_sources = files('mlx5_glue.c')
 191         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 192         dlopen_includes = [global_inc]
 193         dlopen_includes += include_directories(
 194                 '../../../lib/librte_eal/common/include/generic',
 195         )
 196         shared_lib = shared_library(
 197                 dlopen_lib_name,
 198                 dlopen_sources,
 199                 include_directories: dlopen_includes,
 200                 c_args: cflags,
 201                 dependencies: libs,
 202                 link_args: [
 203                 '-Wl,-export-dynamic',
 204                 '-Wl,-h,@0@'.format(LIB_GLUE),
 205                 ],
 206                 soversion: dlopen_so_version,
 207                 install: true,
 208                 install_dir: dlopen_install_dir,
 209         )
 210 endif