drivers/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # Defines the order of dependencies evaluation
   5 subdirs = [
   6         'common',
   7         'bus',
   8         'common/cnxk',    # depends on bus.
   9         'common/mlx5',    # depends on bus.
  10         'common/qat',     # depends on bus.
  11         'common/sfc_efx', # depends on bus.
  12         'mempool',        # depends on common and bus.
  13         'net',            # depends on common, bus, mempool
  14         'raw',            # depends on common, bus and net.
  15         'crypto',         # depends on common, bus and mempool (net in future).
  16         'compress',       # depends on common, bus, mempool.
  17         'regex',          # depends on common, bus, regexdev.
  18         'vdpa',           # depends on common, bus and mempool.
  19         'event',          # depends on common, bus, mempool and net.
  20         'baseband',       # depends on common and bus.
  21 ]
  22
  23 if meson.is_cross_build()
  24     disable_drivers += ',' + meson.get_cross_property('disable_drivers', '')
  25     enable_drivers += ',' + meson.get_cross_property('enable_drivers', '')
  26 endif
  27
  28 # add cmdline disabled drivers and meson disabled drivers together
  29 disable_drivers += ',' + get_option('disable_drivers')
  30 disable_drivers = run_command(list_dir_globs, disable_drivers, check: true).stdout().split()
  31
  32 # add cmdline enabled drivers and meson enabled drivers together
  33 enable_drivers = ',' + get_option('enable_drivers')
  34 enable_drivers = run_command(list_dir_globs, enable_drivers, check: true).stdout().split()
  35 if enable_drivers.length() == 0
  36     enable_drivers = run_command(list_dir_globs, '*/*', check: true).stdout().split()
  37 endif
  38
  39 # these drivers must always be enabled, otherwise the build breaks
  40 always_enable = ['bus/pci', 'bus/vdev']
  41 enable_drivers += always_enable
  42
  43 default_cflags = machine_args
  44 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
  45 default_cflags += ['-DALLOW_INTERNAL_API']
  46
  47 if cc.has_argument('-Wno-format-truncation')
  48     default_cflags += '-Wno-format-truncation'
  49 endif
  50
  51 foreach subpath:subdirs
  52     drivers = []
  53     std_deps = []
  54     log_prefix = ''
  55
  56     # subpath can be either "class" or "class/driver"
  57     if subpath.contains('/')
  58         driver_path = subpath.split('/')
  59         class = driver_path[0]
  60         drivers += driver_path[1]
  61     else
  62         class = subpath
  63         subdir(class)
  64     endif
  65
  66     # save class name on first occurrence
  67     if not dpdk_driver_classes.contains(class)
  68         dpdk_driver_classes += class
  69     endif
  70     # get already enabled drivers of the same class
  71     enabled_drivers = get_variable(class + '_drivers', [])
  72
  73     # default log prefix can be defined per class
  74     if log_prefix == ''
  75         # default log name is pmd.class.driver
  76         log_prefix = 'pmd.' + class
  77     endif
  78
  79     foreach drv:drivers
  80         drv_path = join_paths(class, drv)
  81
  82         # set up empty variables used for build
  83         build = true # set to false to disable, e.g. missing deps
  84         reason = '<unknown reason>' # set if build == false to explain
  85         name = drv
  86         sources = []
  87         headers = []
  88         objs = []
  89         cflags = default_cflags
  90         includes = [include_directories(drv_path)]
  91         # set up internal deps. Drivers can append/override as necessary
  92         deps = std_deps
  93         # ext_deps: Stores external library dependency got
  94         # using dependency() (preferred) or find_library().
  95         # For the find_library() case (but not with dependency()) we also
  96         # need to specify the "-l" flags in pkgconfig_extra_libs variable
  97         # too, so that it can be reflected in the pkgconfig output for
  98         # static builds.
  99         ext_deps = []
 100         pkgconfig_extra_libs = []
 101
 102         if not enable_drivers.contains(drv_path)
 103             build = false
 104             reason = 'not in enabled drivers build config'
 105         elif disable_drivers.contains(drv_path)
 106             if always_enable.contains(drv_path)
 107                 message('Driver @0@ cannot be disabled, not disabling.'.format(drv_path))
 108             else
 109                 build = false
 110                 reason = 'explicitly disabled via build config'
 111             endif
 112         endif
 113
 114         if build
 115             # pull in driver directory which should update all the local variables
 116             subdir(drv_path)
 117
 118             # get dependency objs from strings
 119             shared_deps = ext_deps
 120             static_deps = ext_deps
 121             foreach d:deps
 122                 if not build
 123                     break
 124                 endif
 125                 if not is_variable('shared_rte_' + d)
 126                     build = false
 127                     reason = 'missing internal dependency, "@0@"'.format(d)
 128                     message('Disabling @1@ [@2@]: missing internal dependency "@0@"'
 129                             .format(d, name, 'drivers/' + drv_path))
 130                 else
 131                     shared_deps += [get_variable('shared_rte_' + d)]
 132                     static_deps += [get_variable('static_rte_' + d)]
 133                 endif
 134             endforeach
 135         endif
 136
 137         if not build
 138             # some driver directories are placeholders which
 139             # are never built, so we allow suppression of the
 140             # component disable printout in those cases
 141             if reason != ''
 142                 dpdk_drvs_disabled += drv_path
 143                 set_variable(drv_path.underscorify() + '_disable_reason', reason)
 144             endif
 145             continue
 146         endif
 147
 148         enabled_drivers += name
 149         lib_name = '_'.join(['rte', class, name])
 150         cflags += '-DRTE_LOG_DEFAULT_LOGTYPE=' + '.'.join([log_prefix, name])
 151         dpdk_conf.set(lib_name.to_upper(), 1)
 152
 153         dpdk_extra_ldflags += pkgconfig_extra_libs
 154
 155         install_headers(headers)
 156
 157         # generate pmdinfo sources by building a temporary
 158         # lib and then running pmdinfogen on the contents of
 159         # that lib. The final lib reuses the object files and
 160         # adds in the new source file.
 161         out_filename = lib_name + '.pmd.c'
 162         tmp_lib = static_library('tmp_' + lib_name, sources,
 163                 include_directories: includes,
 164                 dependencies: static_deps,
 165                 c_args: cflags)
 166         objs += tmp_lib.extract_all_objects(recursive: true)
 167         sources = custom_target(out_filename,
 168                 command: [pmdinfo, tmp_lib.full_path(), '@OUTPUT@', pmdinfogen],
 169                 output: out_filename,
 170                 depends: [tmp_lib])
 171
 172         # now build the static driver
 173         static_lib = static_library(lib_name,
 174                 sources,
 175                 objects: objs,
 176                 include_directories: includes,
 177                 dependencies: static_deps,
 178                 c_args: cflags,
 179                 install: true)
 180
 181         # now build the shared driver
 182         version_map = '@0@/@1@/version.map'.format(meson.current_source_dir(), drv_path)
 183         implib = 'lib' + lib_name + '.dll.a'
 184
 185         def_file = custom_target(lib_name + '_def',
 186                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 187                 input: version_map,
 188                 output: '@0@_exports.def'.format(lib_name))
 189
 190         mingw_map = custom_target(lib_name + '_mingw',
 191                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 192                 input: version_map,
 193                 output: '@0@_mingw.map'.format(lib_name))
 194
 195         lk_deps = [version_map, def_file, mingw_map]
 196         if is_windows
 197             if is_ms_linker
 198                 lk_args = ['-Wl,/def:' + def_file.full_path()]
 199                 if meson.version().version_compare('<0.54.0')
 200                     lk_args += ['-Wl,/implib:drivers\\' + implib]
 201                 endif
 202             else
 203                 lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 204             endif
 205         else
 206             lk_args = ['-Wl,--version-script=' + version_map]
 207             if developer_mode
 208                 # on unix systems check the output of the
 209                 # check-symbols.sh script, using it as a
 210                 # dependency of the .so build
 211                 lk_deps += custom_target(lib_name + '.sym_chk',
 212                         command: [check_symbols, version_map, '@INPUT@'],
 213                         capture: true,
 214                         input: static_lib,
 215                         output: lib_name + '.sym_chk')
 216             endif
 217         endif
 218
 219         shared_lib = shared_library(lib_name, sources,
 220                 objects: objs,
 221                 include_directories: includes,
 222                 dependencies: shared_deps,
 223                 c_args: cflags,
 224                 link_args: lk_args,
 225                 link_depends: lk_deps,
 226                 version: abi_version,
 227                 soversion: so_version,
 228                 install: true,
 229                 install_dir: driver_install_path)
 230
 231         # create a dependency object and add it to the global dictionary so
 232         # testpmd or other built-in apps can find it if necessary
 233         shared_dep = declare_dependency(link_with: shared_lib,
 234                 include_directories: includes,
 235                 dependencies: shared_deps)
 236         static_dep = declare_dependency(
 237                 include_directories: includes,
 238                 dependencies: static_deps)
 239
 240         dpdk_drivers += static_lib
 241
 242         set_variable('shared_@0@'.format(lib_name), shared_dep)
 243         set_variable('static_@0@'.format(lib_name), static_dep)
 244         dependency_name = ''.join(lib_name.split('rte_'))
 245         if developer_mode
 246             message('drivers/@0@: Defining dependency "@1@"'.format(
 247                     drv_path, dependency_name))
 248         endif
 249     endforeach
 250
 251     set_variable(class + '_drivers', enabled_drivers)
 252 endforeach