drivers/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 if is_windows
   5         subdir_done()
   6 endif
   7
   8 # Defines the order in which the drivers are buit.
   9 dpdk_driver_classes = ['common',
  10                'bus',
  11                'mempool', # depends on common and bus.
  12                'net',     # depends on common, bus, mempool
  13                'raw',     # depends on common, bus and net.
  14                'crypto',  # depends on common, bus and mempool (net in future).
  15                'compress', # depends on common, bus, mempool.
  16                'vdpa',    # depends on common, bus and mempool.
  17                'event',   # depends on common, bus, mempool and net.
  18                'baseband'] # depends on common and bus.
  19
  20 disabled_drivers = run_command(list_dir_globs, get_option('disable_drivers'),
  21                 ).stdout().split()
  22
  23 default_cflags = machine_args
  24 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
  25 default_cflags += ['-DALLOW_INTERNAL_API']
  26
  27 if cc.has_argument('-Wno-format-truncation')
  28         default_cflags += '-Wno-format-truncation'
  29 endif
  30
  31 foreach class:dpdk_driver_classes
  32         drivers = []
  33         std_deps = []
  34         config_flag_fmt = '' # format string used to set the value in dpdk_conf
  35         driver_name_fmt = '' # format string for driver name, used to name
  36                              # the library, the dependency and to find the
  37                              # version file for linking
  38
  39         subdir(class)
  40         class_drivers = []
  41
  42         foreach drv:drivers
  43                 drv_path = join_paths(class, drv)
  44
  45                 # set up empty variables used for build
  46                 build = true # set to false to disable, e.g. missing deps
  47                 reason = '<unknown reason>' # set if build == false to explain
  48                 name = drv
  49                 fmt_name = ''
  50                 sources = []
  51                 objs = []
  52                 cflags = default_cflags
  53                 includes = [include_directories(drv_path)]
  54                 # set up internal deps. Drivers can append/override as necessary
  55                 deps = std_deps
  56                 # ext_deps: Stores external library dependency got
  57                 # using dependency() (preferred) or find_library().
  58                 # For the find_library() case (but not with dependency()) we also
  59                 # need to specify the "-l" flags in pkgconfig_extra_libs variable
  60                 # too, so that it can be reflected in the pkgconfig output for
  61                 # static builds.
  62                 ext_deps = []
  63                 pkgconfig_extra_libs = []
  64
  65                 if disabled_drivers.contains(drv_path)
  66                         build = false
  67                         reason = 'Explicitly disabled via build config'
  68                 else
  69                         # pull in driver directory which should update all the local variables
  70                         subdir(drv_path)
  71                 endif
  72
  73                 if build
  74                         # get dependency objs from strings
  75                         shared_deps = ext_deps
  76                         static_deps = ext_deps
  77                         foreach d:deps
  78                                 if not is_variable('shared_rte_' + d)
  79                                         build = false
  80                                         reason = 'Missing internal dependency, "@0@"'.format(d)
  81                                         message('Disabling @1@ [@2@]: missing internal dependency "@0@"'
  82                                                         .format(d, name, 'drivers/' + drv_path))
  83                                 else
  84                                         shared_deps += [get_variable('shared_rte_' + d)]
  85                                         static_deps += [get_variable('static_rte_' + d)]
  86                                 endif
  87                         endforeach
  88                 endif
  89
  90                 if not build
  91                         # some driver directories are placeholders which
  92                         # are never built, so we allow suppression of the
  93                         # component disable printout in those cases
  94                         if reason != ''
  95                                 dpdk_drvs_disabled += drv_path
  96                                 set_variable(drv_path.underscorify() +
  97                                                 '_disable_reason', reason)
  98                         endif
  99                 else
 100                         class_drivers += name
 101
 102                         if fmt_name == ''
 103                                 fmt_name = name
 104                         endif
 105                         dpdk_conf.set(config_flag_fmt.format(fmt_name.to_upper()),1)
 106                         lib_name = driver_name_fmt.format(fmt_name)
 107
 108                         dpdk_extra_ldflags += pkgconfig_extra_libs
 109
 110                         # generate pmdinfo sources by building a temporary
 111                         # lib and then running pmdinfogen on the contents of
 112                         # that lib. The final lib reuses the object files and
 113                         # adds in the new source file.
 114                         if not is_windows
 115                                 out_filename = lib_name + '.pmd.c'
 116                                 tmp_lib = static_library('tmp_' + lib_name,
 117                                                 sources,
 118                                                 include_directories: includes,
 119                                                 dependencies: static_deps,
 120                                                 c_args: cflags)
 121                                 objs += tmp_lib.extract_all_objects()
 122                                 sources = custom_target(out_filename,
 123                                                 command: [pmdinfo, tmp_lib.full_path(),
 124                                                         '@OUTPUT@', pmdinfogen],
 125                                                 output: out_filename,
 126                                                 depends: [pmdinfogen, tmp_lib])
 127                         endif
 128                         version_map = '@0@/@1@/@2@_version.map'.format(
 129                                         meson.current_source_dir(),
 130                                         drv_path, lib_name)
 131
 132                         is_stable = run_command(is_stable_cmd,
 133                                 files(version_map)).returncode() == 0
 134
 135                         if is_stable
 136                                 lib_version = abi_version
 137                                 so_version = stable_so_version
 138                         else
 139                                 lib_version = experimental_abi_version
 140                                 so_version = experimental_so_version
 141                         endif
 142
 143                         # now build the static driver
 144                         static_lib = static_library(lib_name,
 145                                 sources,
 146                                 objects: objs,
 147                                 include_directories: includes,
 148                                 dependencies: static_deps,
 149                                 c_args: cflags,
 150                                 install: true)
 151
 152                         # now build the shared driver
 153                         version_map = '@0@/@1@/@2@_version.map'.format(
 154                                         meson.current_source_dir(),
 155                                         drv_path, lib_name)
 156                         implib = 'lib' + lib_name + '.dll.a'
 157
 158                         def_file = custom_target(lib_name + '_def',
 159                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 160                                 input: version_map,
 161                                 output: '@0@_exports.def'.format(lib_name))
 162
 163                         mingw_map = custom_target(lib_name + '_mingw',
 164                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 165                                 input: version_map,
 166                                 output: '@0@_mingw.map'.format(lib_name))
 167
 168                         lk_deps = [version_map, def_file, mingw_map]
 169                         if is_windows
 170                                 if is_ms_linker
 171                                         lk_args = ['-Wl,/def:' + def_file.full_path(),
 172                                                 '-Wl,/implib:drivers\\' + implib]
 173                                 else
 174                                         lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 175                                 endif
 176                         else
 177                                 lk_args = ['-Wl,--version-script=' + version_map]
 178                                 # on unix systems check the output of the
 179                                 # check-symbols.sh script, using it as a
 180                                 # dependency of the .so build
 181                                 lk_deps += custom_target(lib_name + '.sym_chk',
 182                                         command: [check_symbols,
 183                                                 version_map, '@INPUT@'],
 184                                         capture: true,
 185                                         input: static_lib,
 186                                         output: lib_name + '.sym_chk')
 187                         endif
 188
 189                         shared_lib = shared_library(lib_name,
 190                                 sources,
 191                                 objects: objs,
 192                                 include_directories: includes,
 193                                 dependencies: shared_deps,
 194                                 c_args: cflags,
 195                                 link_args: lk_args,
 196                                 link_depends: lk_deps,
 197                                 version: lib_version,
 198                                 soversion: so_version,
 199                                 install: true,
 200                                 install_dir: driver_install_path)
 201
 202                         # create a dependency object and add it to the global dictionary so
 203                         # testpmd or other built-in apps can find it if necessary
 204                         shared_dep = declare_dependency(link_with: shared_lib,
 205                                         include_directories: includes,
 206                                         dependencies: shared_deps)
 207                         static_dep = declare_dependency(link_with: static_lib,
 208                                         include_directories: includes,
 209                                         dependencies: static_deps)
 210
 211                         dpdk_drivers += static_lib
 212
 213                         set_variable('shared_@0@'.format(lib_name), shared_dep)
 214                         set_variable('static_@0@'.format(lib_name), static_dep)
 215                         dependency_name = ''.join(lib_name.split('rte_'))
 216                         message('drivers/@0@: Defining dependency "@1@"'.format(
 217                                         drv_path, dependency_name))
 218                 endif # build
 219         endforeach
 220
 221         set_variable(class + '_drivers', class_drivers)
 222 endforeach