drivers/net/ice/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2018 Intel Corporation
   3
   4 subdir('base')
   5 objs = [base_objs]
   6
   7 sources = files(
   8         'ice_ethdev.c',
   9         'ice_rxtx.c',
  10         'ice_switch_filter.c',
  11         'ice_generic_flow.c',
  12         'ice_fdir_filter.c',
  13         'ice_hash.c'
  14         )
  15
  16 deps += ['hash']
  17 includes += include_directories('base')
  18
  19 if arch_subdir == 'x86'
  20         sources += files('ice_rxtx_vec_sse.c')
  21
  22         # compile AVX2 version if either:
  23         # a. we have AVX supported in minimum instruction set baseline
  24         # b. it's not minimum instruction set, but supported by compiler
  25         if dpdk_conf.has('RTE_MACHINE_CPUFLAG_AVX2')
  26                 sources += files('ice_rxtx_vec_avx2.c')
  27         elif cc.has_argument('-mavx2')
  28                 ice_avx2_lib = static_library('ice_avx2_lib',
  29                                 'ice_rxtx_vec_avx2.c',
  30                                 dependencies: [static_rte_ethdev,
  31                                         static_rte_kvargs, static_rte_hash],
  32                                 include_directories: includes,
  33                                 c_args: [cflags, '-mavx2'])
  34                 objs += ice_avx2_lib.extract_objects('ice_rxtx_vec_avx2.c')
  35         endif
  36 endif
  37
  38 install_headers('rte_pmd_ice.h')