drivers/net/ice/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2018 Intel Corporation
   3
   4 subdir('base')
   5 objs = [base_objs]
   6
   7 sources = files(
   8         'ice_ethdev.c',
   9         'ice_rxtx.c',
  10         'ice_switch_filter.c',
  11         'ice_generic_flow.c',
  12         'ice_fdir_filter.c',
  13         'ice_hash.c',
  14         'ice_acl_filter.c'
  15         )
  16
  17 deps += ['hash', 'net', 'common_iavf']
  18 includes += include_directories('base', '../../common/iavf')
  19
  20 if arch_subdir == 'x86'
  21         sources += files('ice_rxtx_vec_sse.c')
  22
  23         # compile AVX2 version if either:
  24         # a. we have AVX supported in minimum instruction set baseline
  25         # b. it's not minimum instruction set, but supported by compiler
  26         if cc.get_define('__AVX2__', args: machine_args) != ''
  27                 sources += files('ice_rxtx_vec_avx2.c')
  28         elif cc.has_argument('-mavx2')
  29                 ice_avx2_lib = static_library('ice_avx2_lib',
  30                                 'ice_rxtx_vec_avx2.c',
  31                                 dependencies: [static_rte_ethdev,
  32                                         static_rte_kvargs, static_rte_hash],
  33                                 include_directories: includes,
  34                                 c_args: [cflags, '-mavx2'])
  35                 objs += ice_avx2_lib.extract_objects('ice_rxtx_vec_avx2.c')
  36         endif
  37
  38         ice_avx512_cpu_support = (
  39                 cc.get_define('__AVX512F__', args: machine_args) != '' and
  40                 cc.get_define('__AVX512BW__', args: machine_args) != '')
  41
  42         ice_avx512_cc_support = (
  43                 not machine_args.contains('-mno-avx512f') and
  44                 cc.has_argument('-mavx512f') and
  45                 cc.has_argument('-mavx512bw'))
  46
  47         if ice_avx512_cpu_support == true or ice_avx512_cc_support == true
  48                 cflags += ['-DCC_AVX512_SUPPORT']
  49                 avx512_args = [cflags, '-mavx512f', '-mavx512bw']
  50                 if cc.has_argument('-march=skylake-avx512')
  51                         avx512_args += '-march=skylake-avx512'
  52                 endif
  53                 ice_avx512_lib = static_library('ice_avx512_lib',
  54                                 'ice_rxtx_vec_avx512.c',
  55                                 dependencies: [static_rte_ethdev,
  56                                         static_rte_kvargs, static_rte_hash],
  57                                 include_directories: includes,
  58                                 c_args: avx512_args)
  59                 objs += ice_avx512_lib.extract_objects('ice_rxtx_vec_avx512.c')
  60         endif
  61 endif
  62
  63 sources += files('ice_dcf.c',
  64                  'ice_dcf_vf_representor.c',
  65                  'ice_dcf_ethdev.c',
  66                  'ice_dcf_parent.c')
  67
  68 headers = files('rte_pmd_ice.h')