drivers/net/mlx5/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2018 6WIND S.A.
   3 # Copyright 2018 Mellanox Technologies, Ltd
   4
   5 if not is_linux
   6         build = false
   7         reason = 'only supported on Linux'
   8         subdir_done()
   9 endif
  10 build = true
  11
  12 pmd_dlopen = (get_option('ibverbs_link') == 'dlopen')
  13 LIB_GLUE_BASE = 'librte_pmd_mlx5_glue.so'
  14 LIB_GLUE_VERSION = '19.08.0'
  15 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
  16 if pmd_dlopen
  17         dpdk_conf.set('RTE_IBVERBS_LINK_DLOPEN', 1)
  18         cflags += [
  19                 '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  20                 '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  21         ]
  22 endif
  23
  24 libnames = [ 'mlx5', 'ibverbs' ]
  25 libs = []
  26 foreach libname:libnames
  27         lib = dependency('lib' + libname, required:false)
  28         if not lib.found()
  29                 lib = cc.find_library(libname, required:false)
  30         endif
  31         if lib.found()
  32                 libs += [ lib ]
  33         else
  34                 build = false
  35                 reason = 'missing dependency, "' + libname + '"'
  36         endif
  37 endforeach
  38
  39 if build
  40         allow_experimental_apis = true
  41         ext_deps += libs
  42         sources = files(
  43                 'mlx5.c',
  44                 'mlx5_ethdev.c',
  45                 'mlx5_flow.c',
  46                 'mlx5_flow_dv.c',
  47                 'mlx5_flow_verbs.c',
  48                 'mlx5_mac.c',
  49                 'mlx5_mr.c',
  50                 'mlx5_nl.c',
  51                 'mlx5_rss.c',
  52                 'mlx5_rxmode.c',
  53                 'mlx5_rxq.c',
  54                 'mlx5_rxtx.c',
  55                 'mlx5_mp.c',
  56                 'mlx5_stats.c',
  57                 'mlx5_trigger.c',
  58                 'mlx5_txq.c',
  59                 'mlx5_vlan.c',
  60                 'mlx5_devx_cmds.c',
  61         )
  62         if (dpdk_conf.has('RTE_ARCH_X86_64')
  63                 or dpdk_conf.has('RTE_ARCH_ARM64')
  64                 or dpdk_conf.has('RTE_ARCH_PPC_64'))
  65                 sources += files('mlx5_rxtx_vec.c')
  66         endif
  67         if not pmd_dlopen
  68                 sources += files('mlx5_glue.c')
  69         endif
  70         cflags_options = [
  71                 '-std=c11',
  72                 '-Wno-strict-prototypes',
  73                 '-D_BSD_SOURCE',
  74                 '-D_DEFAULT_SOURCE',
  75                 '-D_XOPEN_SOURCE=600'
  76         ]
  77         foreach option:cflags_options
  78                 if cc.has_argument(option)
  79                         cflags += option
  80                 endif
  81         endforeach
  82         if get_option('buildtype').contains('debug')
  83                 cflags += [ '-pedantic', '-UNDEBUG', '-DPEDANTIC' ]
  84         else
  85                 cflags += [ '-DNDEBUG', '-UPEDANTIC' ]
  86         endif
  87         # To maintain the compatibility with the make build system
  88         # mlx5_autoconf.h file is still generated.
  89         # input array for meson member search:
  90         # [ "MACRO to define if found", "header for the search",
  91         #   "symbol to search", "struct member to search" ]
  92         has_member_args = [
  93                 [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  94                 'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  95                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V42', 'infiniband/verbs.h',
  96                 'struct ibv_counter_set_init_attr', 'counter_set_id' ],
  97                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V45', 'infiniband/verbs.h',
  98                 'struct ibv_counters_init_attr', 'comp_mask' ],
  99         ]
 100         # input array for meson symbol search:
 101         # [ "MACRO to define if found", "header for the search",
 102         #   "symbol to search" ]
 103         has_sym_args = [
 104                 [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
 105                 'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
 106                 [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
 107                 'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
 108                 [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
 109                 'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
 110                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
 111                 'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
 112                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_PAD', 'infiniband/mlx5dv.h',
 113                 'MLX5DV_CQ_INIT_ATTR_FLAGS_CQE_PAD' ],
 114                 [ 'HAVE_IBV_FLOW_DV_SUPPORT', 'infiniband/mlx5dv.h',
 115                 'mlx5dv_create_flow_action_packet_reformat' ],
 116                 [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
 117                 'IBV_FLOW_SPEC_MPLS' ],
 118                 [ 'HAVE_IBV_WQ_FLAGS_PCI_WRITE_END_PADDING', 'infiniband/verbs.h',
 119                 'IBV_WQ_FLAGS_PCI_WRITE_END_PADDING' ],
 120                 [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
 121                 'IBV_WQ_FLAG_RX_END_PADDING' ],
 122                 [ 'HAVE_MLX5DV_DR_DEVX_PORT', 'infiniband/mlx5dv.h',
 123                 'mlx5dv_query_devx_port' ],
 124                 [ 'HAVE_IBV_DEVX_OBJ', 'infiniband/mlx5dv.h',
 125                 'mlx5dv_devx_obj_create' ],
 126                 [ 'HAVE_IBV_FLOW_DEVX_COUNTERS', 'infiniband/mlx5dv.h',
 127                 'MLX5DV_FLOW_ACTION_COUNTERS_DEVX' ],
 128                 [ 'HAVE_IBV_DEVX_ASYNC', 'infiniband/mlx5dv.h',
 129                 'mlx5dv_devx_obj_query_async' ],
 130                 [ 'HAVE_MLX5DV_DR_ACTION_DEST_DEVX_TIR', 'infiniband/mlx5dv.h',
 131                 'mlx5dv_dr_action_create_dest_devx_tir' ],
 132                 [ 'HAVE_MLX5DV_DR', 'infiniband/mlx5dv.h',
 133                 'MLX5DV_DR_DOMAIN_TYPE_NIC_RX' ],
 134                 [ 'HAVE_MLX5DV_DR_ESWITCH', 'infiniband/mlx5dv.h',
 135                 'MLX5DV_DR_DOMAIN_TYPE_FDB' ],
 136                 [ 'HAVE_MLX5DV_DR_VLAN', 'infiniband/mlx5dv.h',
 137                 'mlx5dv_dr_action_create_push_vlan' ],
 138                 [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 139                 'SUPPORTED_40000baseKR4_Full' ],
 140                 [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 141                 'SUPPORTED_40000baseCR4_Full' ],
 142                 [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 143                 'SUPPORTED_40000baseSR4_Full' ],
 144                 [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 145                 'SUPPORTED_40000baseLR4_Full' ],
 146                 [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 147                 'SUPPORTED_56000baseKR4_Full' ],
 148                 [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 149                 'SUPPORTED_56000baseCR4_Full' ],
 150                 [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 151                 'SUPPORTED_56000baseSR4_Full' ],
 152                 [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 153                 'SUPPORTED_56000baseLR4_Full' ],
 154                 [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 155                 'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 156                 [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 157                 'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 158                 [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 159                 'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 160                 [ 'HAVE_IFLA_NUM_VF', 'linux/if_link.h',
 161                 'IFLA_NUM_VF' ],
 162                 [ 'HAVE_IFLA_EXT_MASK', 'linux/if_link.h',
 163                 'IFLA_EXT_MASK' ],
 164                 [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 165                 'IFLA_PHYS_SWITCH_ID' ],
 166                 [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 167                 'IFLA_PHYS_PORT_NAME' ],
 168                 [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 169                 'RDMA_NL_NLDEV' ],
 170                 [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 171                 'RDMA_NLDEV_CMD_GET' ],
 172                 [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 173                 'RDMA_NLDEV_CMD_PORT_GET' ],
 174                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 175                 'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 176                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 177                 'RDMA_NLDEV_ATTR_DEV_NAME' ],
 178                 [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 179                 'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 180                 [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 181                 'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 182         ]
 183         config = configuration_data()
 184         foreach arg:has_sym_args
 185                 config.set(arg[0], cc.has_header_symbol(arg[1], arg[2],
 186                         dependencies: libs))
 187         endforeach
 188         foreach arg:has_member_args
 189                 file_prefix = '#include <' + arg[1] + '>'
 190                 config.set(arg[0], cc.has_member(arg[2], arg[3],
 191                         prefix : file_prefix, dependencies: libs))
 192         endforeach
 193         configure_file(output : 'mlx5_autoconf.h', configuration : config)
 194 endif
 195 # Build Glue Library
 196 if pmd_dlopen and build
 197         dlopen_name = 'mlx5_glue'
 198         dlopen_lib_name = driver_name_fmt.format(dlopen_name)
 199         dlopen_so_version = LIB_GLUE_VERSION
 200         dlopen_sources = files('mlx5_glue.c')
 201         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 202         shared_lib = shared_library(
 203                 dlopen_lib_name,
 204                 dlopen_sources,
 205                 include_directories: global_inc,
 206                 c_args: cflags,
 207                 dependencies: libs,
 208                 link_args: [
 209                 '-Wl,-export-dynamic',
 210                 '-Wl,-h,@0@'.format(LIB_GLUE),
 211                 ],
 212                 soversion: dlopen_so_version,
 213                 install: true,
 214                 install_dir: dlopen_install_dir,
 215         )
 216 endif