drivers/net/mlx5/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2018 6WIND S.A.
   3 # Copyright 2018 Mellanox Technologies, Ltd
   4
   5 pmd_dlopen = get_option('enable_driver_mlx_glue')
   6 LIB_GLUE_BASE = 'librte_pmd_mlx5_glue.so'
   7 LIB_GLUE_VERSION = '18.05.0'
   8 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
   9 if pmd_dlopen
  10         dpdk_conf.set('RTE_LIBRTE_MLX5_DLOPEN_DEPS', 1)
  11         cflags += [
  12                 '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  13                 '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  14         ]
  15 endif
  16 libs = [
  17         cc.find_library('mnl', required:false),
  18         cc.find_library('mlx5', required:false),
  19         cc.find_library('ibverbs', required:false),
  20 ]
  21 build = true
  22 foreach lib:libs
  23         if not lib.found()
  24                 build = false
  25         endif
  26 endforeach
  27 if build
  28         allow_experimental_apis = true
  29         ext_deps += libs
  30         sources = files(
  31                 'mlx5.c',
  32                 'mlx5_ethdev.c',
  33                 'mlx5_flow.c',
  34                 'mlx5_mac.c',
  35                 'mlx5_mr.c',
  36                 'mlx5_nl.c',
  37                 'mlx5_nl_flow.c',
  38                 'mlx5_rss.c',
  39                 'mlx5_rxmode.c',
  40                 'mlx5_rxq.c',
  41                 'mlx5_rxtx.c',
  42                 'mlx5_socket.c',
  43                 'mlx5_stats.c',
  44                 'mlx5_trigger.c',
  45                 'mlx5_txq.c',
  46                 'mlx5_vlan.c',
  47         )
  48         if dpdk_conf.has('RTE_ARCH_X86_64') or dpdk_conf.has('RTE_ARCH_ARM64')
  49                 sources += files('mlx5_rxtx_vec.c')
  50         endif
  51         if not pmd_dlopen
  52                 sources += files('mlx5_glue.c')
  53         endif
  54         cflags_options = [
  55                 '-Wextra',
  56                 '-std=c11',
  57                 '-Wno-strict-prototypes',
  58                 '-D_BSD_SOURCE',
  59                 '-D_DEFAULT_SOURCE',
  60                 '-D_XOPEN_SOURCE=600'
  61         ]
  62         foreach option:cflags_options
  63                 if cc.has_argument(option)
  64                         cflags += option
  65                 endif
  66         endforeach
  67         if get_option('buildtype').contains('debug')
  68                 cflags += [ '-pedantic', '-UNDEBUG', '-DPEDANTIC' ]
  69         else
  70                 cflags += [ '-DNDEBUG', '-UPEDANTIC' ]
  71         endif
  72         # To maintain the compatibility with the make build system
  73         # mlx5_autoconf.h file is still generated.
  74         # input array for meson member search:
  75         # [ "MACRO to define if found", "header for the search",
  76         #   "symbol to search", "struct member to search" ]
  77         has_member_args = [
  78                 [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  79                 'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  80                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_SUPPORT', 'infiniband/verbs.h',
  81                 'struct ibv_counter_set_init_attr', 'counter_set_id' ],
  82         ]
  83         # input array for meson symbol search:
  84         # [ "MACRO to define if found", "header for the search",
  85         #   "symbol to search" ]
  86         has_sym_args = [
  87                 [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
  88                 'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
  89                 [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
  90                 'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
  91                 [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
  92                 'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
  93                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
  94                 'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
  95                 [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
  96                 'IBV_FLOW_SPEC_MPLS' ],
  97                 [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
  98                 'IBV_WQ_FLAG_RX_END_PADDING' ],
  99                 [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 100                 'SUPPORTED_40000baseKR4_Full' ],
 101                 [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 102                 'SUPPORTED_40000baseCR4_Full' ],
 103                 [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 104                 'SUPPORTED_40000baseSR4_Full' ],
 105                 [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 106                 'SUPPORTED_40000baseLR4_Full' ],
 107                 [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 108                 'SUPPORTED_56000baseKR4_Full' ],
 109                 [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 110                 'SUPPORTED_56000baseCR4_Full' ],
 111                 [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 112                 'SUPPORTED_56000baseSR4_Full' ],
 113                 [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 114                 'SUPPORTED_56000baseLR4_Full' ],
 115                 [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 116                 'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 117                 [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 118                 'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 119                 [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 120                 'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 121                 [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 122                 'IFLA_PHYS_SWITCH_ID' ],
 123                 [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 124                 'IFLA_PHYS_PORT_NAME' ],
 125                 [ 'HAVE_TCA_FLOWER_ACT', 'linux/pkt_cls.h',
 126                 'TCA_FLOWER_ACT' ],
 127                 [ 'HAVE_TCA_FLOWER_FLAGS', 'linux/pkt_cls.h',
 128                 'TCA_FLOWER_FLAGS' ],
 129                 [ 'HAVE_TCA_FLOWER_KEY_ETH_TYPE', 'linux/pkt_cls.h',
 130                 'TCA_FLOWER_KEY_ETH_TYPE' ],
 131                 [ 'HAVE_TCA_FLOWER_KEY_ETH_DST', 'linux/pkt_cls.h',
 132                 'TCA_FLOWER_KEY_ETH_DST' ],
 133                 [ 'HAVE_TCA_FLOWER_KEY_ETH_DST_MASK', 'linux/pkt_cls.h',
 134                 'TCA_FLOWER_KEY_ETH_DST_MASK' ],
 135                 [ 'HAVE_TCA_FLOWER_KEY_ETH_SRC', 'linux/pkt_cls.h',
 136                 'TCA_FLOWER_KEY_ETH_SRC' ],
 137                 [ 'HAVE_TCA_FLOWER_KEY_ETH_SRC_MASK', 'linux/pkt_cls.h',
 138                 'TCA_FLOWER_KEY_ETH_SRC_MASK' ],
 139                 [ 'HAVE_TCA_FLOWER_KEY_IP_PROTO', 'linux/pkt_cls.h',
 140                 'TCA_FLOWER_KEY_IP_PROTO' ],
 141                 [ 'HAVE_TCA_FLOWER_KEY_IPV4_SRC', 'linux/pkt_cls.h',
 142                 'TCA_FLOWER_KEY_IPV4_SRC' ],
 143                 [ 'HAVE_TCA_FLOWER_KEY_IPV4_SRC_MASK', 'linux/pkt_cls.h',
 144                 'TCA_FLOWER_KEY_IPV4_SRC_MASK' ],
 145                 [ 'HAVE_TCA_FLOWER_KEY_IPV4_DST', 'linux/pkt_cls.h',
 146                 'TCA_FLOWER_KEY_IPV4_DST' ],
 147                 [ 'HAVE_TCA_FLOWER_KEY_IPV4_DST_MASK', 'linux/pkt_cls.h',
 148                 'TCA_FLOWER_KEY_IPV4_DST_MASK' ],
 149                 [ 'HAVE_TCA_FLOWER_KEY_IPV6_SRC', 'linux/pkt_cls.h',
 150                 'TCA_FLOWER_KEY_IPV6_SRC' ],
 151                 [ 'HAVE_TCA_FLOWER_KEY_IPV6_SRC_MASK', 'linux/pkt_cls.h',
 152                 'TCA_FLOWER_KEY_IPV6_SRC_MASK' ],
 153                 [ 'HAVE_TCA_FLOWER_KEY_IPV6_DST', 'linux/pkt_cls.h',
 154                 'TCA_FLOWER_KEY_IPV6_DST' ],
 155                 [ 'HAVE_TCA_FLOWER_KEY_IPV6_DST_MASK', 'linux/pkt_cls.h',
 156                 'TCA_FLOWER_KEY_IPV6_DST_MASK' ],
 157                 [ 'HAVE_TCA_FLOWER_KEY_TCP_SRC', 'linux/pkt_cls.h',
 158                 'TCA_FLOWER_KEY_TCP_SRC' ],
 159                 [ 'HAVE_TCA_FLOWER_KEY_TCP_SRC_MASK', 'linux/pkt_cls.h',
 160                 'TCA_FLOWER_KEY_TCP_SRC_MASK' ],
 161                 [ 'HAVE_TCA_FLOWER_KEY_TCP_DST', 'linux/pkt_cls.h',
 162                 'TCA_FLOWER_KEY_TCP_DST' ],
 163                 [ 'HAVE_TCA_FLOWER_KEY_TCP_DST_MASK', 'linux/pkt_cls.h',
 164                 'TCA_FLOWER_KEY_TCP_DST_MASK' ],
 165                 [ 'HAVE_TCA_FLOWER_KEY_UDP_SRC', 'linux/pkt_cls.h',
 166                 'TCA_FLOWER_KEY_UDP_SRC' ],
 167                 [ 'HAVE_TCA_FLOWER_KEY_UDP_SRC_MASK', 'linux/pkt_cls.h',
 168                 'TCA_FLOWER_KEY_UDP_SRC_MASK' ],
 169                 [ 'HAVE_TCA_FLOWER_KEY_UDP_DST', 'linux/pkt_cls.h',
 170                 'TCA_FLOWER_KEY_UDP_DST' ],
 171                 [ 'HAVE_TCA_FLOWER_KEY_UDP_DST_MASK', 'linux/pkt_cls.h',
 172                 'TCA_FLOWER_KEY_UDP_DST_MASK' ],
 173                 [ 'HAVE_TCA_FLOWER_KEY_VLAN_ID', 'linux/pkt_cls.h',
 174                 'TCA_FLOWER_KEY_VLAN_ID' ],
 175                 [ 'HAVE_TCA_FLOWER_KEY_VLAN_PRIO', 'linux/pkt_cls.h',
 176                 'TCA_FLOWER_KEY_VLAN_PRIO' ],
 177                 [ 'HAVE_TCA_FLOWER_KEY_VLAN_ETH_TYPE', 'linux/pkt_cls.h',
 178                 'TCA_FLOWER_KEY_VLAN_ETH_TYPE' ],
 179                 [ 'HAVE_TC_ACT_VLAN', 'linux/tc_act/tc_vlan.h',
 180                 'TCA_VLAN_PUSH_VLAN_PRIORITY' ],
 181                 [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 182                 'RDMA_NL_NLDEV' ],
 183                 [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 184                 'RDMA_NLDEV_CMD_GET' ],
 185                 [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 186                 'RDMA_NLDEV_CMD_PORT_GET' ],
 187                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 188                 'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 189                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 190                 'RDMA_NLDEV_ATTR_DEV_NAME' ],
 191                 [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 192                 'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 193                 [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 194                 'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 195         ]
 196         config = configuration_data()
 197         foreach arg:has_sym_args
 198                 config.set(arg[0], cc.has_header_symbol(arg[1], arg[2]))
 199         endforeach
 200         foreach arg:has_member_args
 201                 file_prefix = '#include<' + arg[1] + '>'
 202                 config.set(arg[0], cc.has_member(arg[2], arg[3],
 203                         prefix : file_prefix))
 204         endforeach
 205         configure_file(output : 'mlx5_autoconf.h', configuration : config)
 206 endif
 207 # Build Glue Library
 208 if pmd_dlopen and build
 209         dlopen_name = 'mlx5_glue'
 210         dlopen_lib_name = driver_name_fmt.format(dlopen_name)
 211         dlopen_so_version = LIB_GLUE_VERSION
 212         dlopen_sources = files('mlx5_glue.c')
 213         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 214         shared_lib = shared_library(
 215                 dlopen_lib_name,
 216                 dlopen_sources,
 217                 include_directories: global_inc,
 218                 c_args: cflags,
 219                 dependencies: libs,
 220                 link_args: [
 221                 '-Wl,-export-dynamic',
 222                 '-Wl,-h,@0@'.format(LIB_GLUE),
 223                 ],
 224                 soversion: dlopen_so_version,
 225                 install: true,
 226                 install_dir: dlopen_install_dir,
 227         )
 228 endif