drivers/net/mlx5/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2018 6WIND S.A.
   3 # Copyright 2018 Mellanox Technologies, Ltd
   4
   5 if not is_linux
   6         build = false
   7         reason = 'only supported on Linux'
   8         subdir_done()
   9 endif
  10 build = true
  11
  12 pmd_dlopen = (get_option('ibverbs_link') == 'dlopen')
  13 LIB_GLUE_BASE = 'librte_pmd_mlx5_glue.so'
  14 LIB_GLUE_VERSION = '19.08.0'
  15 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
  16 if pmd_dlopen
  17         dpdk_conf.set('RTE_IBVERBS_LINK_DLOPEN', 1)
  18         cflags += [
  19                 '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  20                 '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  21         ]
  22 endif
  23
  24 libnames = [ 'mlx5', 'ibverbs' ]
  25 libs = []
  26 foreach libname:libnames
  27         lib = dependency('lib' + libname, required:false)
  28         if not lib.found()
  29                 lib = cc.find_library(libname, required:false)
  30         endif
  31         if lib.found()
  32                 libs += [ lib ]
  33         else
  34                 build = false
  35                 reason = 'missing dependency, "' + libname + '"'
  36         endif
  37 endforeach
  38
  39 if build
  40         allow_experimental_apis = true
  41         deps += ['hash']
  42         ext_deps += libs
  43         sources = files(
  44                 'mlx5.c',
  45                 'mlx5_ethdev.c',
  46                 'mlx5_flow.c',
  47                 'mlx5_flow_meter.c',
  48                 'mlx5_flow_dv.c',
  49                 'mlx5_flow_verbs.c',
  50                 'mlx5_mac.c',
  51                 'mlx5_mr.c',
  52                 'mlx5_nl.c',
  53                 'mlx5_rss.c',
  54                 'mlx5_rxmode.c',
  55                 'mlx5_rxq.c',
  56                 'mlx5_rxtx.c',
  57                 'mlx5_mp.c',
  58                 'mlx5_stats.c',
  59                 'mlx5_trigger.c',
  60                 'mlx5_txq.c',
  61                 'mlx5_vlan.c',
  62                 'mlx5_devx_cmds.c',
  63                 'mlx5_utils.c',
  64         )
  65         if (dpdk_conf.has('RTE_ARCH_X86_64')
  66                 or dpdk_conf.has('RTE_ARCH_ARM64')
  67                 or dpdk_conf.has('RTE_ARCH_PPC_64'))
  68                 sources += files('mlx5_rxtx_vec.c')
  69         endif
  70         if not pmd_dlopen
  71                 sources += files('mlx5_glue.c')
  72         endif
  73         cflags_options = [
  74                 '-std=c11',
  75                 '-Wno-strict-prototypes',
  76                 '-D_BSD_SOURCE',
  77                 '-D_DEFAULT_SOURCE',
  78                 '-D_XOPEN_SOURCE=600'
  79         ]
  80         foreach option:cflags_options
  81                 if cc.has_argument(option)
  82                         cflags += option
  83                 endif
  84         endforeach
  85         if get_option('buildtype').contains('debug')
  86                 cflags += [ '-pedantic', '-UNDEBUG', '-DPEDANTIC' ]
  87         else
  88                 cflags += [ '-DNDEBUG', '-UPEDANTIC' ]
  89         endif
  90         # To maintain the compatibility with the make build system
  91         # mlx5_autoconf.h file is still generated.
  92         # input array for meson member search:
  93         # [ "MACRO to define if found", "header for the search",
  94         #   "symbol to search", "struct member to search" ]
  95         has_member_args = [
  96                 [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  97                 'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  98                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V42', 'infiniband/verbs.h',
  99                 'struct ibv_counter_set_init_attr', 'counter_set_id' ],
 100                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V45', 'infiniband/verbs.h',
 101                 'struct ibv_counters_init_attr', 'comp_mask' ],
 102         ]
 103         # input array for meson symbol search:
 104         # [ "MACRO to define if found", "header for the search",
 105         #   "symbol to search" ]
 106         has_sym_args = [
 107                 [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
 108                 'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
 109                 [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
 110                 'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
 111                 [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
 112                 'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
 113                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
 114                 'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
 115                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_PAD', 'infiniband/mlx5dv.h',
 116                 'MLX5DV_CQ_INIT_ATTR_FLAGS_CQE_PAD' ],
 117                 [ 'HAVE_IBV_FLOW_DV_SUPPORT', 'infiniband/mlx5dv.h',
 118                 'mlx5dv_create_flow_action_packet_reformat' ],
 119                 [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
 120                 'IBV_FLOW_SPEC_MPLS' ],
 121                 [ 'HAVE_IBV_WQ_FLAGS_PCI_WRITE_END_PADDING', 'infiniband/verbs.h',
 122                 'IBV_WQ_FLAGS_PCI_WRITE_END_PADDING' ],
 123                 [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
 124                 'IBV_WQ_FLAG_RX_END_PADDING' ],
 125                 [ 'HAVE_MLX5DV_DR_DEVX_PORT', 'infiniband/mlx5dv.h',
 126                 'mlx5dv_query_devx_port' ],
 127                 [ 'HAVE_IBV_DEVX_OBJ', 'infiniband/mlx5dv.h',
 128                 'mlx5dv_devx_obj_create' ],
 129                 [ 'HAVE_IBV_FLOW_DEVX_COUNTERS', 'infiniband/mlx5dv.h',
 130                 'MLX5DV_FLOW_ACTION_COUNTERS_DEVX' ],
 131                 [ 'HAVE_IBV_DEVX_ASYNC', 'infiniband/mlx5dv.h',
 132                 'mlx5dv_devx_obj_query_async' ],
 133                 [ 'HAVE_MLX5DV_DR_ACTION_DEST_DEVX_TIR', 'infiniband/mlx5dv.h',
 134                 'mlx5dv_dr_action_create_dest_devx_tir' ],
 135                 [ 'HAVE_MLX5_DR_CREATE_ACTION_FLOW_METER', 'infiniband/mlx5dv.h',
 136                 'mlx5dv_dr_action_create_flow_meter' ],
 137                 [ 'HAVE_MLX5DV_MMAP_GET_NC_PAGES_CMD', 'infiniband/mlx5dv.h',
 138                 'MLX5_MMAP_GET_NC_PAGES_CMD' ],
 139                 [ 'HAVE_MLX5DV_DR', 'infiniband/mlx5dv.h',
 140                 'MLX5DV_DR_DOMAIN_TYPE_NIC_RX' ],
 141                 [ 'HAVE_MLX5DV_DR_ESWITCH', 'infiniband/mlx5dv.h',
 142                 'MLX5DV_DR_DOMAIN_TYPE_FDB' ],
 143                 [ 'HAVE_MLX5DV_DR_VLAN', 'infiniband/mlx5dv.h',
 144                 'mlx5dv_dr_action_create_push_vlan' ],
 145                 [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 146                 'SUPPORTED_40000baseKR4_Full' ],
 147                 [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 148                 'SUPPORTED_40000baseCR4_Full' ],
 149                 [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 150                 'SUPPORTED_40000baseSR4_Full' ],
 151                 [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 152                 'SUPPORTED_40000baseLR4_Full' ],
 153                 [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 154                 'SUPPORTED_56000baseKR4_Full' ],
 155                 [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 156                 'SUPPORTED_56000baseCR4_Full' ],
 157                 [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 158                 'SUPPORTED_56000baseSR4_Full' ],
 159                 [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 160                 'SUPPORTED_56000baseLR4_Full' ],
 161                 [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 162                 'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 163                 [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 164                 'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 165                 [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 166                 'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 167                 [ 'HAVE_IFLA_NUM_VF', 'linux/if_link.h',
 168                 'IFLA_NUM_VF' ],
 169                 [ 'HAVE_IFLA_EXT_MASK', 'linux/if_link.h',
 170                 'IFLA_EXT_MASK' ],
 171                 [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 172                 'IFLA_PHYS_SWITCH_ID' ],
 173                 [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 174                 'IFLA_PHYS_PORT_NAME' ],
 175                 [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 176                 'RDMA_NL_NLDEV' ],
 177                 [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 178                 'RDMA_NLDEV_CMD_GET' ],
 179                 [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 180                 'RDMA_NLDEV_CMD_PORT_GET' ],
 181                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 182                 'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 183                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 184                 'RDMA_NLDEV_ATTR_DEV_NAME' ],
 185                 [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 186                 'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 187                 [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 188                 'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 189         ]
 190         config = configuration_data()
 191         foreach arg:has_sym_args
 192                 config.set(arg[0], cc.has_header_symbol(arg[1], arg[2],
 193                         dependencies: libs))
 194         endforeach
 195         foreach arg:has_member_args
 196                 file_prefix = '#include <' + arg[1] + '>'
 197                 config.set(arg[0], cc.has_member(arg[2], arg[3],
 198                         prefix : file_prefix, dependencies: libs))
 199         endforeach
 200         configure_file(output : 'mlx5_autoconf.h', configuration : config)
 201 endif
 202 # Build Glue Library
 203 if pmd_dlopen and build
 204         dlopen_name = 'mlx5_glue'
 205         dlopen_lib_name = driver_name_fmt.format(dlopen_name)
 206         dlopen_so_version = LIB_GLUE_VERSION
 207         dlopen_sources = files('mlx5_glue.c')
 208         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 209         dlopen_includes = [global_inc]
 210         dlopen_includes += include_directories(
 211                 '../../../lib/librte_eal/common/include/generic',
 212         )
 213         shared_lib = shared_library(
 214                 dlopen_lib_name,
 215                 dlopen_sources,
 216                 include_directories: dlopen_includes,
 217                 c_args: cflags,
 218                 dependencies: libs,
 219                 link_args: [
 220                 '-Wl,-export-dynamic',
 221                 '-Wl,-h,@0@'.format(LIB_GLUE),
 222                 ],
 223                 soversion: dlopen_so_version,
 224                 install: true,
 225                 install_dir: dlopen_install_dir,
 226         )
 227 endif