examples/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 driver_libs = []
   5 if get_option('default_library') == 'static'
   6         driver_libs = dpdk_drivers
   7 endif
   8
   9 execinfo = cc.find_library('execinfo', required: false)
  10
  11 allow_skips = true # don't flag an error if we can't build an app
  12
  13 if get_option('examples').to_lower() == 'all'
  14         dirs = run_command('sh', '-c',
  15                 'cd $MESON_SOURCE_ROOT/$MESON_SUBDIR && for d in * ; do if [ -d $d ] ; then echo $d ; fi ; done')
  16         examples = dirs.stdout().split()
  17 else
  18         examples = get_option('examples').split(',')
  19         allow_skips = false # error out if we can't build a requested app
  20 endif
  21 default_cflags = machine_args
  22 if cc.has_argument('-Wno-format-truncation')
  23         default_cflags += '-Wno-format-truncation'
  24 endif
  25
  26 # specify -D_GNU_SOURCE unconditionally
  27 default_cflags += '-D_GNU_SOURCE'
  28
  29 foreach example: examples
  30         name = example
  31         build = true
  32         sources = []
  33         allow_experimental_apis = false
  34         cflags = default_cflags
  35
  36         ext_deps = [execinfo]
  37         includes = [include_directories(example)]
  38         deps = ['eal', 'mempool', 'net', 'mbuf', 'ethdev', 'cmdline']
  39         subdir(example)
  40
  41         if build
  42                 dep_objs = ext_deps
  43                 foreach d:deps
  44                         var_name = get_option('default_library') + '_rte_' + d
  45                         if not is_variable(var_name)
  46                                 error('Missing dependency "@0@" for example "@1@"'.format(d, name))
  47                         endif
  48                         dep_objs += [get_variable(var_name)]
  49                 endforeach
  50                 if allow_experimental_apis
  51                         cflags += '-DALLOW_EXPERIMENTAL_API'
  52                 endif
  53                 executable('dpdk-' + name, sources,
  54                         include_directories: includes,
  55                         link_whole: driver_libs,
  56                         link_args: dpdk_extra_ldflags,
  57                         c_args: cflags,
  58                         dependencies: dep_objs)
  59         elif not allow_skips
  60                 error('Cannot build requested example "' + name + '"')
  61         else
  62                 message('Skipping example "' + name + '"')
  63         endif
  64 endforeach