examples/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 driver_libs = []
   5 if get_option('default_library') == 'static'
   6         driver_libs = dpdk_drivers
   7 endif
   8
   9 execinfo = cc.find_library('execinfo', required: false)
  10
  11 allow_skips = true # don't flag an error if we can't build an app
  12
  13 if get_option('examples').to_lower() == 'all'
  14         dirs = run_command('sh', '-c',
  15                 'cd $MESON_SOURCE_ROOT/$MESON_SUBDIR && for d in * ; do if [ -d $d ] ; then echo $d ; fi ; done')
  16         examples = dirs.stdout().split()
  17 else
  18         examples = get_option('examples').split(',')
  19         allow_skips = false # error out if we can't build a requested app
  20 endif
  21 foreach example: examples
  22         name = example
  23         build = true
  24         sources = []
  25         allow_experimental_apis = false
  26         cflags = machine_args
  27         ext_deps = [execinfo]
  28         includes = [include_directories(example)]
  29         deps = ['eal', 'mempool', 'net', 'mbuf', 'ethdev', 'cmdline']
  30         subdir(example)
  31
  32         if build
  33                 dep_objs = ext_deps
  34                 foreach d:deps
  35                         dep_objs += [get_variable(
  36                                 get_option('default_library') + '_rte_' + d)]
  37                 endforeach
  38                 if allow_experimental_apis
  39                         cflags += '-DALLOW_EXPERIMENTAL_API'
  40                 endif
  41                 executable('dpdk-' + name, sources,
  42                         include_directories: includes,
  43                         link_whole: driver_libs,
  44                         link_args: dpdk_extra_ldflags,
  45                         c_args: cflags,
  46                         dependencies: dep_objs)
  47         elif not allow_skips
  48                 error('Cannot build requested example "' + name + '"')
  49         else
  50                 message('Skipping example "' + name + '"')
  51         endif
  52 endforeach