kernel/linux/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2018 Intel Corporation
   3
   4 subdirs = ['igb_uio', 'kni']
   5
   6 WARN_CROSS_COMPILE='Need "kernel_dir" option for kmod compilation when cross-compiling'
   7 WARN_NO_HEADERS='Cannot compile kernel modules as requested - are kernel headers installed?'
   8
   9 # if we are cross-compiling we need kernel_dir specified
  10 if get_option('kernel_dir') == '' and meson.is_cross_build()
  11         warning(WARN_CROSS_COMPILE)
  12         subdir_done()
  13 endif
  14
  15 kernel_dir = get_option('kernel_dir')
  16 if kernel_dir == ''
  17         # use default path for native builds
  18         kernel_version = run_command('uname', '-r').stdout().strip()
  19         kernel_dir = '/lib/modules/' + kernel_version + '/build'
  20 endif
  21
  22 # test running make in kernel directory, using "make kernelversion"
  23 make_returncode = run_command('make', '-sC', kernel_dir,
  24                 'kernelversion').returncode()
  25 if make_returncode != 0
  26         warning(WARN_NO_HEADERS)
  27         subdir_done()
  28 endif
  29
  30 # DO ACTUAL MODULE BUILDING
  31 foreach d:subdirs
  32         subdir(d)
  33 endforeach