lib/librte_acl/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 sources = files('acl_bld.c', 'acl_gen.c', 'acl_run_scalar.c',
   5                 'rte_acl.c', 'tb_mem.c')
   6 headers = files('rte_acl.h', 'rte_acl_osdep.h')
   7
   8 if dpdk_conf.has('RTE_ARCH_X86')
   9         sources += files('acl_run_sse.c')
  10
  11         # compile AVX2 version if either:
  12         # a. we have AVX supported in minimum instruction set baseline
  13         # b. it's not minimum instruction set, but supported by compiler
  14         #
  15         # in former case, just add avx2 C file to files list
  16         # in latter case, compile c file to static lib, using correct compiler
  17         # flags, and then have the .o file from static lib linked into main lib.
  18         if dpdk_conf.has('RTE_MACHINE_CPUFLAG_AVX2')
  19                 sources += files('acl_run_avx2.c')
  20                 cflags += '-DCC_AVX2_SUPPORT'
  21         elif cc.has_argument('-mavx2')
  22                 avx2_tmplib = static_library('avx2_tmp',
  23                                 'acl_run_avx2.c',
  24                                 dependencies: static_rte_eal,
  25                                 c_args: cflags + ['-mavx2'])
  26                 objs += avx2_tmplib.extract_objects('acl_run_avx2.c')
  27                 cflags += '-DCC_AVX2_SUPPORT'
  28         endif
  29
  30 elif dpdk_conf.has('RTE_ARCH_ARM') or dpdk_conf.has('RTE_ARCH_ARM64')
  31         cflags += '-flax-vector-conversions'
  32         sources += files('acl_run_neon.c')
  33 elif dpdk_conf.has('RTE_ARCH_PPC_64')
  34         sources += files('acl_run_altivec.c')
  35 endif