lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [
  12         'kvargs', # eal depends on kvargs
  13         'eal', # everything depends on eal
  14         'cmdline', # ethdev depends on cmdline for parsing functions
  15         'ring', 'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci', # core
  16         'metrics', # bitrate/latency stats depends on this
  17         'hash',    # efd depends on this
  18         'timer',   # eventdev depends on this
  19         'acl', 'bbdev', 'bitratestats', 'cfgfile',
  20         'compressdev', 'cryptodev',
  21         'distributor', 'efd', 'eventdev',
  22         'gro', 'gso', 'ip_frag', 'jobstats',
  23         'kni', 'latencystats', 'lpm', 'member',
  24         'power', 'pdump', 'rawdev',
  25         'rcu', 'reorder', 'sched', 'security', 'stack', 'vhost',
  26         #ipsec lib depends on crypto and security
  27         'ipsec',
  28         # add pkt framework libs which use other libs from above
  29         'port', 'table', 'pipeline',
  30         # flow_classify lib depends on pkt framework table lib
  31         'flow_classify', 'bpf', 'telemetry']
  32
  33 if is_windows
  34         libraries = ['kvargs','eal'] # only supported libraries for windows
  35 endif
  36
  37 default_cflags = machine_args
  38 if cc.has_argument('-Wno-format-truncation')
  39         default_cflags += '-Wno-format-truncation'
  40 endif
  41
  42 enabled_libs = [] # used to print summary at the end
  43
  44 foreach l:libraries
  45         build = true
  46         name = l
  47         version = 1
  48         allow_experimental_apis = false
  49         sources = []
  50         headers = []
  51         includes = []
  52         cflags = default_cflags
  53         objs = [] # other object files to link against, used e.g. for
  54                   # instruction-set optimized versions of code
  55
  56         # use "deps" for internal DPDK dependencies, and "ext_deps" for
  57         # external package/library requirements
  58         ext_deps = []
  59         deps = []
  60         # eal is standard dependency once built
  61         if dpdk_conf.has('RTE_LIBRTE_EAL')
  62                 deps += ['eal']
  63         endif
  64
  65         dir_name = 'librte_' + l
  66         subdir(dir_name)
  67
  68         if build
  69                 enabled_libs += name
  70                 dpdk_conf.set('RTE_LIBRTE_' + name.to_upper(), 1)
  71                 install_headers(headers)
  72
  73                 libname = 'rte_' + name
  74                 includes += include_directories(dir_name)
  75
  76                 if sources.length() == 0
  77                         # if no C files, just set a dependency on header path
  78                         shared_dep = declare_dependency(include_directories: includes)
  79                         static_dep = shared_dep
  80                 else
  81                         shared_deps = ext_deps
  82                         static_deps = ext_deps
  83                         foreach d:deps
  84                                 if not is_variable('shared_rte_' + d)
  85                                         error('Missing dependency ' + d +
  86                                                 ' for library ' + libname)
  87                                 endif
  88                                 shared_deps += [get_variable('shared_rte_' + d)]
  89                                 static_deps += [get_variable('static_rte_' + d)]
  90                         endforeach
  91
  92                         if allow_experimental_apis
  93                                 cflags += '-DALLOW_EXPERIMENTAL_API'
  94                         endif
  95
  96                         if get_option('per_library_versions')
  97                                 lib_version = '@0@.1'.format(version)
  98                                 so_version = '@0@'.format(version)
  99                         else
 100                                 lib_version = major_version
 101                                 so_version = major_version
 102                         endif
 103
 104                         # first build static lib
 105                         static_lib = static_library(libname,
 106                                         sources,
 107                                         objects: objs,
 108                                         c_args: cflags,
 109                                         dependencies: static_deps,
 110                                         include_directories: includes,
 111                                         install: true)
 112                         static_dep = declare_dependency(link_with: static_lib,
 113                                         include_directories: includes,
 114                                         dependencies: static_deps)
 115
 116                         # then use pre-build objects to build shared lib
 117                         sources = []
 118                         objs += static_lib.extract_all_objects(recursive: false)
 119                         version_map = '@0@/@1@/rte_@2@_version.map'.format(
 120                                         meson.current_source_dir(), dir_name, name)
 121                         implib = dir_name + '.dll.a'
 122
 123                         def_file = custom_target(name + '_def',
 124                                 command: [map_to_def_cmd, '@INPUT@', '@OUTPUT@'],
 125                                 input: version_map,
 126                                 output: 'rte_@0@_exports.def'.format(name))
 127                         if is_windows
 128                                 lk_args = ['-Wl,/def:' + def_file.full_path(),
 129                                         '-Wl,/implib:lib\\' + implib]
 130                         else
 131                                 lk_args = ['-Wl,--version-script=' + version_map]
 132                         endif
 133
 134                         shared_lib = shared_library(libname,
 135                                         sources,
 136                                         objects: objs,
 137                                         c_args: cflags,
 138                                         dependencies: shared_deps,
 139                                         include_directories: includes,
 140                                         link_args: lk_args,
 141                                         link_depends: [version_map, def_file],
 142                                         version: lib_version,
 143                                         soversion: so_version,
 144                                         install: true)
 145                         shared_dep = declare_dependency(link_with: shared_lib,
 146                                         include_directories: includes,
 147                                         dependencies: shared_deps)
 148
 149                         dpdk_libraries = [shared_lib] + dpdk_libraries
 150                         dpdk_static_libraries = [static_lib] + dpdk_static_libraries
 151                 endif # sources.length() > 0
 152
 153                 set_variable('shared_' + libname, shared_dep)
 154                 set_variable('static_' + libname, static_dep)
 155         endif # if build
 156 endforeach