lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [
  12         'kvargs', # eal depends on kvargs
  13         'eal', # everything depends on eal
  14         'ring', 'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci', # core
  15         'cmdline',
  16         'metrics', # bitrate/latency stats depends on this
  17         'hash',    # efd depends on this
  18         'timer',   # eventdev depends on this
  19         'acl', 'bbdev', 'bitratestats', 'cfgfile',
  20         'compressdev', 'cryptodev',
  21         'distributor', 'efd', 'eventdev',
  22         'gro', 'gso', 'ip_frag', 'jobstats',
  23         'kni', 'latencystats', 'lpm', 'member',
  24         'power', 'pdump', 'rawdev',
  25         'rcu', 'reorder', 'sched', 'security', 'stack', 'vhost',
  26         # ipsec lib depends on net, crypto and security
  27         'ipsec',
  28         # add pkt framework libs which use other libs from above
  29         'port', 'table', 'pipeline',
  30         # flow_classify lib depends on pkt framework table lib
  31         'flow_classify', 'bpf', 'telemetry']
  32
  33 if is_windows
  34         libraries = ['kvargs','eal'] # only supported libraries for windows
  35 endif
  36
  37 default_cflags = machine_args
  38 if cc.has_argument('-Wno-format-truncation')
  39         default_cflags += '-Wno-format-truncation'
  40 endif
  41
  42 enabled_libs = [] # used to print summary at the end
  43
  44 foreach l:libraries
  45         build = true
  46         reason = '<unknown reason>' # set if build == false to explain why
  47         name = l
  48         version = 1
  49         allow_experimental_apis = false
  50         use_function_versioning = false
  51         sources = []
  52         headers = []
  53         includes = []
  54         cflags = default_cflags
  55         objs = [] # other object files to link against, used e.g. for
  56                   # instruction-set optimized versions of code
  57
  58         # use "deps" for internal DPDK dependencies, and "ext_deps" for
  59         # external package/library requirements
  60         ext_deps = []
  61         deps = []
  62         # eal is standard dependency once built
  63         if dpdk_conf.has('RTE_LIBRTE_EAL')
  64                 deps += ['eal']
  65         endif
  66
  67         dir_name = 'librte_' + l
  68         subdir(dir_name)
  69
  70         if build
  71                 shared_deps = ext_deps
  72                 static_deps = ext_deps
  73                 foreach d:deps
  74                         if not is_variable('shared_rte_' + d)
  75                                 error('Missing internal dependency "@0@" for @1@ [@2@]'
  76                                                 .format(d, name, 'lib/' + dir_name))
  77                         endif
  78                         shared_deps += [get_variable('shared_rte_' + d)]
  79                         static_deps += [get_variable('static_rte_' + d)]
  80                 endforeach
  81         endif
  82
  83         if not build
  84                 dpdk_libs_disabled += name
  85                 set_variable(name.underscorify() + '_disable_reason', reason)
  86         else
  87                 enabled_libs += name
  88                 dpdk_conf.set('RTE_LIBRTE_' + name.to_upper(), 1)
  89                 install_headers(headers)
  90
  91                 libname = 'rte_' + name
  92                 includes += include_directories(dir_name)
  93
  94                 if sources.length() == 0
  95                         # if no C files, just set a dependency on header path
  96                         shared_dep = declare_dependency(include_directories: includes)
  97                         static_dep = shared_dep
  98                 else
  99
 100                         if allow_experimental_apis
 101                                 cflags += '-DALLOW_EXPERIMENTAL_API'
 102                         endif
 103                         if use_function_versioning
 104                                 cflags += '-DRTE_USE_FUNCTION_VERSIONING'
 105                         endif
 106
 107                         if get_option('per_library_versions')
 108                                 lib_version = '@0@.1'.format(version)
 109                                 so_version = '@0@'.format(version)
 110                         else
 111                                 lib_version = major_version
 112                                 so_version = major_version
 113                         endif
 114
 115                         # first build static lib
 116                         static_lib = static_library(libname,
 117                                         sources,
 118                                         objects: objs,
 119                                         c_args: cflags,
 120                                         dependencies: static_deps,
 121                                         include_directories: includes,
 122                                         install: true)
 123                         static_dep = declare_dependency(link_with: static_lib,
 124                                         include_directories: includes,
 125                                         dependencies: static_deps)
 126
 127                         if not use_function_versioning
 128                                 # use pre-build objects to build shared lib
 129                                 sources = []
 130                                 objs += static_lib.extract_all_objects(recursive: false)
 131                         else
 132                                 # for compat we need to rebuild with
 133                                 # RTE_BUILD_SHARED_LIB defined
 134                                 cflags += '-DRTE_BUILD_SHARED_LIB'
 135                         endif
 136                         version_map = '@0@/@1@/rte_@2@_version.map'.format(
 137                                         meson.current_source_dir(), dir_name, name)
 138                         implib = dir_name + '.dll.a'
 139
 140                         def_file = custom_target(name + '_def',
 141                                 command: [map_to_def_cmd, '@INPUT@', '@OUTPUT@'],
 142                                 input: version_map,
 143                                 output: 'rte_@0@_exports.def'.format(name))
 144                         if is_windows
 145                                 lk_args = ['-Wl,/def:' + def_file.full_path(),
 146                                         '-Wl,/implib:lib\\' + implib]
 147                         else
 148                                 lk_args = ['-Wl,--version-script=' + version_map]
 149                         endif
 150
 151                         shared_lib = shared_library(libname,
 152                                         sources,
 153                                         objects: objs,
 154                                         c_args: cflags,
 155                                         dependencies: shared_deps,
 156                                         include_directories: includes,
 157                                         link_args: lk_args,
 158                                         link_depends: [version_map, def_file],
 159                                         version: lib_version,
 160                                         soversion: so_version,
 161                                         install: true)
 162                         shared_dep = declare_dependency(link_with: shared_lib,
 163                                         include_directories: includes,
 164                                         dependencies: shared_deps)
 165
 166                         dpdk_libraries = [shared_lib] + dpdk_libraries
 167                         dpdk_static_libraries = [static_lib] + dpdk_static_libraries
 168                 endif # sources.length() > 0
 169
 170                 set_variable('shared_rte_' + name, shared_dep)
 171                 set_variable('static_rte_' + name, static_dep)
 172                 message('lib/@0@: Defining dependency "@1@"'.format(
 173                                 dir_name, name))
 174         endif # if build
 175 endforeach