meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 project('DPDK', 'C',
   5         version: '18.02.0',
   6         license: 'BSD',
   7         default_options: ['buildtype=release', 'default_library=static'],
   8         meson_version: '>= 0.41'
   9 )
  10
  11 # set up some global vars for compiler, platform, configuration, etc.
  12 cc = meson.get_compiler('c')
  13 dpdk_conf = configuration_data()
  14 dpdk_libraries = []
  15 dpdk_drivers = []
  16 dpdk_extra_ldflags = []
  17
  18 driver_install_path = join_paths(get_option('libdir'), 'dpdk/drivers')
  19 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  20
  21 # configure the build, and make sure configs here and in config folder are
  22 # able to be included in any file. We also store a global array of include dirs
  23 # for passing to pmdinfogen scripts
  24 global_inc = include_directories('.', 'config')
  25 subdir('config')
  26
  27 # build libs and drivers
  28 subdir('lib')
  29 subdir('buildtools')
  30 subdir('drivers')
  31
  32 # build binaries and installable tools
  33 subdir('usertools')
  34 subdir('app')
  35 subdir('test')
  36
  37 # build any examples explicitly requested - useful for developers
  38 if get_option('examples') != ''
  39         subdir('examples')
  40 endif
  41
  42 # write the build config
  43 build_cfg = 'rte_build_config.h'
  44 configure_file(output: build_cfg,
  45                 configuration: dpdk_conf,
  46                 install_dir: join_paths(get_option('includedir'),
  47                                 get_option('include_subdir_arch')))
  48
  49 # for static builds, include the drivers as libs and we need to "whole-archive"
  50 # them.
  51 dpdk_drivers = ['-Wl,--whole-archive'] + dpdk_drivers + ['-Wl,--no-whole-archive']
  52
  53 # driver .so files often depend upon the bus drivers for their connect bus,
  54 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  55 # to be in the library path, so symlink the drivers from the main lib directory.
  56 meson.add_install_script('buildtools/symlink-drivers-solibs.sh',
  57                 driver_install_path,
  58                 get_option('libdir'))
  59
  60 pkg = import('pkgconfig')
  61 pkg.generate(name: meson.project_name(),
  62         filebase: 'lib' + meson.project_name().to_lower(),
  63         version: meson.project_version(),
  64         libraries: dpdk_libraries,
  65         libraries_private: dpdk_drivers + dpdk_libraries +
  66                         ['-Wl,-Bdynamic'] + dpdk_extra_ldflags,
  67         description: 'The Data Plane Development Kit (DPDK)',
  68         subdirs: [get_option('include_subdir_arch'), '.'],
  69         extra_cflags: ['-include', 'rte_config.h'] + machine_args
  70 )