meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 project('DPDK', 'C',
   5         # Get version number from file.
   6         # Fallback to "more" for Windows compatibility.
   7         version: run_command(find_program('cat', 'more'),
   8                 files('VERSION')).stdout().strip(),
   9         license: 'BSD',
  10         default_options: ['buildtype=release', 'default_library=static'],
  11         meson_version: '>= 0.47.1'
  12 )
  13
  14 # set up some global vars for compiler, platform, configuration, etc.
  15 cc = meson.get_compiler('c')
  16 dpdk_conf = configuration_data()
  17 dpdk_libraries = []
  18 dpdk_static_libraries = []
  19 dpdk_driver_classes = []
  20 dpdk_drivers = []
  21 dpdk_extra_ldflags = []
  22 dpdk_app_link_libraries = []
  23
  24 # configure the build, and make sure configs here and in config folder are
  25 # able to be included in any file. We also store a global array of include dirs
  26 # for passing to pmdinfogen scripts
  27 global_inc = include_directories('.', 'config',
  28         'lib/librte_eal/common/include',
  29         'lib/librte_eal/@0@/eal/include'.format(host_machine.system()),
  30 )
  31 subdir('config')
  32
  33 # build libs and drivers
  34 subdir('lib')
  35 subdir('buildtools')
  36 subdir('drivers')
  37
  38 # build binaries and installable tools
  39 subdir('usertools')
  40 subdir('app')
  41
  42 # build docs
  43 subdir('doc')
  44
  45 # build any examples explicitly requested - useful for developers - and
  46 # install any example code into the appropriate install path
  47 subdir('examples')
  48
  49 # build kernel modules if enabled
  50 if get_option('enable_kmods')
  51         subdir('kernel')
  52 endif
  53
  54 # write the build config
  55 build_cfg = 'rte_build_config.h'
  56 configure_file(output: build_cfg,
  57                 configuration: dpdk_conf,
  58                 install_dir: join_paths(get_option('includedir'),
  59                                 get_option('include_subdir_arch')))
  60
  61 # for static builds, include the drivers as libs and we need to "whole-archive"
  62 # them.
  63 dpdk_drivers = ['-Wl,--whole-archive'] + dpdk_drivers + ['-Wl,--no-whole-archive']
  64
  65 pkg = import('pkgconfig')
  66 pkg.generate(name: meson.project_name(),
  67         filebase: 'lib' + meson.project_name().to_lower(),
  68         version: meson.project_version(),
  69         libraries: dpdk_libraries,
  70         libraries_private: dpdk_drivers + dpdk_static_libraries +
  71                         ['-Wl,-Bdynamic'] + dpdk_extra_ldflags,
  72         requires: libbsd, # apps using rte_string_fns.h may need this if enabled
  73                           # if libbsd is not enabled, then this is blank
  74         description: '''The Data Plane Development Kit (DPDK).
  75 Note that CFLAGS might contain an -march flag higher than typical baseline.
  76 This is required for a number of static inline functions in the public headers.''',
  77         subdirs: [get_option('include_subdir_arch'), '.'],
  78         extra_cflags: ['-include', 'rte_config.h'] + machine_args
  79 )
  80
  81 # final output, list all the libs and drivers to be built
  82 # this does not affect any part of the build, for information only.
  83 output_message = '\n=================\nLibraries Enabled\n=================\n'
  84 output_message += '\nlibs:\n\t'
  85 output_count = 0
  86 foreach lib:enabled_libs
  87         output_message += lib + ', '
  88         output_count += 1
  89         if output_count == 8
  90                 output_message += '\n\t'
  91                 output_count = 0
  92         endif
  93 endforeach
  94 message(output_message + '\n')
  95
  96 output_message = '\n===============\nDrivers Enabled\n===============\n'
  97 foreach class:dpdk_driver_classes
  98         class_drivers = get_variable(class + '_drivers')
  99         output_message += '\n' + class + ':\n\t'
 100         output_count = 0
 101         foreach drv:class_drivers
 102                 output_message += drv + ', '
 103                 output_count += 1
 104                 if output_count == 8
 105                         output_message += '\n\t'
 106                         output_count = 0
 107                 endif
 108         endforeach
 109 endforeach
 110 message(output_message + '\n')